如何阻止 g++ 链接不需要的异常处理代码？

我正在使用为arm-eabi 编译的GCC/G++ 开发嵌入式应用程序。由于资源限制，我尝试禁用标准 C++ 异常处理。我正在用“-fno-exceptions”编译代码 -nostartfiles -ffreestand”。

当一个类的全局实例存在，并且该类包含另一个类的实例作为成员时，就会链接很多异常处理代码。这不会那么糟糕，除了它还引入了很多异常处理代码。 stdio 的东西，比如 printf、fopen、fclose 和其他 FILE 函数。这个应用程序没有文件系统，即使有，这些函数也浪费了太多的代码空间。

据我了解，即使使用 -fno-exceptions，G++ 也会链接到使用异常的运算符 new，因为该库没有非异常使用运算符 new（除了 new(nothrot)）。我创建了 new 和 delete 运算符的替代品，并将它们链接到输出以及不需要的标准库函数中。

让我困惑的是我没有在任何地方调用 new 。仅当全局对象包含另一个对象时，所有这些代码才会链接到其中。

例如：

class UartA {
...
private:
  Ringbuffer* rxbuf;
};

class UartB {
...
private:
  Ringbuffer rxbuf;
};

如果创建了 UartA 的全局实例，则不会链接异常处理、operator new 和 stdio 内容。这就是我想要的。

如果创建了 UartB 的全局实例（其中 rxbuf 是实例而不是指针），则会链接不需要的代码。

UartA和UartB都不使用operator new、exception或stdio。它们的区别仅在于 rxbuf 的类型。

您能建议如何防止链接额外的代码吗？另外，为什么它被链接到 UartB，而不是 UartA？

因为您基本上正在做操作系统开发人员为获得独立的 c 或 c++ 环境而要做的事情。您可能想考虑仅使用自定义链接器脚本。您只需要小心，因为像全局构造函数这样的事情不再自动发生......但是您也不会得到任何您没有明确要求的东西（并且编写调用全局构造函数的代码并不难）。这是我的操作系统中的链接器脚本。

OUTPUT_FORMAT("elf32-i386")
ENTRY(start)

virt = 0xc0100000; /* 3.1 gig */
phys = 0x00100000; /* 1 meg */

SECTIONS
{ 
    .text virt : AT(phys) 
    {
        code = .; _code = .; __code = .;
        *(.text)
        *(.gnu.linkonce.t*)
        . = ALIGN(4096); 
    }

    .rodata : AT(phys + (rodata - code))
    {
        rodata = .; _rodata = .; __rodata = .;
        *(.rodata*)
        *(.gnu.linkonce.r*)
        __CTOR_LIST__ = .;
        LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2) 
        *(.ctors) 
        LONG(0) 
        __CTOR_END__ = .; 

        __DTOR_LIST__ = .; 
        LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2) 
        *(.dtors) 
        LONG(0) 
        __DTOR_END__ = .; 
        . = ALIGN(4096); 
    }

    .data : AT(phys + (data - code))
    {
        data = .; _data = .; __data = .;    
        *(.data)
        *(.gnu.linkonce.d*)
        . = ALIGN(4096); 
    }

    .tbss : AT(phys + (tbss - code)) 
    {
        tbss = .; _tbss = .; __tbss = .;
        *(.tbss)
        *(.tbss.*)
        . = ALIGN(4096); 
    }

    .bss : AT(phys + (bss - code)) 
    {
        bss = .; _bss = .; __bss = .;
        *(.bss)
        *(.bss.*)
        *(COMMON)
        *(.gnu.linkonce.b*)
        . = ALIGN(4096); 
    }

    end = .; _end = .; __end = .;
}

它的功能可能超出您的需要（将部分与 4k 边界对齐，所有符号都大于 3GB 标记），但它是一个很好的起点。

你可以这样使用它：

ld -T link_script.ld *.o -lc -o appname

如果您想要的话，“-lc”也应该链接到 libc 中。