我想将变量参数传递给外部 SQL 文件（带有 SQL*Plus 的 PL/SQL）

我已经在这个论坛和谷歌上搜索了我的问题的答案，但我找不到我的挑战的具体答案。这就是为什么我在这里问这个问题，希望能得到你们其中一个人的答复。

我想使用多个 SQL 文件，而一个 SQL 文件是使用参数执行其他 SQL 文件的控制文件。 该文件名为：startup.sql

我有一个包含所有值的表（不要介意列的名称，我为我的帖子更改了它们）。

create table control (
  S varchar2(15) not null,
  N varchar2(25 char) not null, 
  B varchar2(25 char) not null, 
  Acheck varchar2(25 char) not null, 
  Adcheck varchar2(25) not null, 
  Blu varchar2(25) not null,
  ADB varchar2(25)
)

插入以下内容之一的位置（还有更多条目，但一个足以向您展示工作方式）：

    insert into control (S,N,B,Acheck,Adcheck,Blu,ADB)
       values('Test','B','J','J','N','N', '');

我的控制文件如下所示：

set escape on
set serveroutput on
SET DEFINE ON

declare
  cursor c_lees_control is
    select S, N, B, Acheck, Adcheck, Blu, ADB
  from control

  v_s           varchar2(30);
  v_b           varchar2(30);
  v_blu     varchar2(30);

begin

  for r_lees_control in c_lees_control
  loop
    v_s := r_lees_control.S;
    v_b := r_lees_control.B;
    v_blu := r_lees_control.Blu;

    if v_b = 'J' then
      --Also tried this.
      --@C:/Temp/uitvoer.sql $v_s $v_blu
      @C:/Temp/uitvoer.sql %v_s% %v_blu%
end if;
  end loop;
end;
/

在我的 uitvoer.sql 中，我有一个如下变量：

    variable_s := '&&1';
    variable_blu := '&&2';

现在正在发生以下情况。 我启动SQL另外（使​​用我所有的凭据），我启动我的控制文件（control.sql）。 在SQL的输出中另外还说明了以下内容：

old 89:        s = '&&1';
new 89:        s = '%v_s%';
old 128:       b_lu := '&&2';
new 128:       b_lu := '%v_blu%';

我期待以下内容：

old 89:        s = '&&1';
new 89:        s = 'Test';
old 128:       b_lu := '&&2';
new 128:       b_lu := 'J';

为什么控制文件中的变量没有正确解析到新的 SQL 文件中？

我还发现了以下帖子：如何在 sqlplus 中使用 START 将参数传递给 sql 文件中的 PL/SQL 块？ / 从批处理文件启动 PL/SQL 脚本（带参数）这看起来像是我的挑战，但我不是从批处理文件调用，而是从 sql 文件调用。

我希望有一个人可以帮助我。如果有什么不清楚，我可以尝试进一步解释。

@ is a SQL*Plus 命令，它在 PL/SQL 中没有任何意义。您的脚本在解析时包含在 PL/SQL 块中，您可以看到list缓冲区中的代码。控制块中声明的变量可直接供“包含”代码使用，无需替换。

举个例子，如果uitvoer.sql仅包含：

dbms_output.put_line(v_s);

然后这个控制脚本：

set serveroutput on
declare
  v_s varchar2(10) := 'Test';
begin
  @uitvoer.sql
end;
/

list

生产：

Test

PL/SQL procedure successfully completed.

  1  declare
  2    v_s varchar2(10) := 'Test';
  3  begin
  4  dbms_output.put_line(v_s);
  5* end;

缓冲区中的 PL/SQL 块包含包含的代码，not参考uitvoer.sql。但包含的代码有效，因为它引用了控制脚本中仍在范围内的变量。

如果你想允许控制变量具有不同的名称，允许uitvoer.sql也许要更灵活地调用，那么您仍然可以使用替换变量，但您仍然替换变量名称，而不是其值。例如，用这个uitvoer.sql（请注意，替换变量赋值不会not周围有引号）：

declare
  variable_s varchar2(10);
begin
  variable_s := &&1;
  dbms_output.put_line(variable_s);
end;

并且您的控制脚本传递变量名称：

declare
  v_s varchar2(10) := 'Test';
begin
  @uitvoer.sql v_s
end;
/

You see:

old   7:   variable_s := &&1;
new   7:   variable_s := v_s;
Test

PL/SQL procedure successfully completed.

  1  declare
  2    v_s varchar2(10) := 'Test';
  3  begin
  4  declare
  5    variable_s varchar2(10);
  6  begin
  7    variable_s := &&1;
  8    dbms_output.put_line(variable_s);
  9  end;
 10* end;