我在我的 twebbrowser 中有以下选择
<Select name="ship_to_method">
<option value="1941">Royal Mail Standard Delivery at £1.45 </option>
<option value="1942">Courier Standard Delivery at £4.64 </option>
<option value="1943">Royal Mail Priority Delivery at £1.66 </option>
<option value="1944">Courier Priority Delivery at £5.15 </option>
</select>
选项的数量和值动态变化，
我怎样才能将选项放入数组中，这样我就有了..
option_ids=(1941,1942,1943,1944);
option_texts=("Royal Mail Standard Delivery at £1.45","Courier Standard Delivery at £4.64","Royal Mail Priority Delivery at £1.66","Courier Priority Delivery at £5.15");
如果有人有任何代码可以分享那就太好了！
非常感谢
Stu
Using a TWebBrowser named Wb您可以通过以下方式获取您的 ID 和短信：
uses MSHTML;
var
Disp: IDispatch;
SelEl: IHTMLSelectElement;
i: Integer;
OptionEl: IHTMLOptionElement;
option_ids: array of WideString;
option_texts: array of WideString;
begin
// load test web page containing your SELECT
Wb.Navigate('c:\temp\select.htm');
// wait for browser to finish loading
while Wb.ReadyState <> READYSTATE_COMPLETE do
Application.ProcessMessages;
// search the document for the SELECT element with the given name
Disp:=(Wb.ControlInterface.Document as IHTMLDocument2).all.item('ship_to_method', EmptyParam);
// EDIT: the following two lines are demonstrating how to get the element with focus
// simulate user selection by setting focus to SELECT element
(Disp as IHTMLElement2).focus;
// now ask document for active element which should be the SELECT element
Disp:=(Wb.ControlInterface.Document as IHTMLDocument2).activeElement;
// basic error checking and acquiring of IHTMLSelectElement interface which is needed to access single OPTIONs within the SELECT
if Assigned(Disp) and Supports(Disp, IHTMLSelectElement, SelEl) then
begin
// prepare array
SetLength(option_ids, SelEl.length);
SetLength(option_texts, SelEl.length);
// get OPTIONs from SELECT
for i:=0 to SelEl.length-1 do
begin
OptionEl := SelEl.Item(i,EmptyParam) as IHTMLOptionElement;
// voila - read value and text of option element, store in arrays
option_ids[i] := OptionEl.Value;
option_texts[i] := OptionEl.Text;
end;
end;
// option_ids now contains your IDs
// option_texts now contains your texts
end;
编辑：添加option_texts以及。
Edit2：这是网页“select.htm”：
<html>
<head>
</head>
<body>
<Select name="ship_to_method">
<option value="1941">Royal Mail Standard Delivery at £1.45 </option>
<option value="1942">Courier Standard Delivery at £4.64 </option>
<option value="1943">Royal Mail Priority Delivery at £1.66 </option>
<option value="1944">Courier Priority Delivery at £5.15 </option>
</select>
</body>
</html>
本文内容由网友自发贡献，版权归原作者所有，本站不承担相应法律责任。如您发现有涉嫌抄袭侵权的内容，请联系:hwhale#tublm.com(使用前将#替换为@)
