类似于这个问题（http://stackoverflow.com/q/1333558/948404）我想使用XPath来计算结构中产品的总和，如下所示：
<items>
<item>
<value>1.0</value>
<quantity>3</quantity>
</item>
<item>
<value>2.5</value>
<quantity>2</quantity>
</item>
<!-- ... -->
</items>
是否有一个 XPath 表达式可以计算每个项目的乘积之和value and quantity?
Update:该解决方案必须与 PHP 的 XSLTProcessor 类一起使用，这意味着它可能必须兼容 XSLT 1.0。这就是为什么我尚未接受使用 XSLT 2.0 的两个可能正确的答案。我既无法在 PHP 实现中测试它们，也无法在浏览器中测试它们，也无法在 w3schools 的 Tryit 编辑器 [1] 中测试它们。对不起！
使用此 XPath 2.0 表达式:
sum(/items/item/(value * quantity))
这是一个 XSLT 2.0 转换作为验证:
<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
<xsl:template match="/">
<xsl:sequence select="sum(/items/item/(value * quantity))"/>
</xsl:template>
</xsl:stylesheet>
当此转换应用于提供的 XML 文档时：
<items>
<item>
<value>1.0</value>
<quantity>3</quantity>
</item>
<item>
<value>2.5</value>
<quantity>2</quantity>
</item>
<!-- ... -->
</items>
计算 XPath 表达式并输出计算结果：
8
解释:
在 XPath 2.0 中，定位步骤是合法的
/(expression),
or even
/someFunction(argumentList)
二. XSLT 1.0 解决方案:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:template match="/*">
<xsl:call-template name="sumProducts">
<xsl:with-param name="pNodes" select="item"/>
</xsl:call-template>
</xsl:template>
<xsl:template name="sumProducts">
<xsl:param name="pNodes" select="/.."/>
<xsl:param name="pAccum" select="0"/>
<xsl:choose>
<xsl:when test="not($pNodes)">
<xsl:value-of select="$pAccum"/>
</xsl:when>
<xsl:otherwise>
<xsl:call-template name="sumProducts">
<xsl:with-param name="pNodes" select="$pNodes[position() >1]"/>
<xsl:with-param name="pAccum" select=
"$pAccum + $pNodes[1]/value * $pNodes[1]/quantity"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
当此转换应用于提供的 XML 文档（上面）时，再次生成所需的正确结果:
8
Do note: 此类问题很容易解决FXSL 库。调用的模板是transform-and-sum .
本文内容由网友自发贡献，版权归原作者所有，本站不承担相应法律责任。如您发现有涉嫌抄袭侵权的内容，请联系:hwhale#tublm.com(使用前将#替换为@)
