8086 汇编中更快的键盘扫描代码检测

是否有可能比仅从硬件端口 60h 读取数据更快地检测和收集键盘的通断和制动？

每当我按下一个键，比如说“W”键，然后快速按下另一个键，“W”键的中断代码仍然由端口 60h 返回。

在我正在编写的游戏中，当用户尝试快速改变方向时，这会产生将玩家精灵锁定到位的效果。

我尝试过使用 int 16h 函数 01h 和 int 16h 函数 00，但与端口 60h 相比，它非常不稳定且缓慢。

这是我使用端口 60h 的输入代码。我只是将扫描码传递给 bp。我所有需要用户输入的程序都会检查 bp 中的扫描码。

HANDLE_INPUT PROC

;CLEARS THE KEYBOARD TYPEHEAD BUFFER AND COLLECTS A SCANCODE 

;ALTERS BP

    push ax
    push es

    mov ax, 40h                
    mov es, ax                  ;access keyboard data area via segment 40h
    mov WORD PTR es:[1ah], 1eh  ;set the kbd buff head to start of buff
    mov WORD PTR es:[1ch], 1eh  ;set the kbd buff tail to same as buff head
                                ;the keyboard typehead buffer is now cleared
    xor ah, ah
    in al, 60h                  ;al -> scancode
    mov bp, ax                  ;bp -> scancode, accessible globally   

    pop es
    pop ax
    ret


HANDLE_INPUT ENDP

这是使用 int 16h 的替代版本，其工作效果几乎不如上面使用端口 60h 的版本。

HANDLE_INPUT PROC

;COLLECTS A SCANCODE 

;ALTERS BP

    push ax

    xor bp, bp    ;clear out bp
    mov ah, 1     ;Function 1, check key status.
    int 16h       ;Is a key ready? 
    jz NO_KEY     ;If zf cleared, then no.
    xor ah, ah    ;Otherwise, a key is waiting.
    int 16h       ;ah -> scancode
    xor al, al    
    xchg al, ah   ;ax -> scancode
    mov bp, ax    ;bp -> scancode, accessible globally


NO_KEY:

    pop ax
    ret


HANDLE_INPUT ENDP

为了回答我自己的问题，通过端口 60h 提供的扫描码实际上并不是太慢，而是太快了。

在我的问题中给出的以下示例中：“每当我按下一个键，比如说‘W’键，然后快速按下另一个键，‘W’键的中断代码仍然由端口 60h 返回。”

我认为端口 60h 仍然返回“W”的中断代码的原因是键盘控制器没有足够的时间来记录我敲击了新键的事实。

实际上，我先按下了另一个键，并且确实返回了该键的 make 代码。然后，一瞬间，我的手指从“W”键上移开，用“W”中断代码覆盖了端口 60h 返回的字节。

解决方案：仅在中断代码与已存储在 bp 中的 make 代码相对应时才采用中断代码。

新的 HANDLE_INPUT 过程，现在工作得更好：

HANDLE_INPUT PROC

;CLEARS THE KEYBOARD TYPEHEAD BUFFER AND COLLECTS A SCANCODE 

;ALTERS BP

    push ax
    push bx
    push es

    mov ax, 40h                
    mov es, ax                  ;access keyboard data area via segment 40h
    mov WORD PTR es:[1ah], 1eh  ;set the kbd buff head to start of buff
    mov WORD PTR es:[1ch], 1eh  ;set the kbd buff tail to same as buff head
                                ;the keyboard typehead buffer is now cleared
    xor ah, ah
    in al, 60h                  ;al -> scancode
    test al, 80h                ;Is a break code in al?
    jz ACCEPT_KEY               ;If not, accept it. 
                                ;If so, check to see if it's the break code
                                ;that corresponds with the make code in bp.
    mov bx, bp                  ;bx -> make code   
    or bl, 80h                  ;change make code into it's break code  
    cmp bl, al                  ;Do the new and old break codes match?
    je ACCEPT_KEY               ;If so, accept the break code.
    pop es                      ;If not, bp retains old make code.
    pop bx
    pop ax
    ret

ACCEPT_KEY: 
    mov bp, ax                  ;bp -> scancode, accessible globally

    pop es
    pop bx
    pop ax
    ret


HANDLE_INPUT ENDP