该命名约定的存在使得 NET 可以确保加载正确的设置。由于您已将管理设置的控制权交给了 NET Framework/VB 应用程序框架,因此它还承担了确保应用程序加载正确的设置集的责任。既然如此,证据哈希就是用来唯一标识一个WindowsApplication1
来自另一个(除其他外)。
I know this is possible to acchieve, because I've seen much .NET applications that can store its userconfig file in a custom Roaming folder
这是有可能的,但我不确定一切都是你得出的结论。我非常怀疑,当许多应用程序可以使用自定义设置类更轻松地将 XML 文件保存到该位置时,它们会经历实现自定义提供程序的麻烦。
简单的解决方案
编写您自己的用户选项类,并自行序列化。例如,可以使用共享/静态方法以很少的代码反序列化类(这恰好使用 JSON):
Friend Shared Function Load() As UserOptions
' create instance for default on new install
Dim u As New UserOptions
If File.Exists(filePath) Then
' filepath can be anywhere you have access to!
Dim jstr = File.ReadAllText(filePath)
If String.IsNullOrEmpty(jstr) = False Then
u = JsonConvert.DeserializeObject(Of UserOptions)(jstr)
End If
End If
Return u
End Function
实现它的应用程序:
UOpt = UserOptions.Load()
之间Pros, 你有完全控制文件的保存位置,并且可以使用您喜欢的任何序列化器。最重要的是,它是simple- 代码比下面介绍的要少得多。
The Cons使用它的代码必须手动加载和保存它们(在应用程序事件中轻松处理),并且没有花哨的设计器。
漫长而曲折的道路:自定义SettingsProvider
一个习俗SettingsProvider
将允许您更改设置的处理、保存和加载方式,包括更改文件夹位置。
这个问题主要集中在更改文件位置。问题是你的应用程序没有一种(干净、简单)的方式与你的应用程序对话。SettingsProvider
以指定文件夹。提供商需要能够在内部解决这个问题,当然还要保持一致。
大多数人想要做的不仅仅是更改所使用的文件夹名称。例如,在尝试过程中,我使用了 SQLite 数据库来代替 XML,它反映了代码使用的结构。这使得加载本地和正确的漫游值变得非常容易。如果始终采用这种方法,代码可能会大大简化,整个升级过程也可能会大大简化。因此,该提供商考虑了一些更广泛的需求。
即使您只想更改文件名,也有两个关键注意事项:
本地与漫游
对提供者进行编码以始终存储在AppData\Roaming
但写出不合格的本地设置那就是不负责任的了。区分它们是一项不应该为了消除文件夹名称中的证据哈希而牺牲的功能。
注:每Setting
可以设置为Roaming
or Local
值:在设置编辑器中选择设置后,打开属性窗格 - 更改Roaming
为真。
这里关于处理定制的(非常)几个问题似乎达成了共识SettingsProvider
将本地和漫游保存到同一文件但不同的部分。这很有意义 - 并且比从 2 个文件加载更简单 - 因此使用的 XML 结构是:
<configuration>
<CommonShared>
<setting name="FirstRun">True</setting>
<setting name="StartTime">15:32:18</setting>
...
</CommonShared>
<MACHINENAME_A>
<setting name="MainWdwLocation">98, 480</setting>
<setting name="myGuid">d62eb904-0bb9-4897-bb86-688d974db4a6</setting>
<setting name="LastSaveFolder">C:\Folder ABC</setting>
</MACHINENAME_A>
<MACHINENAME_B>
<setting name="MainWdwLocation">187, 360</setting>
<setting name="myGuid">a1f8d5a5-f7ec-4bf9-b7b8-712e80c69d93</setting>
<setting name="LastSaveFolder">C:\Folder XYZ</setting>
</MACHINENAME_B>
</configuration>
漫游项目存储在以它们所使用的 MachineName 命名的部分中。保留这些可能有一定的价值<NameSpace>.My.MySettings
节点,但我不确定它的用途是什么。
我删除了SerializeAs
元素,因为它没有被使用。
Versions
如果你调用,什么都不会发生My.Settings.Upgrade
。尽管它是一个Settings
方法,它实际上是在ApplicationSettingsBase
,因此您的提供商不参与其中。
因此,如果自动递增最后一个元素,则使用完整版本字符串作为文件夹的一部分会导致问题。简单的重建将创建一个新文件夹并丢失并孤立旧设置。当没有当前文件时,也许您可以查找并加载先前版本的值。然后也许删除该旧文件/文件夹,因此始终只有一组可能的旧设置。请随意添加大量合并代码。
出于更改数据存储文件夹的主要目的,我删除了版本文件夹部分。使用全局提供程序时,代码会自动累积设置。已删除的设置不会“泄漏”到应用程序中,因为 NET 不会要求其值。唯一的问题是 XML 中会有一个值。
我添加了代码来清除这些。如果您稍后重复使用不同类型的设置名称,这将防止出现问题。旧的保存值Foo
as Decimal
不能与新的一起使用Foo
as Size
例如。如果你从根本上改变一种类型,事情仍然会变得很糟糕。不要那样做。
这个答案user.config 的自定义路径为定制提供商提供了一个非常好的起点。它有一些问题,并且缺少一些东西,但为任何提供商典型的一些步骤和样板代码提供了快速入门指南。由于许多人可能需要进一步修改此处的提供程序,因此可能值得阅读(并投票)。
这里的代码借鉴了该答案的一些内容:
- 添加各种改进
- 提供自定义路径
- 检测设置为漫游的设置
- 文件中的本地和漫游部分
- 正确处理复杂类型,例如
Point
or Size
- 检测并删除已删除的设置
- is in VB
1. 设置
在大多数情况下,您无法增量地编写/调试它 - 在完成之前几乎不会起作用。
- 添加参考
System.Configuration
- 向您的项目添加一个新类
Example:
Imports System.Configuration
Public Class CustomSettingsProvider
Inherits SettingsProvider
End Class
接下来,转到设置设计器并添加一些用于测试的设置。将某些标记为漫游以进行完整测试。然后单击<> View Code
此处显示的按钮:
Everyone loves freehand circles!
显然有两种方法可以实现自定义提供程序。这里的代码将使用您的代码代替My.MySettings
。您还可以通过在“属性”窗格中键入提供程序名称来为每个设置指定自定义提供程序,并跳过此步骤的其余部分。我没有对此进行测试,但这就是它应该如何工作。
为了使用“您”编写的新设置提供程序,它需要与MySettings
使用属性:
Imports System.Configuration
<SettingsProvider(GetType(ElectroZap.CustomSettingsProvider))>
Partial Friend NotInheritable Class MySettings
End Class
顺便说一下,“ElektroZap”是您的根命名空间,“ElektroApp”是您的应用程序名称。构造函数中的代码可以更改为使用产品名称或模块名称。
我们已经完成了该文件;保存并关闭它。
2. 设置提供者
首先,请注意,此 CustomProvider 是通用的,只需将其指定为SettingsProvider
。但它实际上只做了两件事:
通常,在求助于自定义提供商之前,人们会拥有更长的待办事项列表,因此对于许多人来说,这可能只是提供其他事情的起点。请记住,某些更改可能会使其特定于某个项目。
添加的内容之一是支持更复杂的类型,例如Point
or Size
。它们被序列化为不变字符串,以便可以对其进行解析。这意味着什么:
Console.WriteLine(myPoint.ToString())
结果,{X=64, Y=22}
不能直接转换回来Point
缺少一个Parse/TryParse
方法。使用不变字符串形式64,22
允许它转换回正确的类型。原始链接代码仅使用:
Convert.ChangeType(setting.DefaultValue, t);
这适用于简单类型,但不适用于Point
, Font
等等。我不能确定,但我认为这是一个简单的使用错误SettingsPropertyValue.Value
而不是.SerializedValue
.
3. 守则
Public Class CustomSettingsProvider
Inherits SettingsProvider
' data we store for each item
Friend Class SettingsItem
Friend Name As String
'Friend SerializeAs As String ' not needed
Friend Value As String
Friend Roamer As Boolean
Friend Remove As Boolean ' mutable
'Friend VerString As String ' ToDo (?)
End Class
' used for node name
Private thisMachine As String
' loaded XML config
'Private xDoc As XDocument
Private UserConfigFilePath As String = ""
Private myCol As Dictionary(Of String, SettingsItem)
Public Sub New()
myCol = New Dictionary(Of String, SettingsItem)
Dim asm = Assembly.GetExecutingAssembly()
Dim verInfo = FileVersionInfo.GetVersionInfo(asm.Location)
Dim Company = verInfo.CompanyName
' product name may have no relation to file name...
Dim ProdName = verInfo.ProductName
' use this for assembly file name:
Dim modName = Path.GetFileNameWithoutExtension(asm.ManifestModule.Name)
' dont use FileVersionInfo;
' may want to omit the last element
'Dim ver = asm.GetName.Version
' uses `SpecialFolder.ApplicationData`
' since it will store Local and Roaming val;ues
UserConfigFilePath = Path.Combine(GetFolderPath(SpecialFolder.ApplicationData),
Company, modName,
"user.config")
' "CFG" prefix prevents illegal XML,
' the FOO suffix is to emulate a different machine
thisMachine = "CFG" & My.Computer.Name & "_FOO"
End Sub
' boilerplate
Public Overrides Property ApplicationName As String
Get
Return Assembly.GetExecutingAssembly().ManifestModule.Name
End Get
Set(value As String)
End Set
End Property
' boilerplate
Public Overrides Sub Initialize(name As String, config As Specialized.NameValueCollection)
MyBase.Initialize(ApplicationName, config)
End Sub
' conversion helper in place of a 'Select Case GetType(foo)'
Private Shared Conversion As Func(Of Object, Object)
Public Overrides Function GetPropertyValues(context As SettingsContext,
collection As SettingsPropertyCollection) As SettingsPropertyValueCollection
' basically, create a Dictionary entry for each setting,
' store the converted value to it
' Add an entry when something is added
'
' This is called the first time you get a setting value
If myCol.Count = 0 Then
LoadData()
End If
Dim theSettings = New SettingsPropertyValueCollection()
Dim tValue As String = ""
' SettingsPropertyCollection is like a Shopping list
' of props that VS/VB wants the value for
For Each setItem As SettingsProperty In collection
Dim value As New SettingsPropertyValue(setItem)
value.IsDirty = False
If myCol.ContainsKey(setItem.Name) Then
value.SerializedValue = myCol(setItem.Name)
tValue = myCol(setItem.Name).Value
Else
value.SerializedValue = setItem.DefaultValue
tValue = setItem.DefaultValue.ToString
End If
' ToDo: Enums will need an extra step
Conversion = Function(v) TypeDescriptor.
GetConverter(setItem.PropertyType).
ConvertFromInvariantString(v.ToString())
value.PropertyValue = Conversion(tValue)
theSettings.Add(value)
Next
Return theSettings
End Function
Public Overrides Sub SetPropertyValues(context As SettingsContext,
collection As SettingsPropertyValueCollection)
' this is not called when you set a new value
' rather, NET has one or more changed values that
' need to be saved, so be sure to save them to disk
Dim names As List(Of String) = myCol.Keys.ToList
Dim sItem As SettingsItem
For Each item As SettingsPropertyValue In collection
sItem = New SettingsItem() With {
.Name = item.Name,
.Value = item.SerializedValue.ToString(),
.Roamer = IsRoamer(item.Property)
}
'.SerializeAs = item.Property.SerializeAs.ToString(),
names.Remove(item.Name)
If myCol.ContainsKey(sItem.Name) Then
myCol(sItem.Name) = sItem
Else
myCol.Add(sItem.Name, sItem)
End If
Next
' flag any no longer used
' do not use when specifying a provider per-setting!
For Each s As String In names
myCol(s).Remove = True
Next
SaveData()
End Sub
' detect if a setting is tagged as Roaming
Private Function IsRoamer(prop As SettingsProperty) As Boolean
Dim r = prop.Attributes.
Cast(Of DictionaryEntry).
FirstOrDefault(Function(q) TypeOf q.Value Is SettingsManageabilityAttribute)
Return r.Key IsNot Nothing
End Function
Private Sub LoadData()
' load from disk
If File.Exists(UserConfigFilePath) = False Then
CreateNewConfig()
End If
Dim xDoc = XDocument.Load(UserConfigFilePath)
Dim items As IEnumerable(Of XElement)
Dim item As SettingsItem
items = xDoc.Element(CONFIG).
Element(COMMON).
Elements(SETTING)
' load the common settings
For Each xitem As XElement In items
item = New SettingsItem With {.Name = xitem.Attribute(ITEMNAME).Value,
.Roamer = False}
'.SerializeAs = xitem.Attribute(SERIALIZE_AS).Value,
item.Value = xitem.Value
myCol.Add(item.Name, item)
Next
' First check if there is a machine node
If xDoc.Element(CONFIG).Element(thisMachine) Is Nothing Then
' nope, add one
xDoc.Element(CONFIG).Add(New XElement(thisMachine))
End If
items = xDoc.Element(CONFIG).
Element(thisMachine).
Elements(SETTING)
For Each xitem As XElement In items
item = New SettingsItem With {.Name = xitem.Attribute(ITEMNAME).Value,
.Roamer = True}
'.SerializeAs = xitem.Attribute(SERIALIZE_AS).Value,
item.Value = xitem.Value
myCol.Add(item.Name, item)
Next
' we may have changed the XDOC, by adding a machine node
' save the file
xDoc.Save(UserConfigFilePath)
End Sub
Private Sub SaveData()
' write to disk
Dim xDoc = XDocument.Load(UserConfigFilePath)
Dim roamers = xDoc.Element(CONFIG).
Element(thisMachine)
Dim locals = xDoc.Element(CONFIG).
Element(COMMON)
Dim item As XElement
Dim section As XElement
For Each kvp As KeyValuePair(Of String, SettingsItem) In myCol
If kvp.Value.Roamer Then
section = roamers
Else
section = locals
End If
item = section.Elements().
FirstOrDefault(Function(q) q.Attribute(ITEMNAME).Value = kvp.Key)
If item Is Nothing Then
' found a new item
Dim newItem = New XElement(SETTING)
newItem.Add(New XAttribute(ITEMNAME, kvp.Value.Name))
'newItem.Add(New XAttribute(SERIALIZE_AS, kvp.Value.SerializeAs))
newItem.Value = If(String.IsNullOrEmpty(kvp.Value.Value), "", kvp.Value.Value)
section.Add(newItem)
Else
If kvp.Value.Remove Then
item.Remove()
Else
item.Value = If(String.IsNullOrEmpty(kvp.Value.Value), "", kvp.Value.Value)
End If
End If
Next
xDoc.Save(UserConfigFilePath)
End Sub
' used in the XML
Const CONFIG As String = "configuration"
Const SETTING As String = "setting"
Const COMMON As String = "CommonShared"
Const ITEMNAME As String = "name"
'Const SERIALIZE_AS As String = "serializeAs"
' https://stackoverflow.com/a/11398536
Private Sub CreateNewConfig()
Dim fpath = Path.GetDirectoryName(UserConfigFilePath)
Directory.CreateDirectory(fpath)
Dim xDoc = New XDocument
xDoc.Declaration = New XDeclaration("1.0", "utf-8", "true")
Dim cfg = New XElement(CONFIG)
cfg.Add(New XElement(COMMON))
cfg.Add(New XElement(thisMachine))
xDoc.Add(cfg)
xDoc.Save(UserConfigFilePath)
End Sub
End Class
这是很多代码,只是为了从路径中删除证据哈希,但这是 MS 推荐的。这也可能是唯一的方法:ConfigurationManager
其获取的文件是只读的并且由代码支持。
Results:
实际的 XML 如前面所示,包含本地/通用和计算机特定部分。我使用了几个不同的应用程序名称并进行了各种测试:
忽略版本部分。如前所述,该内容已被删除。否则,文件夹是正确的 - 如上所述,当涉及到 AppName 段时,您有一些选项。
重要笔记
- 除非相关应用程序访问 Settings 属性,否则不会调用提供程序中的 Load 方法
- 加载后,无论代码是否更改任何内容,应用程序结束时都会调用 Save 方法(使用 VB 框架)
- NET 似乎只保存与默认值不同的设置。使用自定义提供程序时,所有值都会被标记
IsDirty
为真且UsingDefaultValue
为假。
- 如果/加载时,将返回所有值,并且 NET 在应用程序的整个生命周期中简单地从该集合中获取值
我主要关心的是类型的正确转换和本地/漫游支持。我没有检查每一个可能的类型。特别是自定义类型和枚举(我知道枚举需要额外的处理)。
值得注意的是,使用DataTable
使这个much更简单。您不需要SettingsItem
类、集合、无 XDoc(使用.WriteXML
/ .ReadXml
)。所有创建和组织 XElement 的代码也都消失了。
生成的 XML 文件有所不同,但这只是函数后面的形式。一共可以去掉60行左右的代码,而且更加简单。
资源
- 设置提供者类
- 有关设置的 MSDN 博客条目
- 堆栈溢出:user.config 的自定义路径“Chuck”使用更好命名的暂存变量
- 堆栈溢出:XML 中的 MachineName 问题
- 直到完成后我才看到这篇 CodeProject 文章:创建自定义设置提供程序这似乎是根据每个设置使用自定义提供程序的不同方法。