更改 CMAKE_CXX_FLAGS_DEBUG 和 CMake 中朋友的默认值

我想更改默认值CMAKE_CXX_FLAGS_RELEASE or CMAKE_CXX_FLAGS_DEBUG在 CMake 中。基本上，我有一些项目默认值与 CMake 的默认值略有不同（例如，对于发布），我不应该问自己“哦，当使用 add_compile_options 添加时，他们的 -O3 还是我们的 -O2 优先。”

现在，我知道如何设置这些值，但我不知道如何使用户可以通过两种常用方式编辑它们：通过使用 -DCMAKE_CXX_FLAGS_DEBUG=yourflags在命令行上或通过使用 ccmake 或 CMakeSetup 进行配置。

问题在于 CMAKE 设置并缓存其自己的默认值，如果您尝试在不使用 FORCE 的情况下覆盖变量，则“默认值”永远不会更改。如果我在 set 命令中使用 FORCE：set(CMAKE_CXX_FLAGS_DEBUG blah CACHE STRING "" FORCE)，每次运行脚本时它都会覆盖它，从而消除了用户根据需要更改它的可能性。

我设法通过执行以下操作来破解它以与 CCMAKE 一起使用，但这仍然不起作用cmake -DCMAKE_CXX_FLAGS_DEBUG因为它会在完成后覆盖用户更改：

set(DEFAULTS_SET FALSE CACHE BOOL "")
set(CMAKE_CXX_FLAGS_DEBUG "-this -that" CACHE STRING "" FORCE)
set(DEFAULTS_SET TRUE CACHE BOOL "" FORCE)

显然，这是一个令人讨厌的黑客行为，并且不能完全起作用（在 cmake -Dwhatever=thisorthat 的情况下）。我也可以添加其他构建类型，但我真的不明白为什么仅仅为了改变一些简单的事情就需要这样做。

2015年3月1日编辑：

我已经创建了一个有效的解决方案，尽管我仍然对我必须做的事情不太兴奋。我看过其他解决设置问题的评论CMAKE_CXX_FLAGS_DEBUG和朋友，而不让它们被破坏，但这最初对我不起作用，因为我试图根据正在使用的编译器来选择它们。然而，编译器直到它已经为我填充了变量才确定。我使用的技巧如下。您必须在项目命令之前将标志变量设置为“特殊”。

set(CMAKE_CXX_FLAGS_DEBUG "_UNSET" CACHE STRING "")
project(your_project C CXX)

if(${CMAKE_CXX_FLAGS_DEBUG} STREQUAL "_UNSET")
    # Do some compiler switching here and then set your flags with FORCE.
    set(CMAKE_CXX_FLAGS_DEBUG "-ggdb3 -O0" CACHE STRING "" FORCE)
endif()

现在，我可以选择通过命令行使用 -D 或在 cmake-gui 中完全覆盖的默认值。

我只是想添加我看到的四种可能性：

1. 拥有自己的工具链文件，其中包含您支持的每个编译器的预设，例如：

   GNU工具链.cmake

    set(CMAKE_CXX_FLAGS_DEBUG "-ggdb3 -O0" CACHE STRING "")
   

   然后使用它

    cmake -DCMAKE_TOOLCHAIN_FILE:string=GNUToolchain.cmake ...
   

2. 您可以尝试通过检查来确定编译器CMAKE_GENERATOR（在之前有效project()命令）：

   CMakeLists.txt

    if("${CMAKE_GENERATOR}" MATCHES "Makefiles" OR 
       ("${CMAKE_GENERATOR}" MATCHES "Ninja" AND NOT WIN32))
        set(CMAKE_CXX_FLAGS_DEBUG "-ggdb3 -O0" CACHE STRING "")
    endif()
   
    project(your_project C CXX)
   

3. 您可以使用CMAKE_USER_MAKE_RULES_OVERRIDE给你自己的脚本..._INIT values:

   它在 CMake 的内置编译器和平台信息模块加载之后但在使用信息之前加载。该文件可以设置平台信息变量来覆盖 CMake 的默认值。

   MyInitFlags.cmake

    # Overwrite the init values choosen by CMake
    if (CMAKE_CXX_COMPILER_ID MATCHES "GNU")
        set(CMAKE_CXX_FLAGS_DEBUG_INIT "-ggdb3 -O0")
    endif()
   

   CMakeLists.txt

    set(CMAKE_USER_MAKE_RULES_OVERRIDE "MyInitFlags.cmake")
   
    project(your_project C CXX)
   

4. 从 3 月 1 日起，您可以通过检查来简化您的解决方案..._INIT编译器标志变量的变体：

   CMakeLists.txt

    project(your_project C CXX)
   
    if (DEFINED CMAKE_CXX_FLAGS_DEBUG_INIT AND  
        "${CMAKE_CXX_FLAGS_DEBUG_INIT}" STREQUAL "${CMAKE_CXX_FLAGS_DEBUG}")
        # Overwrite the init values choosen by CMake
        if (CMAKE_CXX_COMPILER_ID MATCHES "GNU")
            set(CMAKE_CXX_FLAGS_DEBUG "-ggdb3 -O0" CACHE STRING "" FORCE)
        endif()
    endif()
   

Comments:

我更喜欢并使用工具链变体。但我承认它的缺点是必须手动提供工具链文件（如果您不调用cmake通过脚本/批处理文件）。

参考:

• CMake：文件按什么顺序解析（缓存、工具链等）？
• cmake - 全局链接器标志设置（对于目录中的所有目标）
• 使用 CMake 在 GCC 和 Clang/LLVM 之间切换