U-boot引导流程分析一

2023-10-26

U-Boot,全称 Universal Boot Loader,即通用引导程序,是遵循GPL条款的开放源码项目。它的源码目录、编译形式与Linux内核很相似,事实上,不少U-Boot源码就是相应的Linux内核源程序的简化,尤其是一些设备的驱动程序,这从U-Boot源码的注释中能体现这一点。U-Boot不仅仅支持嵌入式Linux系统的引导,它还支持NetBSD, VxWorks, QNX, RTEMS, ARTOS, LynxOS嵌入式操作系统

U-Boot的工作模式有启动加载模式和下载模式。启动加载模式是Bootloader的正常工作模式,嵌入式产品发布时,Bootloader必须工作在这种模式下,Bootloader将嵌入式操作系统从FLASH中加载到SDRAM中运行,整个过程是自动的。下载模式就是Bootloader通过某些通信手段将内核映像或根文件系统映像等从PC机中下载到目标板的FLASH中。用户可以利用Bootloader提供的一些命令接口来完成自己想要的操作。

Android体系中U-Boot的大致引导流程:


U-Boot的源码目录结构

1、board:开发板相关的配置文件,一个子文件对应一个开发板配置;
2、common:通用的多功能函数实现,比如环境,命令,控制台相关函数等;
3、cpu:存放特定CPU结构相关的目录;
4、disk:硬盘接口程序;
5、doc:
6、drivers:支持的各种设备的驱动程序;
7、dtt:数字温度测量器或传感器的驱动;
8、examples:这个不解析;
9、fs:文件系统,最常用的是JFFS2文件系统;
10、include:头文件和开发板配置文件,开发板的配置文件放在include/configs目录下;
11、lib_generic:通用函数库,比如printf函数等;
12、lib_*:某一具体平台架构下的通用函数库,lib_i386就对应i386系统架构的通用函数库;
13、nand_spl:
14、net:与网络协议相关的代码,bootp协议、TFTP协议、NFS文件系统的实现;
15、post:上电自检程序;
16、rtc:实时时钟的驱动;
17、temp:
18、tools:制作s-record、u-boot格式映像的工具,比如mkimage。

U-Boot启动流程(简约)

大多数BootLoader都分为stage1和stage2两大部分,U-boot也不例外。依赖于cpu体系结构的代码(如设备初始化代码等)通常都放在stage1且可以用汇编语言来实现,而stage2则通常用C语言来实现,这样可以实现复杂的功能,而且有更好的可读性和移植性。
1、 stage1(start.s代码结构)
U-boot的stage1代码通常放在start.s文件中,它用汇编语言写成,其主要代码部分如下:
(1) 定义入口。由于一个可执行的image必须有一个 入口点,并且只能有一个全局入口,通常这个入口放在rom(Flash)的0x0地址,因此,必须通知 编译器以使其知道这个入口,该工作可通过修改连接器脚本来完成。
(2)设置异常向量(exception vector)。
(3)设置CPU的速度、 时钟频率及中断 控制寄存器
(4)初始化内存控制器 。
(5)将rom中的程序复制到ram中。
(6)初始化 堆栈 。
(7)转到ram中执行,该工作可使用指令ldrpc来完成。
2、 stage2(C语言代码部分)
lib_arm/board.c中的start  armboot是C语言开始的函数,也是整个启动代码中C语言的 主函数,同时还是整个u-boot(armboot)的主函数,该函数主要完成如下操作:
(1)调用一系列的初始化函数。
(2)初始化flash设备。
(3)初始化系统内存分配函数。
(4)如果目标系统拥有nand设备,则初始化nand设备。
(5)如果目标系统有显示设备,则初始化该类设备。
(6)初始化相关网络设备,填写ip,c地址等。
(7)进入命令循环(即整个boot的工作循环),接受用户从串口输入的命令,然后进行相应的工作。
下面结合SMDK2410(ARM920T)的U-Boot的源码来分析下U-Boot的整个引导流程。

Stage I过程分析

