使用具有按钮属性的不同命令按钮触发相同的宏

正如主题所建议的，我已经构建了一个需要变量输入的宏

Sub GetFile(Account as String)

目前我正在设置多个子程序来调用脚本并将它们分配给不同的命令按钮

Sub AC1_File
    Call GetFile("Account1")
end sub

Sub AC2_File
    Call GetFile("Account2")
end sub

名单还在继续

我试图不让我的代码太长（因为我有两位数的帐户）， 我的代码是否可以获取命令按钮名称的属性并使用它来代替帐户 1,2,3...？

像下面这样的东西？

Call GetFile(triggering-commandbutton.name)

表单控件

在普通模块中添加一个不带参数的过程：

Public Sub Button_Click()
    GetFile Application.Caller
End Sub  

此代码将获取按钮名称并将其传递给GetFile程序。

Sub GetFile(Account As String)
    MsgBox "Account Name is " & Account
End Sub  

所以现在您需要做的就是为按钮命名Account1, Account2， ETC..

ActiveX 控件

如果您使用 ActiveX 控件，则可以使用类来捕获单击事件。

创建一个类模块并命名clsButtonClick.
将此代码添加到类模块中：

Public WithEvents AccountBtn As MSForms.CommandButton

Private Sub AccountBtn_Click()
    MsgBox AccountBtn.Name & " on " & AccountBtn.Parent.Name
    GetFile AccountBtn.Name
End Sub

在普通模块的最顶部添加以下行：

Public colBtns As New Collection  

并将此代码添加到模块中：

Public Sub Initialize_Buttons()

    Dim wrkSht As Worksheet
    Dim btnEvnt As clsButtonClick
    Dim obj As OLEObject

    For Each wrkSht In ThisWorkbook.Worksheets
        For Each obj In wrkSht.OLEObjects
            If TypeName(obj.Object) = "CommandButton" Then
                Set btnEvnt = New clsButtonClick
                Set btnEvnt.AccountBtn = obj.Object
                colBtns.Add btnEvnt
            End If
        Next obj
    Next wrkSht

End Sub  

这将遍历工作簿中的每个工作表，并为任何 ActiveX 命令按钮提供来自类模块的单击事件。
更新Initialize_Buttons如果您需要将其限制为特定工作表或工作表上的特定按钮，请执行以下步骤。

最后调用Initialize_Buttons代码在Workbook_Open事件在ThisWorkbook module.