如何使用新线程库中的 Task.Wait For Any？

尝试使用Delphi中的线程库并行计算任务并使用TTask.WaitForAny()为了得到第一个计算结果，偶尔会出现异常停止执行。

异常时的调用堆栈：

第一次机会例外，价格为 752D2F71 美元。异常类 EMonitorLockException 带有消息“不拥有对象锁”。处理 Project1.exe (11248)

:752d2f71 KERNELBASE.RaiseException + 0x48
System.TMonitor.CheckOwningThread
System.ErrorAt(25,$408C70)
System.Error(reMonitorNotLocked)
System.TMonitor.CheckOwningThread
System.TMonitor.Exit
System.TMonitor.Exit($2180E40)
System.Threading.TTask.RemoveCompleteEvent(???)
System.Threading.TTask.DoWaitForAny((...),4294967295)
System.Threading.TTask.WaitForAny((...))
Project9.Parallel2
Project9.Project1
:74ff919f KERNEL32.BaseThreadInitThunk + 0xe
:7723b54f ntdll.RtlInitializeExceptionChain + 0x8f
:7723b51a ntdll.RtlInitializeExceptionChain + 0x5a

调用堆栈得出的结论是异常是由线程库中的错误引起的，TMonitor和/或TTask.WaitForAny()。为了验证这一点，代码被缩减到最少：

program Project1;

{$APPTYPE CONSOLE}

uses
  System.SysUtils, System.Threading, System.Classes, System.SyncObjs,
  System.StrUtils;
var
  WorkerCount : integer = 1000;

function MyTaskProc: TProc;
begin
  result := procedure
    begin
      // Do something
    end;
end;

procedure Parallel2;
var
  i : Integer;
  Ticks: Cardinal;
  tasks: array of ITask;
  LTask: ITask;
  workProc: TProc;
begin
  workProc := MyTaskProc();
  Ticks := TThread.GetTickCount;
  SetLength(tasks, WorkerCount); // number of parallel tasks to undertake
  for i := 0 to WorkerCount - 1 do // parallel tasks
    tasks[i] := TTask.Run(workProc);
  TTask.WaitForAny(tasks); // wait for the first one to finish
  for LTask in tasks do
    LTask.Cancel; // kill the remaining tasks
  Ticks := TThread.GetTickCount - Ticks;
  WriteLn('Parallel time ' + Ticks.ToString + ' ms');
end;

begin
  try
    repeat
      Parallel2;
      WriteLn('finished');
    until FALSE;
  except
    on E: Exception do
      writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.

现在，一段时间后错误再次出现，并且 RTL 错误已得到验证。

这被提交为RSP-10197 TTask.WaitForAny 给出异常 EMonitorLockException“对象锁未被拥有”到内河码头。

鉴于目前无法使用 Delphi 线程库解决这个问题，问题是：

是否有解决方法可以并行执行过程以获得第一个获得的解决方案？

这是一个使用的示例TParallel.For当产生答案时停止执行。它使用TParallel.LoopState向并行 for 循环的其他成员发出信号。通过使用.Stop信号，所有当前和待处理的迭代都应该停止。当前迭代应该检查loopState.Stopped.

procedure Parallel3(CS: TCriticalSection);
var
  Ticks: Cardinal;
  i,ix: Integer;  // variables that are only touched once in the Parallel.For loop
begin
  i := 0;
  Ticks := TThread.GetTickCount;
  TParallel.For(1,WorkerCount,
    procedure(index:Integer; loopState: TParallel.TLoopState)
    var
      k,l,m: Integer;
    begin
      // Do something complex
      k := (1000 - index)*1000;
      for l := 0 to Pred(k) do
        m := k div 1000;
      // If criteria to stop fulfilled:
      CS.Enter;
      Try
        if loopState.Stopped then // A solution was already found
          Exit;
        loopState.Stop;  // Signal 
        Inc(i);
        ix := index;
      Finally
        CS.Leave;
      End;
    end
  );
  Ticks := TThread.GetTickCount - Ticks;
  WriteLn('Parallel time ' + Ticks.ToString + ' ticks', ' i :',i,' index:',ix);
end;

临界区保护计算结果，这里为简单起见 i,ix。

免责声明，考虑到内部存在大量错误System.Threading库，我会推荐另一种使用 OTL 框架的解决方案。至少在图书馆打下稳定的基础之前是这样。