(MathLink) 正确处理从属内核生成的消息

当工作通过MathLink对于从属内核，我在正确解析时遇到问题TextPackets。特别是当这样的数据包对应于Message由从属内核生成我根本不明白如何正确处理它。我需要这样的Messages打印在评估笔记本中，就好像它们是由主内核生成的一样（但有一些标记以表明它来自从属内核）。而我需要分开TextPackets 对应于Messages 从 刚刚 到Print[]命令。后者我也需要正确解析，将它们打印在评估笔记本中，并带有一点标记，表明它来自从属内核。

以下是所发生情况的示例：

link = LinkLaunch[First[$CommandLine] <> " -mathlink"]
Print@LinkRead[link]
LinkWrite[link, 
 Unevaluated[EnterExpressionPacket[Print[a]; 1/0; Print[b]]]]
While[Not@MatchQ[packet = LinkRead[link], InputNamePacket[_]], 
 Print[packet]]

The Message默认情况下通过MathLink形式为：

TextPacket[                                 1
Power::infy: Infinite expression - encountered.
                                 0]

看起来很丑。我发现让它变得更好的唯一方法是在从属内核中进行评估

$MessagePrePrint = InputForm;

但我认为应该有更直接的解决方案。特别是当我以这种方式处理时TextPackets with HoldForm里面：

TextPacket[Power::infy: Infinite expression HoldForm[0^(-1)] encountered.]

我不知道如何将这样的字符串转换为适合打印的形式Message.

附：这个问题来自that问题。

我想分享 Todd Gayley（Wolfram Research）针对给定问题提出的一个很好的技巧。也许对某人有用，对我也有用。这个技巧以相当优雅的方式解决了所讨论的问题。

一种技术是离开 OutputForm 的 FormatType 为 计算，但覆盖 暂时处理消息 切换到 StandardForm，以便仅 消息输出返回 标准格式：

LinkWrite[link,
        Unevaluated[EnterExpressionPacket[
            Unprotect[Message];
            Message[args___]:=
               Block[{$inMsg = True, result},
                  SetOptions[$Output, FormatType->StandardForm];
                  result = Message[args];
                  SetOptions[$Output, FormatType->OutputForm];
                  result
               ] /; !TrueQ[$inMsg]
           ]
        ]]

您将得到一个包含 a 内容的 ExpressionPacket 信息。要将其打印为消息单元格中的 笔记本：

cell = Cell[<the ExpressionPacket>, "Message", "MSG"]
CellPrint[cell]

高级方法：所有内容都以 StandardForm 形式打印

为了让除了输出之外的所有内容都返回StandardForm我们可以重新定义变量$Pre and $Post以特殊方式在从属内核中（应在从属内核中评估以下代码）：

SetOptions[$Output, {PageWidth -> 72, FormatType -> StandardForm}];
(*$inPost is needed for tracing mode compatibility 
(could be switched on by evaluating On[] in the slave kernel) 
in which Messages are printed during evaluation of $Post.*)
$inPost = False; Protect[$inPost];
$Pre := Function[inputexpr, 
  SetOptions[$Output, FormatType -> StandardForm]; 
  Unevaluated[inputexpr], HoldAllComplete];
$Post := Function[outputexpr, 
  Block[{$inPost = True}, 
   SetOptions[$Output, FormatType -> OutputForm]; 
   Unevaluated[outputexpr]], HoldAllComplete];
Protect[$Pre]; Protect[$Post];
$inMsg = False; Protect[$inMsg];
Unprotect[Message];
Message[args___] /; $inPost := Block[{$inMsg = True},
    SetOptions[$Output, FormatType -> StandardForm];
    Message[args];
    SetOptions[$Output, FormatType -> OutputForm]] /; ! $inMsg;
Protect[Message];