在 JWASM/MASM 中 - pshufw 产生错误 A2030：当前 CPU 模式下不接受指令或寄存器

我有以下汇编程序，在编译时出现错误：

.686
.mmx
.model flat,c
.code

MmxAdd  proc
    push ebp
    mov ebp,esp

    mov eax, [ebp+24]        
    cmp eax, AddOpTableCount      
    jae BadAddOp                

    movq mm0,[ebp+8]             
    movq mm1,[ebp+16]       
    jmp [AddOpTable+eax*4]       

MmxPaddb:
    paddb mm0,mm1            
    jmp SaveResult

MmxPaddsb:
    paddsb mm0,mm1               
    jmp SaveResult  

MmxPaddusb:
    paddusb mm0,mm1             
    jmp SaveResult

MmxPaddw:
    paddw mm0,mm1             
    jmp SaveResult

MmxPaddsw:
    paddsw mm0,mm1             
    jmp SaveResult  

MmxPaddusw:
    paddusw mm0,mm1           
    jmp SaveResult

MmxPaddd:                       
    paddd mm0,mm1
    jmp SaveResult

BadAddOp:
    pxor mm0,mm0

SaveResult:
    movd eax,mm0                   
    pshufw mm2,mm0, 01001110b       
    movd edx,mm2                   
    emms                           

    pop ebp
    ret

    align 4                                            

AddOpTable:
    dword MmxPaddb, MmxPaddsb, MmxPaddusb
    dword MmxPaddw, MmxPaddsw, MmxPaddusw
    dword MmxPaddd

AddOpTableCount equ ($-AddOpTable) / size dword

MmxAdd  endp
    end

但每次我尝试使用 JWASM 编译它时，都会收到以下错误：

Mmx_Addition.asm(51) : 错误 A2030: 当前 CPU 模式下不接受指令或寄存器

这是给我错误的指令：

pshufw mm2,mm0, 01001110b

我该如何解决这个问题？

pshufw被认为是SSE(SSE-1)指令。该指令被认为是 MMX 的扩展，又名MMXEXT，要使用它，您必须使用以下命令启用 SSE.xmm指令而不是.mmx。这应该有效：

.686
.xmm
.model flat,c
.code

.xmm也暗示着.mmx所以你不需要两者。如果你同时使用的话.mmx必须先来.xmm。我不建议同时使用两者。

作为 SSE-1 的 MMX 扩展添加的其他指令是：

• PINSRW

  将通用寄存器中的 16 位值插入到四个元素之一（由立即数指定）

• PEXTRW

  将四个元素之一（由立即数指定）提取到通用寄存器

• PMULHU

  将四个 16 位无符号元素相乘，返回每个元素的最高有效 16 位

• PSHUFW

  在 8 位立即数掩码的控制下对 16 位元素进行完全洗牌

• PMOVMSB

  将由字节元素的 MSb 组成的 8 位掩码移至通用寄存器

• PAVGB

  字节元素的平均值 (Di = –(Di+ Si + 1)/2, i = 0…7)

• PAVGW

  16 位元素的平均值 (Di = –(Di + Si + 1)/2, i = 0…3)

• PSADBW

  16 位元素的差值绝对值之和 (D1,0 = Σi=0…3 |Di – Si|)

• PMINSW

  有符号 16 位元素的最小值

• PMINUB

  无符号字节元素的最小值

• PMAXSW

  有符号 16 位元素的最大值

• PMAXUB

  无符号字节元素的最大值

你必须使用.686（或稍后）旁边.xmm for .xmm指令按预期工作。