XSLT 1.0 无法翻译撇号

我的 XML 中有以下内容：

<MyElement> Cats&amp;apos; eyes </ MyElement >

当我在 XSLT 1.0 中使用以下代码时：

<xsl:value-of select="MyElement" />

输出是

Cats' eyes 

但我想得到

Cats’ eyes

I tried

<xsl:value-of select='translate(MyElement, "&amp;apos; ", "&apos; ")'  />

但这并没有成功，结果是ca'ey与一些消除了人物！！！！

任何想法？

Thanks

您的第一个问题是您的内容似乎已被“双重转义”。撇号的实体是', not '.

您尝试将字符替换为translate()不起作用，因为它的工作方式与您的预期不同。它不是查找/替换方法。您在第二个参数中指定字符列表，然后在第三个参数中指定将每个字符转换为的相应字符。如果第三个参数的字符列表中没有对应的字符，则将其删除。

您将需要使用递归模板执行字符替换。

例如：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:template match="/">
        <xsl:call-template name="replace-string">
            <xsl:with-param name="text" select="MyElement"/>
            <xsl:with-param name="replace" select="'&amp;apos;'"/>
            <xsl:with-param name="with" select='"&apos;"'/>
        </xsl:call-template>
    </xsl:template>

    <xsl:template name="replace-string">
        <xsl:param name="text"/>
        <xsl:param name="replace"/>
        <xsl:param name="with"/>
        <xsl:choose>
            <xsl:when test="contains($text,$replace)">
                <xsl:value-of select="substring-before($text,$replace)"/>
                <xsl:value-of select="$with"/>
                <xsl:call-template name="replace-string">
                    <xsl:with-param name="text"
                        select="substring-after($text,$replace)"/>
                    <xsl:with-param name="replace" select="$replace"/>
                    <xsl:with-param name="with" select="$with"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$text"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

当然，对于 XSLT 2.0，您可以只使用代替（）功能：

<xsl:sequence select='replace(MyElement, "&amp;apos;", "&apos;")'/>