以语义方式填充元组列表

我正在编写一段代码，我必须处理元组列表，其中“键”的顺序和名称（fst元组的 s）匹配某个模板。我通过验证并（如果需要）根据输入生成有效列表来实现容错。

这是我的意思的一个例子：

给定密钥模板，["hello", "world", "this", "is", "a", "test"]，和一个列表[("hello", Just 1), ("world", Just 2), ("test", Just 3)]，将其传递给我的函数validate会导致验证失败 - 因为键的顺序和值与模板不匹配。

验证失败后，我想生成一个新列表，如下所示[("hello", Just 1), ("world", Just 2), ("this", Nothing), ("is", Nothing), ("a", Nothing), ("test", Just 3)].

我尝试使用（不完整的）列表理解来执行最后一步：

[(x, y) | x <- template, y <- l]

（显然，这缺少将空条目替换为Nothings，并在输入类型为假设的情况下工作[(String, Maybe Int)]).

执行此操作最简单的语义方法是什么？

你本质上想要map字符串列表的函数（您称之为“模板”），即该函数

• 需要一个字符串xs,
• returns
  • (xs, Just n)如果一个整数n关联到xs在您的“要验证的列表”中，
  • (xs, Nothing)否则。

这是一种可能的方法：

import Data.List     ( lookup )
import Control.Monad ( join )

consolidate :: [String] -> [(String, Maybe Int)] -> [(String, Maybe Int)]
consolidate temp l = map (\xs -> (xs, join $ lookup xs l)) temp

但是，如果您构建一个，您将获得更快的查找速度Map保存关联列表的键值对（“要验证的列表”）：

import qualified Data.Map as M
import Data.Maybe (maybe)

consolidate :: [String] -> [(String, Maybe Int)] -> [(String, Maybe Int)]
consolidate temp l = map (\cs -> (cs, M.lookup cs $ fromList' l)) temp

fromList' :: Ord a => [(a, Maybe b)] -> M.Map a b
fromList' xs = foldr insertJust M.empty xs

insertJust :: Ord a => (a, Maybe b) -> M.Map a b -> M.Map a b
insertJust (xs, maybeVal) mp = maybe mp (\n -> M.insert xs n mp) maybeVal

In GHCi:

λ> let myTemplate = ["hello", "world", "this", "is", "a", "test"]
λ> let myList = [("hello", Just 1), ("world", Just 2), ("test", Just 3)]
λ> consolidate myTemplate myList 
[("hello",Just 1),("world",Just 2),("this",Nothing),("is",Nothing),("a",Nothing),("test",Just 3)]