拆分列表并从子列表中求和？

我正在为我的 Haskell 课程寻找解决方案。

我有一个数字列表，我需要为列表的每个部分返回 SUM 。部分除以 0。我需要使用 FOLDL 函数。

Example:
初始列表：[1,2,3,0,3,4,0,5,2,1]
子列表 [[1,2,3],[3,4],[5,2,1]]
结果 [6,7,7]

我有一个在初始列表中查找 0 的函数：

findPos list = [index+1 | (index, e) <- zip [0..] list, e == 0] 

（返回示例中的初始列表 [4,6]）

以及使用 FOLDL 求和的函数：

sumList list = foldl (+) 0 list

但我完全没能把它放在一起:/

---- 我的解决方案
最后我发现了一些与你们建议完全不同的东西。
我花了一整天的时间才做到：/

groups :: [Int] -> [Int]
groups list = [sum x | x <- makelist list]

makelist :: [Int] -> [[Int]]
makelist xs = reverse (foldl (\acc x -> zero x acc) [[]] xs)  

zero :: Int -> [[Int]] -> [[Int]]
zero x acc | x == 0 = addnewtolist acc
           | otherwise = addtolist x acc

addtolist :: Int -> [[Int]] -> [[Int]]
addtolist i listlist = (i : (head listlist)) : (drop 1 listlist)

addnewtolist :: [[Int]] -> [[Int]]
addnewtolist listlist = [] : listlist

我将给您一些提示，而不是完整的解决方案，因为这听起来像是一项家庭作业。

我喜欢你建议的步骤分解。对于第一步（从带有零标记的数字列表到列表列表），我建议进行显式递归；尝试这个模板：

splits []     = {- ... -}
splits (0:xs) = {- ... -}
splits (x:xs) = {- ... -}

你也可以滥用groupBy如果你小心的话。

对于第二步，看起来你已经快完成了；您需要的最后一步是查看map :: (a -> b) -> ([a] -> [b])函数，它接受一个普通函数并在列表的每个元素上运行它。

作为一项奖励练习，您可能需要考虑如何将整个事情作为一次折叠完成。如果您跟踪各种参数的类型，这是可能的 - 甚至不是太困难foldr/foldl必须是！

问题改变后的补充：

既然看起来你已经找到了解决方案，我现在可以放心地剧透一下。 =)

我建议了两种可能的实现方式；一种是按照你的建议一步步进行，另一种是一次性完成。一步一步可能如下所示：

splits []     = []
splits (0:xs) = [] : splits xs
splits (x:xs) = case splits xs of
    []       -> [[x]]
    (ys:yss) -> ((x:ys):yss)

groups' = map sum . splits

或者像这样：

splits' = groupBy (\x y -> y /= 0)
groups'' = map sum . splits'

一次性版本可能如下所示：

accumulate 0 xs     = 0:xs
accumulate n (x:xs) = (n+x):xs

groups''' = foldr accumulate [0]

为了检查您是否理解这些内容，您可以尝试以下一些练习：

• What do splits and splits'做与[1,2,3,0,4,5]? [1,2,0,3,4,0]? [0]? []？在 ghci 中检查您的预测。
• 预测四个版本中的每一个的内容groups（包括你的）输入的输出，例如[] or [1,2,0,3,4,0]，然后在 ghci 中测试您的预测。
• Modify groups'''展示其他实现之一的行为。
• Modify groups''' to use foldl代替foldr.