使用Git显示所有一级后代分支

如何获取当前 HEAD 的一级后代分支的列表？

我可以通过以下方式获取整棵树的列表：

git log --graph --abbrev-commit --pretty=decorate --branches

这使

* 2eff4a7... (refs/heads/issue-8351) Added a factory factory factory.
* 2e387aa... Refactored all of the factory factories.
| * b3fad52... (refs/heads/issue-8354) Moved the baz out of the constructor.
|/
| * f4cf3fe... (refs/heads/experimental) quuz looking good
| * 1d276b9... Risky fix to replace the quux with the quuz.
| * d6b0222... (refs/heads/issue-7559) Fixed the quux in the foo.
|/
| * 3f4cfff... (refs/heads/dev) wip
|/
* 76f493f... (refs/heads/master) SVN 30192

但我只想获得当前分支的第一级子级的简单列表，就像这个例子master:

dev
issue-7559
issue-8354
issue-8351

如果我在树枝上issue-7559我只会看到：

experimental

我该怎么办？

您可以按如下方式进行操作。

首先是通常的序言：

#! /usr/bin/perl

use warnings;
use strict;

Use git for-each-ref收集每个引用的 SHA-1 和名称：

sub refs {
  open my $fh, "-|", "git", "for-each-ref",
                            "--format=%(objectname)\t%(refname:short)"
    or die "$0: failed to run git for-each-ref";

  my %ref2sha;
  while (<$fh>) {
    chomp;
    my($sha,$ref) = split /\t/;
    $ref2sha{$ref} = $sha;
  }

  \%ref2sha;
}

如果提交是子项HEAD，可从以下位置到达的提交集HEAD排除从有问题的提交中可到达的所有内容就是空集。我们可以检查这种关系git rev-list.

sub is_child {
  my($ref) = @_;

  # git rev-list ^dev master
  my $refs = `git rev-list ^$ref HEAD -- 2>&1`;
  die "$0: git rev-list-failed.\n$refs" if $?;

  $refs !~ /\S/;
}

对于每个 ref 的后代HEAD但它不等于HEAD，我们检查来自的路径HEAD到该参考使用git log。如果路径包含另一个分支的尖端，则 ref 不能是第一级子级。

所有这场挑战的幸存者都是一级子弟。

chomp(my $head = `git rev-parse HEAD 2>&1`);
die "$0: git rev-parse failed.\n$head" if $?;

my $ref2sha = refs;
my %headsha = reverse %$ref2sha;

REF:
foreach my $ref (keys %$ref2sha) {
  my $refsha = $ref2sha->{$ref};

  next if $refsha eq $head || !is_child $ref;

  my @log = `git log --pretty=format:%H ..$ref 2>&1`;
  die "$0: git log failed.\n@log" if $?;
  for (@log) {
    chomp;
    next if $_ eq $refsha;
    next REF if exists $headsha{$_};
  }

  print $ref, "\n";
}