MS Excel - 使用分隔符连接

我有一个很长的电子表格，里面有数字。

我需要将它们放在一个由 ; 分隔的字符串中 例如。 4364453;24332432;2342432

我知道我能做到：

=concat(A1:A2000)

但这会将其合并到一个没有分隔符的字符串中 - 当您指定范围时，我似乎找不到分隔符的选项。

谢谢

使用 TEXTJOIN() 代替：

=TEXTJOIN(";",TRUE,A1:A2000)

对于那些没有 OFFICE 365 Excel 的用户，请使用这个模仿 TEXTJOIN 函数的 UDF。

将其放入工作簿附加的模块中，并使用上面的公式进行调用。

Function TEXTJOIN(delim As String, skipblank As Boolean, arr)
    Dim d As Long
    Dim c As Long
    Dim arr2()
    Dim t As Long, y As Long
    t = -1
    y = -1
    If TypeName(arr) = "Range" Then
        arr2 = arr.Value
    Else
        arr2 = arr
    End If
    On Error Resume Next
    t = UBound(arr2, 2)
    y = UBound(arr2, 1)
    On Error GoTo 0

    If t >= 0 And y >= 0 Then
        For c = LBound(arr2, 1) To UBound(arr2, 1)
            For d = LBound(arr2, 1) To UBound(arr2, 2)
                If arr2(c, d) <> "" Or Not skipblank Then
                    TEXTJOIN = TEXTJOIN & arr2(c, d) & delim
                End If
            Next d
        Next c
    Else
        For c = LBound(arr2) To UBound(arr2)
            If arr2(c) <> "" Or Not skipblank Then
                TEXTJOIN = TEXTJOIN & arr2(c) & delim
            End If
        Next c
    End If
    TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim))
End Function