f# 中多路树的折叠/递归

我正在尝试将布莱恩的折叠改编为二叉树（http://lorgonblog.wordpress.com/2008/04/06/catamorphisms-part-two/）申请多路树。

布莱恩博客的总结：

数据结构：

type Tree<'a> =  
    | Node of (*data*)'a * (*left*)Tree<'a> * (*right*)Tree<'a>  
    | Leaf 

let tree7 = Node(4, Node(2, Node(1, Leaf, Leaf), Node(3, Leaf, Leaf)),  
                    Node(6, Node(5, Leaf, Leaf), Node(7, Leaf, Leaf)))

二叉树折叠函数

let FoldTree nodeF leafV tree =   
    let rec Loop t cont =   
        match t with   
        | Node(x,left,right) -> Loop left  (fun lacc ->    
                                Loop right (fun racc ->   
                                cont (nodeF x lacc racc)))   
        | Leaf -> cont leafV   
    Loop tree (fun x -> x) 

examples

let SumNodes = FoldTree (fun x l r -> x + l + r) 0 tree7
let Tree6to0 = FoldTree (fun x l r -> Node((if x=6 then 0 else x), l, r)) Leaf tree7

多路树版本 [不（完全）工作]:

数据结构

type MultiTree = | MNode of int * list<MultiTree>

let Mtree7 = MNode(4, [MNode(2, [MNode(1,[]); MNode(3, [])]);  
                    MNode(6, [MNode(5, []); MNode(7, [])])])

折叠功能

let MFoldTree nodeF leafV tree = 
    let rec Loop  tree cont =   
        match tree with   
        | MNode(x,sub)::tail -> Loop (sub@tail) (fun acc -> cont(nodeF x acc))
        | [] -> cont leafV
    Loop  [tree] (fun x -> x) 

实施例1返回 28 - 似乎有效

let MSumNodes = MFoldTree (fun x acc -> x + acc) 0 Mtree7

实施例2

不运行

let MTree6to0 = MFoldTree (fun x acc -> MNode((if x=6 then 0 else x), [acc])) Mtree7

最初我以为MFoldTree需要一个map.something某处但我让它与@改为运算符。

对第二个例子的任何帮助和/或纠正我在第二个例子中所做的事情MFoldTree功能会很棒！

Cheers

dusiod

诀窍在于您需要传递一个附加函数来折叠。

在布莱恩的版本中，折叠功能只需nodeF使用节点中的值以及从左子树和右子树生成的两个值来调用它。

这对于多路树来说是不够的。这里，我们需要一个函数nodeF使用节点中的值以及聚合子树的所有值产生的结果来调用它。但你还需要一个功能 - 比如combineF组合从节点的多个子树产生的值。

你的折叠函数是一个好的开始 - 你只需要再添加一个递归调用来处理tail:

let MFoldTree nodeF combineF leafV tree = 
    let rec Loop trees cont =   
        match trees with   
        | MNode(x,sub)::tail -> 
            // First, process the sub-trees of the current node and get 
            // a single value called 'accSub' representing (aggregated)
            // folding of the sub-trees.
            Loop sub (fun accSub -> 
              // Now we can call 'nodeF' on the current value & folded sub-tree
              let resNode = nodeF x accSub
              // But now we also need to fold all remaining trees that were
              // passed to us in the parameter 'trees'..
              Loop tail (fun accTail ->
                // This produces a value 'accTail' and now we need to combine the
                // result from the tail with the one for the first node 
                // (which is where we need 'combineF')
                cont(combineF resNode accTail) ))
        | [] -> cont leafV
    Loop  [tree] (fun x -> x) 

求和很容易，因为我们只需使用+两个函数的运算符：

let MSumNodes = MFoldTree (+) (+) 0 Mtree7

过滤树更加棘手。这nodeF函数将获取节点中的元素和list子节点（即聚合的结果）并产生single节点。这combineF函数将从第一个节点（即MultiTreevalue）以及从剩余节点生成的子节点列表。从空树生成的初始值是一个空列表：

let MTree6to0 = 
  MFoldTree (fun x children -> MNode((if x=6 then 0 else x), children)) 
            (fun head tail -> head::tail) [] Mtree7