这行代码有什么问题吗？

WordDoc.CheckBoxNum.Value = CheckBoxVal

需要明确的是，我正在使用 ActiveX 控件“复选框”。我将值（真/假）和复选框名称保存在 Excel 文件中。该代码打开我的 Word 文档并自动循环遍历复选框，设置它们的值。我从 Excel 控制 Word 的事实可能会改变我的对象？

如果他们是表单字段...这有效--

CheckBoxNum = "Check1"
CheckBoxVal = "True"
WordDoc.FormFields(CheckBoxNum).CheckBox.Value = CheckBoxVal

这是我的整个代码

Sub Doit()
    Dim WordApp As Object
    Dim WordDoc As Object
    Dim filepath As String
    Dim CheckBoxNum As String
    Dim CheckBoxVal As String
    Dim i As Integer, k As Integer

    'Open Word
    filepath = "C:\test.docx"
    Set WordApp = CreateObject("word.application")
    WordApp.Visible = True
    Set WordDoc = WordApp.Documents.Open(filepath)

    'Editing
    Range("a1").Select 'first value
    i = 0
    For i = 0 To 6 ' number of rows in table 
          'get from excel
          CheckBoxNum = ActiveCell.Offset(i, k + 1).Value
          CheckBoxVal = ActiveCell.Offset(i, k).Value

           'put to word
           WordDoc.CheckBoxNum.Value = CheckBoxVal '<-- HELP!
    Next i

    '// CLEAN UP //
    WordDoc.Application.ActiveDocument.Save
    WordDoc.Close
    WordApp.Quit
    Set WordDoc = Nothing
    Set WordApp = Nothing
End Sub

不幸的是，我们不能使用 ActiveX 控件的名称直接引用它WordDoc.InlineShapes(CheckBoxNum)，只有当我们知道它的索引号时，这才有效：WordDoc.InlineShapes(1).

这意味着您必须循环遍历所有控件，比较其OLEFormat.Object.Name到您要找的名字：

Dim obj As Object

For i = 0 To 6 ' number of rows in table
    'get from excel
    CheckBoxNum = ActiveCell.Offset(i, k + 1).Value
    CheckBoxVal = ActiveCell.Offset(i, k).Value

    For Each obj In WordDoc.InlineShapes
        If obj.OLEFormat.Object.Name = CheckBoxNum Then
            obj.OLEFormat.Object.Value = CheckBoxVal
        End If
    Next obj
Next i