默认打印 XSLT 1.0 文本节点

我看过XSL xsl：模板匹配=“/”但那里没有提到触发我的问题的匹配模式。

我有一个相当复杂的 XML 结构：

<?xml version="1.0" encoding="UTF-8"?>
<MATERIAL_DATA>
<LOG>
    <USER>Peter</USER>
    <DATE>2011-02-18</DATE>
    <MATERIALS>
        <item>
            <MATNR>636207</MATNR>
            <TEXTS>
                <item>
                    <TEXT>granola bar 40gx24</TEXT>
                </item>
            </TEXTS>
            <PRICES>
                <item>
                    <MATNR>636207</MATNR>
                    <COST>125.78</COST>
                </item>
            </PRICES>
            <SALESPRICES>
                <item>
                    <B01>
                        <MATNR>636207</MATNR>
                        <CURR>CZK</CURR>
                        <DATBI>9999-12-31</DATBI>
                        <DATAB>2010-10-05</DATAB>
                    </B01>
                    <B02>
                        <item>
                            <PRICE>477.60</PRICE>
                            <KUNNR>234567</KUNNR>
                        </item>
                    </B02>
                </item>
            </SALESPRICES>
        </item>
    </MATERIALS>
</LOG>
</MATERIAL_DATA>

现在，如果我应用以下 XSLT，我的输出看起来是正确的：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="xml" indent="yes" encoding="UTF-8"/>

<xsl:template match="node() | @*">
    <xsl:apply-templates select="* | @*" />
</xsl:template>

<xsl:template match="B02">
    <xsl:element name="Mi">
        <xsl:value-of select="item/KUNNR"/>
    </xsl:element>
</xsl:template>

</xsl:stylesheet>

我得到输出：

<?xml version="1.0" encoding="UTF-8"?>
<Mi>234567</Mi>

但如果我应用 XSLT：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:output method="xml" indent="yes" encoding="UTF-8"/>

<xsl:template match="/*">
    <xsl:element name="MenuItems">
        <xsl:apply-templates select="LOG/MATERIALS/item/SALESPRICES/item"/>
    </xsl:element>
 </xsl:template>
 
<xsl:template match="B02">
    <xsl:element name="Mi">
        <xsl:value-of select="item/KUNNR"/>
    </xsl:element>
</xsl:template>

</xsl:stylesheet>

输出如下所示：

<?xml version="1.0" encoding="UTF-8"?>
<MenuItems>
                    
                        636207
                        CZK
                        9999-12-31
                        2010-10-05
<Mi>234567</Mi>
</MenuItems>

元素中的所有值<B01>在输出中！但为什么——我不匹配<B01>！？ 如何

<xsl:template match="node() | @*">
<xsl:apply-templates select="* | @*" />
</xsl:template>

使输出正确吗？我所做的就是匹配所有节点或属性并将模板应用于所有内容或所有属性。 但在我看来，当我完全匹配时，这应该不会产生影响<B01>！ 为什么会发生这种情况？

XSLT 包括以下内容默认模板 (除其他外):

<!-- applies to both element nodes and the root node -->
<xsl:template match="*|/">
  <xsl:apply-templates/>
</xsl:template>

<!-- copies values of text and attribute nodes through -->
<xsl:template match="text()|@*">
  <xsl:value-of select="."/>
</xsl:template>

在您的第一个样式表中，您隐式地将所有文本节点与node()，从而覆盖默认操作。然后，在B2模板，您输出目标值并且不应用进一步的模板，这将停止处理。

在第二个样式表中，您显式地将模板应用于LOG/MATERIALS/item/SALESPRICES/item，导致默认模板处理您未显式处理的节点。因为你明确处理B2如果不将模板应用于其子节点，则永远不会为这些节点调用默认模板。但默认模板are适用于 的孩子B1.

将以下模板添加到第二个样式表将覆盖文本节点的默认操作：

<xsl:template match="text()|@*"></xsl:template>

结果如下：

<?xml version="1.0" encoding="UTF-8"?>
<MenuItems><Mi>234567</Mi></MenuItems>

More:

• http://www.w3.org/TR/xslt#built-in-rule