使用存储在注册表中的版本号在 Inno Setup 中检测并卸载旧版本的应用程序

我有一个安装程序在 Windows 注册表中写入此行

[Registry]
Root: "HKCU"; Subkey: "SOFTWARE\W117GAMER"; ValueType: string; ValueName: "DSVersionL4D2"; ValueData: "{#MyAppVersion}"

考虑到{#MyAppVersion}在安装程序时定义并写入

#define MyAppVersion "2.7"

我不断更新安装程序，这就是为什么有些人有旧的安装，当他们更新时，冲突的旧文件被合并，以免卸载以前的版本，有一些方法可以在开始安装之前读取此注册表。

• 第一种情况：如果用户有旧版本，请将其卸载并 安装新版本
• 第二种情况：如果用户有相同的版本，告诉他们他们
  已安装最新版本并取消安装
• 第三种情况：如果用户已经安装了某个版本并且打算
  安装旧版本，告诉他们他们已经拥有最新版本 程序版本

我读过以前的帖子，但它们只适用于程序的“GUID”或“appID”，尝试修改一些代码行，但我什么也得不到，如果有人可以帮助我，我提前谢谢你，对不起我的英语我使用翻译 我来自拉丁美洲

如何检测旧安装并提供删除？

Inno Setup：如何自动卸载以前安装的版本？

随着使用RegQueryStringValue功能 and CompareVersion函数来自比较 Inno Setup 中的版本字符串（你的问题），你可以这样做：

#define MyAppVersion "2.6"

[Code]

function InitializeSetup(): Boolean;
var
  InstalledVersion: string;
  VersionDiff: Integer;
begin
  Result := True;
  if not RegQueryStringValue(
           HKCU, 'Software\My Program', 'DSVersionL4D2', InstalledVersion) then
  begin
    Log('No installed version detected');
  end
    else
  begin
    Log(Format('Found installed version %s', [InstalledVersion]));
    VersionDiff := CompareVersion(InstalledVersion, '{#MyAppVersion}');
    if VersionDiff < 0 then
    begin
      MsgBox(
        Format('You have an old version %s installed, will uninstall it.', [
          InstalledVersion]),
        mbInformation, MB_OK);
      { Uninstall old version here }
    end
      else
    if VersionDiff = 0 then
    begin
      MsgBox(
        'You have this version installed already, cancelling installation.',
        mbInformation, MB_OK);
      Result := False;
    end
      else
    begin
      MsgBox(
        Format(
          'You have newer version %s installed already, ' +
            'cancelling installation.', [InstalledVersion]),
        mbInformation, MB_OK);
      Result := False;
    end;
  end;
end;

只需插入问题中链接的一些答案中的卸载代码即可。

但请注意，您不需要编写自己的版本注册表值。有DisplayVersion, VersionMajor and VersionMinor在标准卸载注册表项中。