使用 EitherT 累积错误

我有以下一个 Web API 的小型示例应用程序，它需要一个巨大的 JSON 文档，并且应该将其分段解析并报告每个部分的错误消息。

以下代码是使用 EitherT （和错误包）的工作示例。但是，那problem是 EitherT 打破了遇到的第一个 Left 的计算，只返回它看到的第一个“错误”。我想要的是一个错误消息列表，所有可能产生的消息。例如，如果第一行runEitherT失败了，那么就没有什么可以做的了。但如果第二行失败，那么我们仍然可以尝试运行后续行，因为它们对第二行没有数据依赖性。所以理论上我们可以产生more（不一定是全部）错误消息一次性出现。

是否可以延迟运行所有计算并返回我们可以找到的所有错误消息？

{-# LANGUAGE OverloadedStrings #-}

module Main where

import Data.ByteString.Lazy.Char8 (pack)
import Web.Scotty as S
import Network.Wai.Middleware.RequestLogger
import Data.Aeson
import Data.Aeson.Types
import Control.Lens hiding ((.=), (??))
import Data.Aeson.Lens
import qualified Data.Text as T
import Control.Error
import Control.Applicative
import qualified Data.HashMap.Strict as H
import Network.HTTP.Types

data TypeOne = TypeOne T.Text TypeTwo TypeThree
  deriving (Show)

data TypeTwo = TypeTwo Double
  deriving (Show)

data TypeThree = TypeThree Double
  deriving (Show)

main :: IO ()
main = scotty 3000 $ do
  middleware logStdoutDev

  post "/pdor" $ do
    api_key <- param "api_key"
    input   <- param "input"

    typeOne <- runEitherT $ do
      result       <- (decode (pack input) :: Maybe Value) ?? "Could not parse. Input JSON document is malformed"
      typeTwoObj   <- (result ^? key "typeTwo")            ?? "Could not find key typeTwo in JSON document."
      typeThreeObj <- (result ^? key "typeThree")          ?? "Could not find key typeThree in JSON document."
      name         <- (result ^? key "name" . _String)     ?? "Could not find key name in JSON document."
      typeTwo      <- hoistEither $ prependLeft "Error when parsing TypeTwo: " $ parseEither jsonTypeTwo typeTwoObj
      typeThree    <- hoistEither $ prependLeft "Error when parsing TypeThree: " $ parseEither jsonTypeThree typeThreeObj

      return $ TypeOne name typeTwo typeThree

    case typeOne of
      Left errorMsg -> do
        _ <- status badRequest400
        S.json $ object ["error" .= errorMsg]
      Right _ ->
        -- do something with the parsed Haskell type
        S.json $ object ["api_key" .= (api_key :: String), "message" .= ("success" :: String)]

prependLeft :: String -> Either String a -> Either String a
prependLeft msg (Left s) = Left (msg ++ s)
prependLeft _ x = x

jsonTypeTwo :: Value -> Parser TypeTwo
jsonTypeTwo (Object v) = TypeTwo <$> v .: "val"
jsonTypeTwo _ = fail $ "no data present for TypeTwo"

jsonTypeThree :: Value -> Parser TypeThree
jsonTypeThree (Object v) = TypeThree <$> v .: "val"
jsonTypeThree _ = fail $ "no data present for TypeThree"

如果有人有重构建议，也可以接受。

正如我在评论中提到的，至少有两种累积错误的方法。下面我详细阐述一下这些。我们需要这些导入：

import Control.Applicative
import Data.Monoid
import Data.These

TheseT单子变压器

免责声明： TheseT叫做ChronicleT in these package.

看看下面的定义These数据类型:

data These a b = This a | That b | These a b

Here This and That相当于Left and Right of Either数据类型。These数据构造函数能够积累能力Monad实例：它包含两个结果（类型为b）和以前的错误的集合（类型的集合a).

利用现有的定义These我们可以轻松创建的数据类型ErrorT-类似单子变压器：

newtype TheseT e m a = TheseT {
  runTheseT :: m (These e a)
}

TheseT是一个实例Monad通过以下方式：

instance Functor m => Functor (TheseT e m) where
  fmap f (TheseT m) = TheseT (fmap (fmap f) m)

instance (Monoid e, Applicative m) => Applicative (TheseT e m) where
  pure x = TheseT (pure (pure x))
  TheseT f <*> TheseT x = TheseT (liftA2 (<*>) f x)

instance (Monoid e, Monad m) => Monad (TheseT e m) where
  return x = TheseT (return (return x))
  m >>= f = TheseT $ do
    t <- runTheseT m
    case t of
      This  e   -> return (This e)
      That    x -> runTheseT (f x)
      These _ x -> do
        t' <- runTheseT (f x)
        return (t >> t')  -- this is where errors get concatenated

Applicative积累ErrorT

免责声明：这种方法更容易适应，因为您已经在m (Either e a)newtype 包装器，但它仅适用于Applicative环境。

如果实际代码只使用Applicative我们可以摆脱的界面ErrorT改变它的Applicative实例。

让我们从非变压器版本开始：

data Accum e a = ALeft e | ARight a

instance Functor (Accum e) where
  fmap f (ARight x) = ARight (f x)
  fmap _ (ALeft e)  = ALeft e

instance Monoid e => Applicative (Accum e) where
  pure = ARight
  ARight f <*> ARight x = ARight (f x)
  ALeft e  <*> ALeft e' = ALeft (e <> e')
  ALeft e  <*> _        = ALeft e
  _        <*> ALeft e  = ALeft e

定义时请注意<*> we know如果双方都是ALefts，因此可以执行<>。如果我们尝试定义相应的Monad我们失败的例子：

instance Monoid e => Monad (Accum e) where
  return = ARight
  ALeft e >>= f = -- we can't apply f

所以唯一的Monad我们可能有的例子是Either。但是之后ap不等于<*>:

Left a <*>  Left b  ≡  Left (a <> b)
Left a `ap` Left b  ≡  Left a

所以我们只能使用Accum as Applicative.

现在我们可以定义Applicative变压器基于Accum:

newtype AccErrorT e m a = AccErrorT {
  runAccErrorT :: m (Accum e a)
}

instance (Functor m) => Functor (AccErrorT e m) where
  fmap f (AccErrorT m) = AccErrorT (fmap (fmap f) m)

instance (Monoid e, Applicative m) => Applicative (AccErrorT e m) where
  pure x = AccErrorT (pure (pure x))
  AccErrorT f <*> AccErrorT x = AccErrorT (liftA2 (<*>) f x)

注意AccErrorT e m本质上是Compose m (Accum e).

EDIT:

AccError被称为AccValidation in validation package.