从文件层面上看主要流程是在这几个文件中进行的:cpu/xxx/start.S、board/xxx/lowlevel_init.S、lib_arm_board.c。

设置中断向量表

cpu/arm920t/start.S开头有如下代码:
/*
 *************************************************************************
 *
 * Jump vector table as in table 3.1 in [1]
 *
 *************************************************************************
 */


.globl _start
_start:	b       reset						/* 复位,CPU复位,b是不带返回的跳转,即无条件直接跳转至reset处执行 */
	ldr	pc, _undefined_instruction			/* 未定义指令向量 */
	ldr	pc, _software_interrupt				/* 软件中断向量 */
	ldr	pc, _prefetch_abort				/* 预取指令异常向量 */
	ldr	pc, _data_abort					/* 数据操作异常向量 */
	ldr	pc, _not_used					/* 未使用 */
	ldr	pc, _irq					/* irq中断向量 */
	ldr	pc, _fiq					/* fiq中断向量 */

_undefined_instruction:	.word undefined_instruction
_software_interrupt:	.word software_interrupt
_prefetch_abort:	.word prefetch_abort
_data_abort:		.word data_abort
_not_used:		.word not_used
_irq:			.word irq
_fiq:			.word fiq

	.balignl 16,0xdeadbeef					/* 16字节对齐,不足之处,用0xdeadbeef填充(搞笑,用“死牛”填充) */   
红色标记的"undefined_instruction"是一个标号,即地址值,对应的就是发生"未定义指令"中断时,系统处理该中断的代码的地址。
/*
 * exception handlers
 */
	.align  5
undefined_instruction:
	get_bad_stack
	bad_save_user_regs
	bl do_undefined_instruction

	.align	5
software_interrupt:
	get_bad_stack
	bad_save_user_regs
	bl 	do_software_interrupt

	.align	5
prefetch_abort:
	get_bad_stack
	bad_save_user_regs
	bl 	do_prefetch_abort

	.align	5
data_abort:
	get_bad_stack
	bad_save_user_regs
	bl 	do_data_abort

	.align	5
not_used:
	get_bad_stack
	bad_save_user_regs
	bl 	do_not_used

#ifdef CONFIG_USE_IRQ

	.align	5
irq:
	get_irq_stack
	irq_save_user_regs
	bl 	do_irq
	irq_restore_user_regs

	.align	5
fiq:
	get_fiq_stack
	/* someone ought to write a more effiction fiq_save_user_regs */
	irq_save_user_regs
	bl 	do_fiq
	irq_restore_user_regs

#else

	.align	5
irq:
	get_bad_stack
	bad_save_user_regs
	bl 	do_irq

	.align	5
fiq:
	get_bad_stack
	bad_save_user_regs
	bl 	do_fiq

#endif
在cpu/arm920t/interrupts.c中有对应的do_undefined_instruction方法。
void do_undefined_instruction (struct pt_regs *pt_regs)
{
	printf ("undefined instruction\n");
	show_regs (pt_regs);
	bad_mode ();
}


void do_software_interrupt (struct pt_regs *pt_regs)
{
	printf ("software interrupt\n");
	show_regs (pt_regs);
	bad_mode ();
}


void do_prefetch_abort (struct pt_regs *pt_regs)
{
	printf ("prefetch abort\n");
	show_regs (pt_regs);
	bad_mode ();
}


void do_data_abort (struct pt_regs *pt_regs)
{
	printf ("data abort\n");
	show_regs (pt_regs);
	bad_mode ();
}


void do_not_used (struct pt_regs *pt_regs)
{
	printf ("not used\n");
	show_regs (pt_regs);
	bad_mode ();
}


void do_fiq (struct pt_regs *pt_regs)
{
	printf ("fast interrupt request\n");
	show_regs (pt_regs);
	bad_mode ();
}


void do_irq (struct pt_regs *pt_regs)
{
#if defined (CONFIG_USE_IRQ) && defined (CONFIG_ARCH_INTEGRATOR)
	/* ASSUMED to be a timer interrupt  */
	/* Just clear it - count handled in */
	/* integratorap.c                   */
	*(volatile ulong *)(CFG_TIMERBASE + 0x0C) = 0;
#else
	printf ("interrupt request\n");
	show_regs (pt_regs);
	bad_mode ();
#endif
}

