SearchBuf soWholeWord 意外输出

测试时StrUtils.SearchBuf with [soWholeWord,soDown]选项，出现了一些意想不到的结果。

program Project1;

Uses
  SysUtils,StrUtils;

function WordFound(aString,searchString: String): Boolean;
begin
  Result := SearchBuf(PChar(aString),Length(aString), 0, 0, searchString, 
    [soWholeWord,soDown]) <> nil;
end;

Procedure Test(aString,searchString: String);
begin
  WriteLn('"',searchString,'" in "',aString,'"',#9,' : ',
    WordFound(aString,searchString));
end;

begin
  Test('Delphi','Delphi');   // True
  Test('Delphi ','Delphi');  // True
  Test(' Delphi','Delphi');  // False
  Test(' Delphi ','Delphi'); // False
  ReadLn;
end.

Why are ' Delphi' and ' Delphi '不考虑一个完整的单词？

那么反向搜索呢？

function WordFoundRev(aString,searchString: String): Boolean;
begin
  Result := SearchBuf(PChar(aString),Length(aString),Length(aString)-1,0,searchString, 
    [soWholeWord]) <> nil;
end;

Procedure TestRev(aString,searchString: String);
begin
  WriteLn('"',searchString,'" in "',aString,'"',#9,' : ',
    WordFoundRev(aString,searchString));
end;

begin
  TestRev('Delphi','Delphi');   // False
  TestRev('Delphi ','Delphi');  // True
  TestRev(' Delphi','Delphi');  // False
  TestRev(' Delphi ','Delphi'); // True
  ReadLn;
end.

我对此完全没有任何意义。除了该功能有缺陷之外。

XE7、XE6 和 XE 的结果相同。

Update

QC127635 StrUtils.SearchBuf 因 [soWholeWord] 选项而失败

对我来说这看起来像是一个错误。这是执行搜索的代码：

while SearchCount > 0 do
begin
  if (soWholeWord in Options) and (Result <> @Buf[SelStart]) then
    if not FindNextWordStart(Result) then Break;
  I := 0;
  while (CharMap[(Result[I])] = (SearchString[I+1])) do
  begin
    Inc(I);
    if I >= Length(SearchString) then
    begin
      if (not (soWholeWord in Options)) or
         (SearchCount = 0) or
         ((Byte(Result[I])) in WordDelimiters) then
        Exit;
      Break;
    end;
  end;
  Inc(Result, Direction);
  Dec(SearchCount);
end;

每次绕while循环我们检查是否soWholeWord位于选项中，然后前进到下一个单词的开头。但我们只有在以下情况下才会这样做：

Result <> @Buf[SelStart]

Now, Result是缓冲区中的当前指针，是匹配的候选者。因此，此测试检查我们是否位于正在搜索的字符串的开头。

此测试的含义是，如果搜索的字符串以非字母数字文本开头，则我们无法前进到第一个单词的开头。

现在，您可能决定删除以下测试

Result <> @Buf[SelStart]

但是如果您这样做，您会发现您不再匹配位于字符串开头的单词。所以你只会以不同的方式失败。处理这个问题的正确方法是确保FindNextWordStart如果我们位于字符串的开头，并且那里的文本是字母数字，则不会前进。

我猜原作者的代码是这样写的：

if (soWholeWord in Options) then
  if not FindNextWordStart(Result) then Break;

然后他们发现字符串开头的单词不匹配，并将代码更改为：

if (soWholeWord in Options) and (Result <> @Buf[SelStart]) then
  if not FindNextWordStart(Result) then Break;

没有人测试过如果字符串以非字母数字文本开头会发生什么。

像这样的事情似乎可以完成工作：

if (soWholeWord in Options) then
  if (Result <> @Buf[SelStart]) or not Result^.IsLetterOrDigit then
    if not FindNextWordStart(Result) then Break;