如何向合并的Word表格添加行？

这就是桌子的样子。

Code:

Sub WordTableTester()
Dim CurrentTable As table
Dim wdDoc As Document
Dim Rw As Long, col As Long
Dim wdFileName

wdFileName = Application.GetOpenFilename("Word files (*.docx),*.docx", , "Please choose a file containing requirements to be imported")
If wdFileName = False Then Exit Sub '(user cancelled import file browser)

Set wdDoc = GetObject(wdFileName) 'open Word file

With wdDoc
    Set CurrentTable = wdDoc.Tables(1)
    Rw = 9: col = CurrentTable.Columns.Count
    wdDoc.Range(CurrentTable.Cell(Rw, 1).Range.start, _
    CurrentTable.Cell(Rw, col).Range.start).Select
    wdDoc.Application.Selection.InsertRowsBelow
End With


End Sub

当我运行此命令时，我收到一条错误消息：Run-Time error '5941': The requested member of the collection does not exist.

Note:我正在运行 VBA Excel 宏并将行导入/添加到 Word 文档中的表中

在 MS Word 表中处理合并行有点棘手。

这是你想要的吗？

Sub Sample()
    Dim CurrentTable As Table
    Dim wdDoc As Document
    Dim Rw As Long, col As Long

    Set wdDoc = ActiveDocument '<~~ Created this for testing
    Set CurrentTable = wdDoc.Tables(1)

    Rw = 9: col = CurrentTable.Columns.Count

    wdDoc.Range(CurrentTable.Cell(Rw, 1).Range.Start, _
    CurrentTable.Cell(Rw, col).Range.Start).Select

    wdDoc.Application.Selection.InsertRowsBelow
End Sub

ScreenShot

Edit

你表的格式全部搞砸了。创建的表只有几行，然后合并/拆分单元格以创建新行，因此您收到错误。另外，由于您正在自动化 Excel 中的 Word，因此我建议采用以下方法。

Try this

Sub WordTableTester()
    Dim oWordApp As Object, oWordDoc As Object, CurrentTable As Object
    Dim flName As Variant
    Dim Rw As Long, col As Long

    flName = Application.GetOpenFilename("Word files (*.docx),*.docx", _
    , "Please choose a file containing requirements to be imported")

    If flName = False Then Exit Sub

    Set oWordApp = CreateObject("Word.Application")
    oWordApp.Visible = True

    Set oWordDoc = oWordApp.Documents.Open(flName)
    Set CurrentTable = oWordDoc.Tables(1)

    Rw = 7: col = CurrentTable.Columns.Count

    oWordDoc.Range(CurrentTable.Cell(Rw, 1).Range.Start, _
    CurrentTable.Cell(Rw, col).Range.Start).Select

    oWordDoc.Application.Selection.InsertRowsBelow
End Sub