列表框（JList）不会从自定义 ListModel 动态更新

我正在使用 Seesaw 在 Clojure 中开发 GUI 应用程序，并且在我的自定义 ListModel 更新时无法更新列表框（Java 中的 JList）。

这是我的一些代码：

(deftype ActionHistoryListModel
  [^{:unsynchronized-mutable true} listeners
   ^{:unsynchronized-mutable true} listening-to]

  ListModel
  (addListDataListener [this listener]
    (set! listeners (conj listeners listener)))
  (removeListDataListener [this listener]
    (set! listeners (remove #(= % listener) listeners)))
  (getSize [this] 
    (get-in (deref listening-to) [:count]))
  (getElementAt [this index]
    (get-in (deref listening-to) [:actions index]))

  ActionHistoryListModelProtocol
  (listen-to [this r]
    (do
      (set! listening-to r)
      (add-watch r this (fn [_ _ _ new-state] (.notify this new-state)))))
  (notify [this new-state]
    (let [action ((meta new-state) :last-action)
          const  (cond
            (= action :create) INTERVAL_ADDED
            (= action :update) CONTENTS_CHANGED)
          index  (last ((meta new-state) :action-target))
          event  (ListDataEvent. this const index index)
          notification (cond
            (= action :create) #(.intervalAdded % event)
            (= action :update) #(.contentsChanged % event))
          ]
      (. (.. System out) print (str "Index: " index "\n" "Event: " event "\n"))
      (map #(invoke-later (notification %)) listeners)))
  )

(defn make-action-history-list-model []
  (ActionHistoryListModel. #{} nil))

(def ahlm (make-action-history-list-model))
(.listen-to ahlm action-history)

(def undo-list (listbox :model ahlm))

; then put list in frame...

where action-history is a ref.

它已经到了应该更新列表的地步，因为System.out.print正在发生，但列表框不想更新

关于可能出什么问题有什么想法吗？是否与使用 EDT 和手表回调的混合有关？

如果需要更多代码，请告诉我。

自定义模型总是很棘手，尤其是在事件通知方面，因此很难说它的效果如何。也就是说，我对为什么没有通知的最好猜测是您使用map这是懒惰的，即你的最后一个形式notify方法实际上并没有做任何事情。试试这个：

(doseq [listener listeners] 
  (invoke-later (notification listener)))

祝你好运。