你不能使用int 10h (0e)当您将位收集到时用于 char 输出bx. That int调用需要bl设置为文本的前景色和bh指向文本页。
Also in bx您将计算的是个数，而不是输入的数字。在调试器（你的原始代码）中尝试一下，在后面放置断点loop并输入（盲目地，如果它没有显示）例如“1100110011001100”，bx将是 8 （如果有些人我可能是错的int调用销毁bx，我没有运行它，只是在我的脑海中运行）。
所以为了修复你的输入部分我会去int 21h, 2相反，用于显示字符，如下所示（还修复了结果的累积bx):
; read 16 bits from keyboard ('0'/'1' characters accepted only)
mov cx, 16 ; loop goes 16 Times because I need 16 bit binary input
xor bx, bx ; result number (initialized to zero)
read:
mov ah, 10h
int 16h ; read character from keyboard
cmp al, '0'
jb read ; ASCII character below '0' -> re-read it
cmp al, '1'
ja read ; ASCII character above '1' -> re-read it
mov dl,al ; keep ASCII for output in DL
shr al,1 ; turn ASCII '0'(0x30)/'1'(0x31) into CF=0/1 (Carry Flag)
rcl bx,1 ; enrol that CF into result from right (and shift previous bits up)
mov ah,2 ; output character in DL on screen
int 21h
loop read ; read 16 bits
我没有检查其余的代码，因为如果我检查的话，我会非常渴望完全重写它，所以暂时只保留输入部分。
调试器应该允许您每次单步执行一条指令（或者在任何行上放置断点，然后运行到该行为止）。
因此，您可以在每个步骤之后检查寄存器和内存中的值。
例如，如果您将断点放在前面add bx,ax在原始代码中，您应该能够在调试器中读取（在按下“1”键并且调试器在add) that:
ax为 1（根据按下的键），并且bx从 0 到“1”按键次数（在进一步的迭代中）。
在按下四次“1”键之后，您应该很明显，bx等于4 (0100以二进制表示）距离很远1111，因此有些东西不能按您想要的方式工作，您必须从“我想在那里写的内容”重新调整为“我真正写的内容”，再次阅读您的代码并了解需要更改哪些内容才能获得预期结果。
在您的情况下，例如添加指令shl bx,1在之前add将解决这种情况（将旧位“向上”移动一个位置，将最低有效位设置为零，即“准备好添加斧头”）。
继续努力尝试调试器的东西，如果不弄清楚调试器，在汇编中几乎不可能做任何事情。或者在这里继续问，看到什么，不明白什么。这对于汇编编程来说确实是绝对必要的。
其他选择就是在你的头脑中“模拟”CPU，并运行带有帮助注释的屏幕上的指令（我强烈建议纸质的，PC 不知何故不适合我）。这比使用调试器要困难和繁琐得多。可能需要数周/数月的时间才能开始“模拟”而不会出现太多错误，因此您通常会在第一次尝试时发现错误。从好的方面来说，这将使您深入了解 CPU 的工作原理。
关于第二部分（数字到十六进制字符串的转换）。
我将尽力帮助您理解您手头的内容，并从原始代码中找出一些错误来演示如何使用它。
所以你有 16 位数字，例如：
1010 1011 1100 1101 (unsigned decimal 43981)
我在每组 4 位之间放置了空格（很少称为“半字节”），因为有一个有趣的事实。每个半字节准确地形成单个十六进制数字。所以上面的数字是十六进制的：
A B C D (10, 11, 12, 13)
检查每个十六进制数字与上面 4 位的对应关系。
因此，您想要的是将原始 16b 值分解为四个 4 位数字，从最高有效位到最低有效位（b12-b15、b8-b11、b4-b7、b0-b3 => 16 位数字中的特定位：“b15 b14 b13 ... b2 b1 b0”）。
每个这样的数字的值为 0-15（因为它们是 4 位，并且使用所有可能的组合），因此您需要将其转换为 ASCII 字符'0'-'9'对于值 0-9，以及'A'-'F'对于值 10-15。
每个转换后的值都存储到内存缓冲区的下一个字节位置，因此最终它们形成字符串“ABCD”。
这听起来可能“显而易见”，但它是第 2 部分内部计算的完整描述，因此请确保您真正理解每个步骤，以便您可以随时对照此检查代码并搜索差异。
现在我将向您展示我在第二部分中看到的一些错误，并尝试将其与上面的“理论”联系起来。
首先是数据和结构：
HEX_Out DB "00", 13, 10, '$'
这编译为字节：'0', '0', 13, 10, '$' (or 30 30 0D 0A 24当以十六进制字节查看时）。
如果你写'A', 'B', 'C', 'D'超过它，你能发现问题吗？
您只为数字保留了两个字节（通过“00”），但您写入了四个字节，所以也13 and 10将被覆盖。
现在关于IntegerToHexFromMap，从代码看来你不明白什么and and shr确实（搜索位运算解释).
您为前三个字符提取相同的 b4-b7 位bx (copy of ax)，然后对于第四个字母，您提取位 b0-b3。因此，这是您尝试将 8 位转换代码扩展到 16 位，但您没有提取正确的位。
我将尝试对它的第一部分进行广泛的评论，让您了解您做了什么。
; bx = 16 bit value, mark each bit as "a#" from a0 to a15
and bx, 00FFh
; the original: a15 a14 a13 ... a2 a1 a0 bits get
; AND-ed by: 0 0 0 ... 1 1 1
; resulting into bx = "a7 to a0 remains, rest is cleared to 0"
shr bx, 1
; shifts bx to right by one bit, inserting 0 into top bit
; bx = 0 0 0 0 0 0 0 0 0 a7 a6 a5 a4 a3 a2 a1 (a0 is in CF)
shr bx, 1
; shifts it further
; bx = 0 0 0 0 0 0 0 0 0 0 a7 a6 a5 a4 a3 a2 (a1 is in CF)
shr bx, 1
; bx = 0 0 0 0 0 0 0 0 0 0 0 a7 a6 a5 a4 a3 (a2 ...)
shr bx, 1
; bx = 0 0 0 0 0 0 0 0 0 0 0 0 a7 a6 a5 a4
; so if bx was value 0x1234 at the beginning, now bx = 0x0003
; conversion to ASCII and write is OK.
因此，您将位 b4-b7 作为第一个字符，但需要位 b12-b15。我希望你能完全理解这一点，我知道一开始你可能会感到困惑，哪一位是哪一位，为什么有时右边有一些东西，然后左边有一些东西。
Bits are usually named from least significant (value 20 = 1, so I call it "b0") to most significant (value 215 = 32768 in case of 16 bit number, I call it "b15").
但由于数字原因，位是从最高有效位到最低有效位（以二进制数形式）写入的，因此“左侧”的位以 b15 开头，“右侧”的位以 b0 结尾。
向右移动意味着移动b_i to b_(i-1)，这实际上使其价值减半，所以shr value,1也可以被视为无符号除以二。
向左移动是从b_i to b_(i+1)，有效地将值乘以二（指令shl and sal，两者都产生相同的结果，因为两者的 b0 都设置为零）。
sar是“算术”右移，保持最高有效位的值完整（符号位），所以对于-1（所有位均为1）它将再次产生-1，对于所有其他数字，它的工作原理是有符号除以二。
顺便说一句，从 80286 CPU 开始你就可以使用shr bx,4（也可以看作除以 16 = 2*2*2*2）。你真的被迫为 8086 编码吗？那么可能值得加载cl与 4 并做shr bx,cl，而不是四个shr bx,1。四行相同的台词让我很恼火。
另外，如果您已经了解了什么and是的，这对你来说一定看起来很荒谬：
and bx, 00FFh ; why not 0Fh already here???
and bl, 0Fh
现在考虑一下如何提取第一个字符的位 b12-b15 以及如何修复您的问题IntegerToHexFromMap.
最后，我将向您展示如何重写它以使代码非常短，我的意思是源代码，但也包括二进制大小。 （为了性能，我会编写不同的代码，而不是针对 8086，但这个应该可以在 8086 上运行）：
警告 - 尝试按照上述建议自行修复您的版本。只有当你有固定版本时，然后看看我的代码，作为 30 年前如何编写某些东西的新想法的灵感。另外，如果您正在做学校作业，请确保您可以说出有关的所有内容XLAT来自头部的指示，因为作为一名讲师，我会对任何使用此代码的学生高度怀疑，它是完整的历史，并且由于编译器不使用它，很明显代码是由人类编写的，并且可能是有经验的人。
IntegerToHexFromMap PROC
; ax = number to convert, di = string buffer to write to
; modifies: ax, bx, cx, dx, di
; copy of number to convert (AX will be used for calculation)
mov dx, ax
; initialize other helpful values before loop
mov bx, OFFSET HEX_Map ; Pointer to hex-character table
mov cx, 00404h ; for rotation of bits and loop counter
; cl = 4, ch = 4 (!) Hexadecimal format allows me
; to position the two "4" easily in single 16b value.
FourDigitLoop: ; I will do every digit with same code, in a loop
; move next nibble (= hexa digit) in DX into b0-b3 position
rol dx, cl
; copy DX b0-b3 into AL, clear other bits (AL = value 0-15)
mov al, dl
and al, 0Fh
; convert 0-15 in AL into ASCII char by special 8086 instruction
; designed to do exactly this task (ignored by C/C++ compilers :))
xlat
; write it into string, and move string pointer to next char
mov [di],al
inc di
; loop trough 4 digits (16 bits)
dec ch
jnz FourDigitLoop
ret
IntegerToHexFromMap ENDP
如果你只是使用这段代码而不理解它是如何工作的，上帝会杀死一只小猫......你不希望这样，对吧？
最后免责声明：我没有任何 16 位 x86 环境，所以我在没有测试的情况下编写了所有代码（我只是有时尝试编译它，但语法必须类似于 NASM，所以我不会为这个 MASM/ 这样做） TASM/emu8086 来源）。因此，可能存在一些语法错误（甚至可能是功能错误？:-O），如果您无法使其工作，请发表评论。
