为什么这个TStreamAdapter没有被释放？

比较这两个片段：

(d as IPersistStream).Save(
  TStreamAdapter.Create(
    TFileStream.Create('test.bin',fmCreate),soOwned),true);
(d as IPersistStream).Load(
  TStreamAdapter.Create(
    TFileStream.Create('test.bin',fmOpenRead),soOwned));

这在第二次失败TFileStream.Create因为第一个没有被破坏。这很奇怪，因为该参数具有唯一的引用，我认为它会在关闭时被破坏Save称呼。所以我尝试了这个：

var
  x:IStream;
begin
  x:=TStreamAdapter.Create(
    TFileStream.Create('test.bin',fmCreate),soOwned);
  (d as IPersistStream).Save(x,true);
  x:=nil;
  x:=TStreamAdapter.Create(
    TFileStream.Create('test.bin',fmOpenRead),soOwned);
  (d as IPersistStream).Load(x);
  x:=nil;

效果很好。 （但再次失败，没有x:=nil;）所以不用担心d, it is a IPersistStream并且行为正确。为什么需要明确nil分配以强制_Release称呼？这是 Delphi 7 的已知问题吗？是因为链接器/编译器开关吗？

这是声明IPersistStream.Save:

function Save(const stm: IStream; fClearDirty: BOOL): HResult; stdcall;

关键点是流参数传递为const。这意味着Save函数不引用IStream界面。它的引用计数既不增加也不减少。由于这两种情况都没有发生，因此它永远不会被破坏。

解决这个问题的方法是确保某些东西拥有对接口的引用。这就是您在第二个示例中演示的内容。

您需要分配任务的原因nil取决于此代码的执行顺序：

x := TStreamAdapter.Create(
  TFileStream.Create('test.bin',fmOpenRead),soOwned
);

它按以下顺序发生：

1. TFileStream.Create.
2. TStreamAdapter.Create.
3. x._Release清除旧的参考。
4. 参考一下新的IStream.

这显然是错误的顺序。你需要清除x打电话之前TFileStream.Create.

根据前 Embarcadero 编译器工程师 Barry Kelly 的说法，关于传递给 const 参数的接口的问题是一个错误。它从未被修复，我个人已经放弃了这种情况发生的希望。

我的 SSCCE 演示该问题的位置如下：

program SO22846335;

{$APPTYPE CONSOLE}

type
  TMyInterfaceObject = class(TObject, IInterface)
    FRefCount: Integer;
    FName: string;
    function QueryInterface(const IID: TGUID; out Obj): HResult; stdcall;
    function _AddRef: Integer; stdcall;
    function _Release: Integer; stdcall;
    constructor Create(const Name: string);
    destructor Destroy; override;
  end;

constructor TMyInterfaceObject.Create(const Name: string);
begin
  inherited Create;
  FName := Name;
  Writeln(FName + ' created');
end;

destructor TMyInterfaceObject.Destroy;
begin
  Writeln(FName + ' destroyed');
  inherited;
end;

function TMyInterfaceObject.QueryInterface(const IID: TGUID; out Obj): HResult;
begin
  Result := E_NOINTERFACE;
end;

function TMyInterfaceObject._AddRef: Integer;
begin
  Writeln(FName + ' _AddRef');
  Result := AtomicIncrement(FRefCount);
end;

function TMyInterfaceObject._Release: Integer;
begin
  Writeln(FName + ' _Release');
  Result := AtomicDecrement(FRefCount);
  if Result = 0 then
    Destroy;
end;

procedure Foo(const Intf: IInterface);
begin
  Writeln('Foo');
end;

procedure Bar(Intf: IInterface);
begin
  Writeln('Bar');
end;

begin
  Foo(TMyInterfaceObject.Create('Instance1'));
  Bar(TMyInterfaceObject.Create('Instance2'));
  Readln;
end.

Output

Instance1 created
Foo
Instance2 created
Instance2 _AddRef
Bar
Instance2 _Release
Instance2 destroyed