在 CMD 中检测可移动驱动器盘符

我正在尝试编写一个脚本，它将检测我的 USB 可移动驱动器的字母“UUI”，然后在其上创建文件夹。我为 CMD 编写了一些命令，这些命令单独运行时可以工作。然而，当我将它们放入bat文件中时，我总是会遇到一些错误。下面是bat文件中的命令：

for /F "tokens=1 delims= " %i in ('WMIC logicaldisk where "DriveType=2" list brief ^| c:\windows\system32\find.exe "UUI"') do (echo %i > drive.txt)
set /p RemovableDriveLetter2= < drive.txt
del /F /Q drive.txt
set RemovableDriveLetter=%RemovableDriveLetter2:~0,1%
%RemovableDriveLetter%:
md MyNewFolder
cd MyNewFolder

当我转到 cmd.exe 并通过调用“myScript.bat”或“call myScript.bat”运行该文件时，出现错误：

C:\Users\UUI\Desktop>myScript.bat

\windows\system32\find.exe这时候出乎意料。

C:\Users\UUI\Desktop>for /F "tokens=1 delims= " \windows\system32\find.exe "UUI"') do (echo i >drive.txt)

C:\用户\UUI\桌面>

我可以看到 MyNewFolder 没有创建。但是，当我复制所有行并在 CMD 中运行它们（例如不在 .bat 文件中）并一一运行它们时，它在 cmd.exe 实例中具有完整的功能。

如何创建 bat 文件，该文件将成功运行并检测可移动驱动器的驱动器号而不会出现问题？或者如何解决“\windows\system32\find.exe 此时出现意外”错误？

你需要double the %用于标记一个的标志FOR批处理脚本中的循环控制变量（.bat or .cmd），即使用%%i代替%i在纯 CLI 中使用。

然而，还有另一种可能的方法如何解析wmic输出。 另请参阅戴夫·贝纳姆的WMIC and FOR /F: 修复了尾随的问题<CR> problem

@echo OFF
SETLOCAL enableextensions
set "USBCounter=0"
for /F "tokens=2 delims==" %%G in ('
    WMIC logicaldisk where "DriveType=2" get DeviceID /value 2^>NUL ^| find "="
') do for /F "tokens=*" %%i in ("%%G") do (
    set /A "USBCounter+=1"
    echo %%i
    rem your stuff here
)
echo USBCounter=%USBCounter%
rem more your stuff here
ENDLOCAL
goto :eof

这里的for循环是

• %%G检索DeviceID value;
• %%i删除结尾回车在返回值中：wmic行为：每个输出行以0x0D0D0A (CR+CR+LF）而不是常见的0x0D0A (CR+LF).

一个可以使用Caption or Name代替DeviceID:

==>WMIC logicaldisk where "DriveType=2" get /value | find ":"
Caption=F:
DeviceID=F:
Name=F:

注意可能有no or more磁盘存在DriveType=2:

==>WMIC logicaldisk where "DriveType=2" get /value | find ":"
No Instance(s) Available.

==>WMIC logicaldisk where "DriveType=2" list brief
DeviceID  DriveType  FreeSpace   ProviderName  Size        VolumeName
F:        2          2625454080                3918512128  HOMER
G:        2          999600128                 1029734400  LOEWE

Script output for no, then one进而twoUSB 驱动器分别：

==>D:\bat\SO\31356732.bat
USBCounter=0

==>D:\bat\SO\31356732.bat
F:
USBCounter=1

==>D:\bat\SO\31356732.bat
F:
G:
USBCounter=2

==>