当一个中断发生,CPU首先会在中断向量表中查找对应的中断向量,然后跳转到对应的中断处理程序处执行。

CPU复位操作,会使CPU进入SVC模式。

设置CPU进入SVC模式

ARM处理器有7中模式,由CPSR的[4:0]决定。

用户模式USR:正常程序运行的工作模式。只能读CPSR。

系统模式SYS:与用户模式共用一套寄存器。用于支持操作系统的特权任务模式,它可以直接切换到其他模式。

管理模式SVC:操作系统的特权任务模式。系统复位和软件中断时才能进入该模式。

除了用户模式外,其他模式都是特权模式。只有在特权模式下,才允许对当前的程序状态寄存器的控制位直接进行读写。特权模式中除了系统模式外,都是异常模式。特权模式可以访问所有系统资源。一般,进入特权模式是为了处理中断、异常或者访问被保护的资源。

ARM处理器的工作模式:

处理器模式 特权模式 说明 CPSR[4:0]
用户模式USR 用户程序运行模式 10000
系统模式SYS 运行特权级的操作系统级任务  
管理模式SVC 提供操作系统使用的保护模式 10011
异常终止模式ABT 用于虚拟存储及存储保护 10111
未定义模式UND 用于支持通过软件仿真硬件的协处理器 11011
一般中断模式IRQ 用户通常的中断使用 10010
快速中断模式FIQ 用于高速数据传输和通道处理 10001

CPSR,Current Program Status Register,当前程序状态寄存器。

/*
 * the actual reset code
 */

reset:
	/*
	 * set the cpu to SVC32 mode
	 */
	mrs	r0,cpsr
	bic	r0,r0,#0x1f		/* 位清零,工作模式为清零 */
	orr	r0,r0,#0xd3		/* 逻辑或,工作模式为设为'(110)10011',即设置CPU为SVC模式,并将中断禁止位和快中断禁止位置1(屏蔽)*/
	msr	cpsr,r0

设置控制寄存器,关看门狗,关中断

看门狗是一个硬件模块,当系统出现死机现象,看门狗就会自动重启系统。看门狗的硬件逻辑:其硬件有一个记录超时功能,它要求用户每隔一段时间(根据需求配置)对某个寄存器置位(简称“喂狗”),若超时为进行“喂狗”动作,系统就会重启。
/* turn off the watchdog */
#if defined(CONFIG_S3C2400)
# define pWTCON 	0x15300000	/* 看门狗寄存器 */
# define INTMSK		0x14400008	/* Interupt-Controller base addresses 中断屏蔽寄存器 */
# define CLKDIVN	0x14800014	/* clock divisor register 时钟分频寄存器 */
#elif defined(CONFIG_S3C2410)
# define pWTCON		0x53000000
# define INTMSK		0x4A000008	/* Interupt-Controller base addresses */
# define INTSUBMSK	0x4A00001C
# define CLKDIVN	0x4C000014	/* clock divisor register */
#endif


#if defined(CONFIG_S3C2400) || defined(CONFIG_S3C2410)
	ldr     r0, =pWTCON
	mov     r1, #0x0	/* 向看门狗寄存器写入0 */
	str     r1, [r0]
	/*
	* mask all IRQs by setting all bits in the INTMR - default
	*/
	mov	r1, #0xffffffff
	ldr	r0, =INTMSK	/* 屏蔽所有中断 */
	str	r1, [r0]

INTMSK寄存器是一个32位寄存器,每一位对应一个中断,向其中写入0xffffffff,即将INTMSK寄存器全部置1,从而屏蔽对应的中断。

INTSUBMSK寄存器也是一个32位寄存器,但是只使用了低15位,向其中写入0x7fffffff,即可屏蔽对应的中断。

