使用 gradle/clojuresq 构建 clojure

我正在尝试使用 gradle/Clojuresque 构建 clojure 代码，运行它并获取 uberjar。 我使用来自的提示http://dev.clojure.org/display/doc/Getting+Started+with+Gradle, https://bitbucket.org/kotarak/clojuresque/wiki/Getting%20Started, and Gradle for Clojure (Clojuresque) 出现“找不到 us.bpsm:edn-java:0.4.3”错误.

这是成绩脚本。

buildscript {
    repositories { 
        maven { url "http://clojars.org/repo" } 
        mavenCentral()
    }
    dependencies {
        classpath "clojuresque:clojuresque:1.7.0" 
    }
}

apply plugin: 'clojure'

clojure.aotCompile = true

repositories {
    flatDir dirs: project.file("lib/runtime")
    maven { url "http://clojars.org/repo" }
}

With gradle build任务，没有错误，我有一个 jar 文件，但我没有看到生成任何类文件；我认为生成的 jar 不包含任何内容，特别是当我比较手动构建的结果时（从命令行将 clojure 源代码编译为类（AOT）（不使用 lein）).

.
├── build
│   ├── libs
│   │   └── clojure.jar
│   └── tmp
│       └── jar
│           └── MANIFEST.MF
├── build.gradle
└── src
    └── hello
        └── core.clj

这是core.clj

(ns hello.core
  (:gen-class))
(defn -main
  "This should be pretty simple."
  []
  (println "Hello, World!"))

可能出了什么问题？另外，如何运行代码并获得 uberjar 之类的lein run and lein uberjar does?

我将目录压缩到https://dl.dropboxusercontent.com/u/10773282/share/2015/clojure_test.zip

创建类文件

源代码应位于./src/main/clojure因为它是默认目录。

不过，可以在 gradle 文件中指定源文件。

sourceSets {
    main {
        clojure {
            srcDirs = ['src']
        }
    }
}

另一个问题是缺少依赖项：

repositories {
    maven { url "http://clojars.org/repo" }
    mavenCentral()
}

dependencies {
    compile "org.clojure:clojure:1.6.0"
}

gradle build将生成类文件。

获取jar文件

我们需要为 jar 文件设置主类。

jar
{
    manifest.attributes("Main-Class": "hello.core")
}

我不太确定设置是否非常必要；gradle jar将生成 jar 文件。

执行jar文件

这是运行代码的命令：

java -cp .:<PATH>/clojure-1.6.0.jar:build/libs/clojure_test.jar hello.core

uberjar

需要进行三处修改：来自的提示https://github.com/DevonStrawn/Clojuresque-Boilerplate/blob/master/UberJar/build.gradle.

uberjar
{
    manifest.attributes("Main-Class": "hello.core")
}

apply plugin: 'application'

uberjar.enabled = true

执行 uberjar

现在只需一个 jar 即可执行

clojure_test> java -jar build/libs/clojure_test-standalone.jar 
Hello, World!

新的 build.gradle 文件

buildscript {
    repositories { 
        maven { url "http://clojars.org/repo" } 
        mavenCentral()
    }
    dependencies {
        classpath "clojuresque:clojuresque:1.7.0" 
    }
}

apply plugin: 'clojure'

clojure.aotCompile = true

sourceSets {
    main {
        clojure {
            srcDirs = ['src']
        }
    }
}

repositories {
    maven { url "http://clojars.org/repo" }
    mavenCentral()
}

dependencies {
    compile "org.clojure:clojure:1.7.0"
}

jar
{
    manifest.attributes("Main-Class": "hello.core")
}   

uberjar
{
    manifest.attributes("Main-Class": "hello.core")
}

apply plugin: 'application'

uberjar.enabled = true

影坛

从 Opal 的回答中，我添加了创建 ShadowJar 的 gradle 脚本。它包含设置主类的 MANIFEST 文件。

buildscript {
    repositories { 
        maven { url "http://clojars.org/repo" } 
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath "clojuresque:clojuresque:1.7.0" 
        classpath 'com.github.jengelman.gradle.plugins:shadow:1.2.0'
    }
}

apply plugin: 'application'
apply plugin: 'clojure'
apply plugin: 'com.github.johnrengelman.shadow'

clojure.aotCompile = true
mainClassName = 'hello.core'

sourceSets {
    main {
        clojure {
            srcDirs = ['src']
        }
    }
}

repositories {
    maven { url "http://clojars.org/repo" }
    mavenCentral()
}

dependencies {
    compile "org.clojure:clojure:1.7.0" 
}

或者使用这两行代码代替清单更改代码：

apply plugin: 'application'
mainClassName = 'hello.core'

执行shadow jar

获取 ubjer jar

gradle shadow

和uberjar是一样的。

clojure_test> java -jar build/libs/clojure_test-all.jar 
Hello, World!

参考

• https://github.com/johnrengelman/shadow
• 锅炉板-https://github.com/DevonStrawn/Clojuresque-Boilerplate
• 使用 Gradle 构建 uberjar