如何使用缩进作为 bison 和 flex 的块分隔符

我很想知道如何在 bison + flex 中实现缩进作为块分隔符。就像在 python 中一样。我正在编写自己的编程语言（主要是为了好玩，但我打算将其与游戏引擎一起使用），我将尝试想出一些特殊的东西来最小化样板文件并最大化开发速度。

我已经写了一个编译器（实际上是‘郎玩具’到 Nasm 翻译器）在 C 中，但失败了。由于某种原因，它只能处理整个源文件中的一个字符串（好吧，我已经醒了超过 48 小时 - 所以......你知道，大脑崩溃了）。

我不知道大括号和/或开始 -> 结束是否更容易实现（我这样做没有问题）或者是否只是我的大脑锁定了。

提前致谢！

Update:好吧，我不知道如何用 Flex 来做到这一点。我在向解析器返回多个 DEDENT 时遇到问题。 Flex/Bison 对我来说相对较新。

更新2：这是我到目前为止想出的 Flex 文件；它不太明白：

%x t
%option noyywrap

%{
  int lineno = 0, ntab = 0, ltab = 0, dedent = 0;
%}

%%

<*>\n  { ntab = 0; BEGIN(t); }
<t>\t  { ++ntab; }
<t>.   { int i; /* my compiler complains not c99 if i use for( int i=0... */
         if( ntab > ltab )
           printf("> indent >\n");
         else if( ntab < ltab )
           for( i = 0; i < ltab - ntab; i++ )
             printf("< dedent <\n");
         else
           printf("=        =\n");

         ltab = ntab; ntab = 0;
         BEGIN(INITIAL);
         /* move to next rule */
         REJECT;}
.    /* ignore everything else for now */

%%

main()
{
  yyin = fopen( "test", "r" );
  yylex();
}

你可以尝试一下，也许你会看到我所缺少的。在 Haxe 中返回多个 dedent 会很容易（ return t_dedent( num ); ）。

此代码并不总是正确匹配缩进/缩进。

更新3：我想我会放弃对 Flex 的希望并按照自己的方式去做，如果有人知道如何在 Flex 中做到这一点，无论如何我都会很高兴听到它。

您需要做的是让 flex 计算每行开头的空格数量，并插入适当数量的 INDENT/UNINDENT 标记，供解析器用来对内容进行分组。一个问题是您想要对制表符与空格做什么 - 您是否只想让它们与固定制表位等效，或者您是否希望要求缩进保持一致（因此，如果一行以制表符开头，下一行以制表符开头）如果有空格，则表示错误，这可能有点困难）。

假设你想要固定的 8 列制表位，你可以使用类似的东西

%{
/* globals to track current indentation */
int current_line_indent = 0;   /* indentation of the current line */
int indent_level = 0;          /* indentation level passed to the parser */
%}

%x indent /* start state for parsing the indentation */
%s normal /* normal start state for everything else */

%%
<indent>" "      { current_line_indent++; }
<indent>"\t"     { current_line_indent = (current_line_indent + 8) & ~7; }
<indent>"\n"     { current_line_indent = 0; /*ignoring blank line */ }
<indent>.        {
                   unput(*yytext);
                   if (current_line_indent > indent_level) {
                       indent_level++;
                       return INDENT;
                   } else if (current_line_indent < indent_level) {
                       indent_level--;
                       return UNINDENT;
                   } else {
                       BEGIN normal;
                   }
                 }

<normal>"\n"     { current_line_indent = 0; BEGIN indent; }
... other flex rules ...

您必须确保以缩进模式开始解析（以在第一行获得缩进）。