以上代码完成了对pWTCON、INTMSK、INTSUBMSK、CLKDIVN四个寄存器的地址设置,并且通过向看门狗寄存器写入0,禁止看门狗的复位功能(即重启功能),否则,在U-Boot启动过程中,CPU将不断重启。

初始化CPU时钟

关闭MMU和Cache

MMU,Memory Management Unit,即内存管理单元。MMU是CPU中用来管理虚拟存储器、物理存储器的控制线路,同时负责将虚拟地址映射为物理地址,以及提供硬件机制的内存访问授权。
/*
      * we do sys-critical inits only at reboot,
      * not when booting from ram!
      */
#ifndef CONFIG_SKIP_LOWLEVEL_INIT
	bl	cpu_init_crit
#endif
cpu_init_crit到底做了哪些操作呢?

#ifndef CONFIG_SKIP_LOWLEVEL_INIT
cpu_init_crit:
	/*
	 * flush v4 I/D caches
	 */
	mov	r0, #0
	mcr	p15, 0, r0, c7, c7, 0	/* flush v3/v4 cache 向c7写入0 */
	mcr	p15, 0, r0, c8, c7, 0	/* flush v4 TLB 向c8写入0 */

	/*
	 * disable MMU stuff and caches
	 */
	mrc	p15, 0, r0, c1, c0, 0	/* 读出控制寄存器到r0中 */
	bic	r0, r0, #0x00002300	@ clear bits 13, 9:8 (--V- --RS)
	bic	r0, r0, #0x00000087	@ clear bits 7, 2:0 (B--- -CAM)
	orr	r0, r0, #0x00000002	@ set bit 2 (A) Align
	orr	r0, r0, #0x00001000	@ set bit 12 (I) I-Cache
	mcr	p15, 0, r0, c1, c0, 0	/* 保存r0到控制寄存器中 */

	/*
	 * before relocating, we have to setup RAM timing
	 * because memory timing is board-dependend, you will
	 * find a lowlevel_init.S in your board directory.
	 */
	mov	ip, lr
	bl	lowlevel_init		/* 跳转到lowlevel_init,执行完lowlevel_init后返回 */
	mov	lr, ip
	mov	pc, lr
#endif /* CONFIG_SKIP_LOWLEVEL_INIT */

注:TLB,Translation Lookaside Buffer,即旁路缓冲,它的作用是在处理器访问内存数据的时候做地址转换。TLB中存放了一些页表文件,文件中记录了虚拟地址和物理地址的映射关系。当程序访问呢一个虚拟地址,会从TLB中查询出对应的物理地址,然后访问物理地址。

代码中的c0、c1、c7、c8是ARM920T的协处理器CP15的寄存器。其中,c7是cache控制寄存器,c8是TLB控制寄存器。

关闭MMU是通过修改CP15协处理器的c1寄存器来实现的。CP15的c1寄存器格式如下:

15

14

13

12

11

10

9

8

7

6

5

4

3

2

1

0

·

·

V

I

·

·

R

S

B

·

·

·

·

C

A

M

对应位的意义如下:

置0

置1

V

异常向量在0x00000000

异常向量在0xFFFF0000

I

关闭ICaches

开启ICaches

R、S

用来与页表中的描述符一起确定内存的访问权限

B

CPU为小字节序

CPU为大字节序

C

关闭DCaches

开启DCaches

A

数据访问时不进行地址对齐检查

数据访问时进行地址对齐检查

M

关闭MMU

开启MMU

初始化内存

lowlevel_init完成了内存初始化的任务,由于内存初始化时依赖开发板的,所以lowlevel_init的代码一般放在board下面相应的目录。对于SMDK2410,lowlevel_init的代码在board/smdk2410/lowlevel_init.S中。
_TEXT_BASE:
	.word	TEXT_BASE

.globl lowlevel_init
lowlevel_init:
	/* memory control configuration */
	/* make r0 relative the current location so that it */
	/* reads SMRDATA out of FLASH rather than memory ! */
	ldr     r0, =SMRDATA
	ldr	r1, _TEXT_BASE
	sub	r0, r0, r1
	ldr	r1, =BWSCON	/* Bus Width Status Controller */
	add     r2, r0, #13*4
