如何自动展开和打印 TreeView

我创建了一个应用程序，它会扫描每台计算机，并使用硬件、软件和更新/修补程序信息填充 TreeView：

我遇到的问题是打印，如何自动展开树视图并将所选计算机的结果发送到打印机？我当前使用的方法是将内容发送到画布（BMP），然后将其发送到打印机，但这不会捕获整个树视图，仅捕获屏幕上显示的内容。有什么建议吗？太感谢了。

打印的问题TTreeView就是不可见的部分没有什么可绘制的。 （Windows 仅绘制控件的可见部分，因此当您使用PrintTo或 APIPrintWindow函数，它只有可见节点可用于打印 - 未显示的内容尚未绘制，因此无法打印。）

如果表格布局有效（没有线条，只有缩进级别），最简单的方法是创建文本并将其放在隐藏的文本中TRichEdit，然后让TRichEdit.Print处理输出。这是一个例子：

// File->New->VCL Forms Application, then
// Drop a TTreeView and a TButton on the form.
// Add the following for the FormCreate (to create the treeview content)
// and button click handlers, and the following procedure to create
// the text content:

procedure TreeToText(const Tree: TTreeView; const RichEdit: TRichEdit);
var
  Node: TTreeNode;
  Indent: Integer;
  Padding: string;
const
  LevelIndent = 4;
begin
  RichEdit.Clear;
  Node := Tree.Items.GetFirstNode;
  while Node <> nil do
  begin
    Padding := StringOfChar(#32, Node.Level * LevelIndent);
    RichEdit.Lines.Add(Padding + Node.Text);
    Node := Node.GetNext;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  HideForm: TForm;
  HideEdit: TRichEdit;
begin
  HideForm := TForm.Create(nil);
  try
    HideEdit := TRichEdit.Create(HideForm);
    HideEdit.Parent := HideForm;
    TreeToText(TreeView1, HideEdit);
    HideEdit.Print('Printed TreeView Text');
  finally
    HideForm.Free;
  end;
end;

procedure TForm3.FormCreate(Sender: TObject);
var
  i, j: Integer;
  RootNode, ChildNode: TTreeNode;
begin
  RootNode := TreeView1.Items.AddChild(nil, 'Root');
  for i := 1 to 6 do
  begin
    ChildNode := TreeView1.Items.AddChild(RootNode, Format('Root node %d', [i]));
    for j := 1 to 4 do
      TreeView1.Items.AddChild(ChildNode, Format('Child node %d', [j]));
  end;
end;