0:
	ldr     r3, [r0], #4
	str     r3, [r1], #4
	cmp     r2, r0
	bne     0b

	/* everything is fine now */
	mov	pc, lr

	.ltorg
/* the literal pools origin */
SMRDATA:	/* 13个寄存器的值 */
    .word (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))
    .word ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))
    .word ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))
    .word ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))
    .word ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))
    .word ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))
    .word ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))
    .word ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN))
    .word ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN))
    .word ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)
    .word 0x32
    .word 0x30
    .word 0x30

lowlevel_init的作用就是将SMRDATA开始的13个值复制给开始地址[BWSCON]13个寄存器,从而完成了存储控制器的设置。

复制StageII的代码到RAM

上面初始化玩内存之后会跳转回start.S继续执行。

#ifndef CONFIG_SKIP_RELOCATE_UBOOT
relocate:				/* relocate U-Boot to RAM	    */
	adr	r0, _start		/* r0 <- current position of code   */
	ldr	r1, _TEXT_BASE		/* test if we run from flash or RAM */
	cmp     r0, r1                  /* don't reloc during debug         */
	beq     stack_setup

	ldr	r2, _armboot_start
	ldr	r3, _bss_start
	sub	r2, r3, r2		/* r2 <- size of armboot            */
	add	r2, r0, r2		/* r2 <- source end address         */

copy_loop:
	ldmia	r0!, {r3-r10}		/* copy from source address [r0]    */
	stmia	r1!, {r3-r10}		/* copy to   target address [r1]    */
	cmp	r0, r2			/* until source end addreee [r2]    */
	ble	copy_loop
#endif	/* CONFIG_SKIP_RELOCATE_UBOOT */

relocate处首先比较_start和_TEXT_BASE的地址,如果相同则说明程序以及在内存中,无须加载。copy_loop处则实现了循环复制Flash的数据到内存中,每次复制8个字长的数据。

设置堆栈

只要将SP指针指向一段未使用的内存就算是完成了对堆栈的设置了。
/* Set up the stack						    */
stack_setup:
	ldr	r0, _TEXT_BASE		/* upper 128 KiB: relocated uboot   */
	sub	r0, r0, #CFG_MALLOC_LEN	/* malloc area                      */
	sub	r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo                        */
#ifdef CONFIG_USE_IRQ
	sub	r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
#endif
	sub	sp, r0, #12		/* leave 3 words for abort-stack    */

根据上面的代码知道U-Boot内存使用情况。


清除BSS段

clear_bss:
	ldr	r0, _bss_start		/* find start of bss segment        */
	ldr	r1, _bss_end		/* stop here                        */
	mov 	r2, #0x00000000		/* clear                            */

clbss_l:str	r2, [r0]		/* clear loop...                    */
	add	r0, r0, #4
	cmp	r0, r1
	ble	clbss_l

BSS段中存放有初始值为0得变量、无初始值的全局变量和一些静态变量。清除BSS段,就是将这些变量初始化赋值0,否则这些变量的初始值将是一个随机的值,若有程序直接使用这些值将会引起未知的后果。

跳转到Stage II代码入口

#if 0
	/* try doing this stuff after the relocation */
	ldr     r0, =pWTCON
	mov     r1, #0x0
	str     r1, [r0]

	/*
	 * mask all IRQs by setting all bits in the INTMR - default
	 */
	mov	r1, #0xffffffff
	ldr	r0, =INTMR
	str	r1, [r0]

	/* FCLK:HCLK:PCLK = 1:2:4 */
	/* default FCLK is 120 MHz ! */
	ldr	r0, =CLKDIVN
	mov	r1, #3
	str	r1, [r0]
	/* END stuff after relocation */
#endif

	ldr	pc, _start_armboot

_start_armboot:	.word start_armboot

由代码可以看出,Stage II代码的入口处在start_armboot。


本文内容由网友自发贡献,版权归原作者所有,本站不承担相应法律责任。如您发现有涉嫌抄袭侵权的内容,请联系:hwhale#tublm.com(使用前将#替换为@)

U-boot引导流程分析一 的相关文章

  • 如何将 IntentService 的结果返回到 Activity 中?

    我正在使用 IntentService 通过 JSON 处理与服务器的网络通信 JSON 服务器部分工作正常 但我无法将结果返回到需要的地方 以下代码显示了我如何从 onClick 内部启动意图服务 然后让该服务更新全局变量以将结果转发回主
  • 如何在 Android 应用程序中添加 Facebook 分享按钮

    我是 android 初学者 我想在我的 android 应用程序中添加 FacebookShare 按钮 我在 2 2 中创建应用程序 请帮助我 我用这个代码 Intent emailIntent new Intent android c
  • PouchDb.get(id,{attachments: true}) 在 Android 上不返回数据

    我正在使用 PouchDb 无复制 开发一个 Ionic 应用程序 我能够成功地存储带有附件的数据 为了检索数据 我使用下面的控制器片段来调用 angularjs 工厂中的 get 函数 pouchDbManager getData cur
  • 如何设置AlertDialog中正负按钮的顺序?

    为什么我要这样做完全是另一个讨论 但我需要找出使我的所有警报对话框在右侧都有肯定按钮的最佳方法 请注意 在 3 0 及更低版本中 按钮通常显示为 确定 取消 而在 4 0 及更高版本中 按钮通常显示为 取消 确定 我想强制我的应用程序以最简
  • 本机 KDE 查找 Qt 5 应用程序

    我在 Kubuntu 12 10 Linux 机器上安装了 Qt5 和 Qt4 并注意到以下内容 使用 Qt4 编译的程序具有原生 KDE 外观和感觉 我使用默认的 KDEOxygen主题 我的程序也是如此 注意带有标题的平滑渐变和聚焦小部
  • 应用程序被终止时未收到推送

    我正在使用新的 FCM 将消息从我的服务器推送到我的 Android 应用程序 to APA91bHun4MxP5egoKMwt2KZFBaFUH 1RYqx data Nick Mario Room PortugalVSDenmark 我
  • Android 模拟器停止显示屏幕键盘?

    我在 eclipse 中使用 AVD 管理器 是否有一个设置可以用来在输入字段获得焦点时停止显示屏幕键盘 我尝试了硬件键盘 true 但模拟器似乎根本没有启动 S 姆斯托伊克的回答 https stackoverflow com a 541
  • Android SuperUser 应用程序如何检测应用程序请求 root?

    我正在编写一个将使用的应用程序su执行linux内核中的一些命令 我想知道超级用户如何确定应用程序正在请求 root 权限 另外 是否有任何已知的方法 通过混淆 可以绕过此检查 换句话说 尽管 Android 清单文件中没有明确请求权限 A
  • 以编程方式绘制气泡

    I would like to have a bubble with a precentage value in my app I can t use 9 patches as i want it to be customizable an
  • 如何修复“android.os.NetworkOnMainThreadException”?

    我在运行 RssReader 的 Android 项目时遇到错误 Code URL url new URL urlToRssFeed SAXParserFactory factory SAXParserFactory newInstance
  • Chrome 无法播放 MP4

    我每天都会从我的安全摄像头系统中收到几封发送到我的 Gmail 帐户的电子邮件 此类邮件包含来自摄像机的 MP4 格式的视频剪辑 每个大约 20 秒 的链接 奇怪的是 在基于 Mageia 的 PC 上单击此类链接后 剪辑将打开并在新的单独
  • 渲染问题无法加载LayoutLib:

    渲染问题无法加载LayoutLib com android layoutlib bridge Bridge 详情 org jetbrains android uipreview RenderingException Failed to lo
  • 在 xml 编辑器中在字符串资源的引用和值预览之间切换

    在 Android Studio 中使用 xml 值并引用时 Strings xy例如 我在视频中看到 实际上可以直接在同一编辑器窗口中显示实际值 它是基本上是在之间切换 String xy和 XYContent 但引用仍然存在 我不是指
  • 在 SpannableStringBuilder 中对齐位图

    如何将位图与 SpannableString 中的文本对齐 SpannableStringBuilder ssb new SpannableStringBuilder arr messages get position String msg
  • 如何在Android中的WebView中永久突出显示文本?

    我正在为 Android 手机开发 ePUB 阅读器 我可以使用 WebView 和 ClipBoardManager 将文本复制到 ClipBoard 但我真正想做的是永久突出显示该选择 我看到一些文章 他们建议让 WebView 处于选
  • GTK 窗口运动动画?

    我想自动在屏幕上移动我的 GTK WINDOW 目前我将它置于绘制 移动循环中 但这非常不稳定 我对 GTK 编程 以及一般的 gui 编程 非常陌生 我缺少什么 您还没有说您希望窗口遵循什么样的路径 如果路径是时间的一些简单函数 也就是说
  • 谷歌登录可以在模拟器中使用,但不能在手机中使用

    我在使用 Firebase 实施 Google 登录时遇到了非常严重的问题 我可以使用我的模拟器 Android 7 0 为 x86 64 构建的 SDK 登录 但如果我将项目上传到手机 Android 6 0 我将无法使用 Google
  • Android:录制的视频似乎*失真*

    我正在尝试使用 MediaRecorder 从相机录制视频 这是一个代码片段 snip mr setAudioSource MediaRecorder AudioSource MIC mr setVideoSource MediaRecor
  • Android动态壁纸如何实现双击?

    我想为 Android 动态壁纸实现双击事件 遗憾的是 我找不到任何具体的代码来实现这一点 目前 我找到了使用 Engine 类的 onTouchEvent 方法的解决方法 public void onTouchEvent MotionEv
  • Sed:为什么 [^\]] 似乎不起作用?

    我试图匹配 输出第一个之前的所有文本 出现 sed i r s 1 FILE tmp 令人惊讶的是 这不起作用 但是 搜索另一个括号确实有效 sed i r s 1 FILE tmp 这是 sed bug 还是我做错了 我知道我可以使用以下

随机推荐

  • hbase面试题(6)

    1 HBase来源于哪篇博文 C BigTable 2 下面对HBase的描述哪些是正确的 B C D B 是面向列的 C 是分布式的 D 是一种NoSQL数据库 3 HBase依靠 存储底层数据 A A HDFS B Hadoop C M
  • SAR目标检测数据集汇总

    SAR目标检测数据集汇总 文章目录 SAR目标检测数据集汇总 1 MSTAR 1996 2 OpenSARShip2 0 2017 3 SSDD SSDD 2020 4 AIR SARShip2 0 2019 5 SAR Ship Data
  • VScode调试php文件(详细且简单易操作)

    之前也不懂 看了网上好多帖子 按照它们步骤操作一遍之后 还是不行 头都大了 现在懂了 原来几步就搞定了 被它们搞得这么复杂 又是配置这个文件 又是配置那个文件 1 下载XAMPP Download XAMPP apachefriends o
  • Java程序员面试常问试题大全

    Java程序员面试常问试题大全 1 面向对象的特征有哪些方面 1 抽象 抽象就是忽略一个主题中与当前目标无关的那些方面 以便更充分地注意与当前目标有关的方面 抽象并不打算了解全部问题 而只是选择其中的一部分 暂时不用部分细节 抽象包括两个方
  • 详解 cryptogen 的内容和配置

    目录 1 cryptogen 模块命令说明 2 cryptogen 模块的配置文件 3 cryptogen 实例 创建测试配置文件 4 Fabric 证书文件的结构 cryptogen 模块主要用来生成组织结构和账号相关的文件 任何 Fab
  • 【react】实现数据双向绑定之不用柯里化的方式

    直接给onChange事件绑定一个箭头函数 这个箭头函数的参数就是event 在箭头函数内再调用saveFormData方法 saveFormData方法里面this setState dataType value
  • 学Python该看什么书?12本精华好书推荐!

    为了让更多想通过看书来学习Python的人能够把时间花在刀刃上 小编总结了Python目前所有热门方向上我个人觉得性价比很高 值得一看的书籍 今天小编来分享给大家 一 Python新手入门 新手学Python的话我推荐这本 Python编程
  • java:面向对象(多态中成员的特点)。

    这次我们说说多态中成员的特点 我们写这样一个代码 class Fu void method1 System out println fu method1 void method2 System out println fu method 2
  • 秒解小米bl锁 无需等待时间_小米全新系统曝光:小米9推送Android Q体验版

    点击上方蓝字订阅每日最新国产手机资讯 对于米粉来说 MIUI系统是他们坚持使用小米手机的重要原因 就在今天上午 MIUI官方微博发布消息 小米9的MIUI Android Q Beta优先体验版现已推送 已获得测试资格的朋友可以升级体验 据
  • 大厂笔试真题

    1 复数相乘 2 K个一组翻转链表 include
  • 浅谈 Python中if __name__ == ‘__main__‘:的工作原理

    为了理解if name main 的工作原理 我们需要先了解Python中的特殊变量 name 每个Python模块都有一个内置的变量 name 这个变量的值取决于如何执行模块 如果模块是被直接运行的 例如 你使用命令python mysc
  • 「网络安全」如何搭建MySQL恶意服务器读取文件?

    前言 注 本文不涉及对MySQL协议报文研究 仅讲解原理 并且做部分演示 搭建MySQL恶意服务器读取文件这件事 虽然直接利用门槛较高 但是由于在网上看到了一种比较新颖的利用方式 利用社会工程学引诱用户连接MySQL进而读取用户文件 个人觉
  • Day【4】字符串解码

    原题链接 思路 对于字符串k encoding 对于这样的形式 我们要加encoding重复k次 从左向右扫描字符串 如果说遇见字符 就直接将该字符添加到结果中 如果说 遇见 k encoding 的形式 我们首先要做的是就是将k和enco
  • GCC参数详解

    gcc and g 分别是gnu的c c 编译器 gcc g 在执行编译工作的时候 总共需要4步 1 预处理 生成 i的文件 预处理器cpp 2 将预处理后的文件不转换成汇编语言 生成文件 s 编译器egcs 3 有汇编变为目标代码 机器代
  • 9.OB4.0调用存储过程通过临时表返回多行记录

    MYSQL存储过程返回多行 1 表数据准备 drop table if exists t1 drop table if exists t2 drop table if exists t3 create table t1 id varchar
  • 任何程序都必须加载到什么中才能被cpu执行

    任何程序都必须加载到内存中才能被cpu执行 内存是计算机中的重要部件之一 它是外存与cpu进行沟通的桥梁 计算机中所有程序的运行都在内存中进行 内存性能的强弱影响计算机整体发挥的水平 任何程序都必须加载到内存中才能被cpu执行 学习视频分享
  • WPF 性能优化建议

    本章讲述 WPF 性能优化建议 20180930 WPF性能优化问题 运行软件发现CPU使用率很大 80 95 程序中含有委托 线程 定时器的处理 之前优化时 主要优化线程和定时器相关线程方面的处理 但是效果甚微 无意间看到博客中说程序界面
  • Android onInterceptTouchEvent与onTouchEvent调用关系

    概述 onInterceptTouchEvent 是用来拦截Touch事件 ViewGroup有 View没有 onTouchEvent 是Touch事件 ViewGroup与View都有 实例讲解 当一个Touch事件发生后 会由父布局开
  • connect错误:no route to host

    linux下 socket 用vmware装了两个虚拟机 分别运行客户端和服务器端 客户端连接的时候报错 connect error no route to host 但是在同一虚拟机下运行正常 我检查了socket返回值 正常 地址和端口
  • U-boot引导流程分析一

    U Boot 全称 Universal Boot Loader 即通用引导程序 是遵循GPL条款的开放源码项目 它的源码目录 编译形式与Linux内核很相似 事实上 不少U Boot源码就是相应的Linux内核源程序的简化 尤其是一些设备的