在 SPSS 宏中循环遍历并行列表/数组

我想编写一个SPSS宏来执行三个操作：

1. 生成自定义表，
2. 清洁输出窗口，
3. 导出表。

如您所知，SPSS 宏工具允许使用两种类型的循环：“数字”，如 (!do !i = !x !to !y) 和 'list'/'for every' 像 (!do !i !in (!1)）。我的目标是创建一个带有如下调用的宏：col v1 v2 / "Sheet A" "Sheet B".以这种方式工作（使用“列表”之类的循环）：

1. 获取第一个变量名称 (v1)
2. 将其放入ctables宏观剖面
3. 获取第一个工作表名称（字符串“Sheet A”）
4. 将其放入output export宏观剖面
5. 获取第二个变量名
6. ...
7. 获取第二个工作表名称
8. ...

等等。

一开始我是这么写的：

define col (!positional !charend('/')
/!positional !cmdend)

!do !i !in (!1)

output close all.

  ctables
  /table x1 + x2
  by !i [mean f1.2, totals[mean f1.2]].

  output modify
  /select logs headings texts warnings pagetitles outlineheaders notes
  /deleteobject delete = yes.

!doend

!do !i !in (!2)

   output export
    /contents export = visible
    /xlsx documentfile = "E:\path\file.xlsx"
      operation = createsheet
      sheet = !i.

!doend

!enddefine.

*** MACRO CALL.
col v1 v2 / "Sheet A" "Sheet B".

输出总体上是不正确的，因为我只得到了带有第二个变量的表。但是，在文件中我发现了两张名称正确的工作表。所以，我尝试嵌套：

define col (!positional !charend('/')
/!positional !cmdend)

!do !i !in (!1)
!do !j !in (!2)

output close all.

  ctables
  /table x1 + x2
  by !i [mean f1.2, totals[mean f1.2]].

  output modify
  /select logs headings texts warnings pagetitles outlineheaders notes
  /deleteobject delete = yes.

   output export
    /contents export = visible
    /xlsx documentfile = "E:\path\file.xlsx"
      operation = createsheet
      sheet = !j.

!doend
!doend

!enddefine.

*** MACRO CALL.
col v1 v2 / "Sheet A" "Sheet B".

输出完全相同，这意味着 SPSS 将“/”左侧列表中的每个元素与“/”右侧列表中的每个元素交叉，并覆盖 Excel 文件中以前的结果。我的目标是接收这样的宏扩展：

* FIRST EXPANSION:
...
  ctables
  /table x1 + x2
  by v1 [mean f1.2, totals[mean f1.2]].
...
   output export
    /contents export = visible
    /xlsx documentfile = "E:\path\file.xlsx"
      operation = createsheet
      sheet = "Sheet A".

* SECOND (LAST) EXPANSION:
...
  ctables
  /table x1 + x2
  by v2 [mean f1.2, totals[mean f1.2]].
...
   output export
    /contents export = visible
    /xlsx documentfile = "E:\path\file.xlsx"
      operation = createsheet
      sheet = "Sheet B".

换句话说 - 2 列出 x 2 个元素，但只有两个循环 - 而不是四个。有谁知道如何得到这样的结果？

据我所知，没有正式/直接的方法可以在 SPSS 宏中的并行列表上运行循环，因此您的选择是 - 要么使用 Python，要么找到解决方法 - 这里有一些想法：

1. 使用数字循环重新创建两个列表
所以你循环数字 1 到 5，并使用它们来创建变量名称 - v1 到 v5 以及“工作表 1”到“工作表 5”：

!do !i=1 !to 5
.....
  by !concat("v",!i) [mean f1.2, totals[mean f1.2]].
.....
  sheet = !quote(!concat("sheet ",!i))
.....
!doend

如果它们不是常量，您还可以将开始和/或结束数字添加到宏调用中。
当然，只有当您的两个列表共享相同的编号（如上例所示）时，这才有效。如果没有，您可以使用以下方法之一：

2. 循环遍历一个列表，同时“吃掉”第二个列表
SPSS 宏循环一次仅迭代一个列表 - 但您可以在第一个列表的每次迭代中获取一个项目并将其从第二个列表中删除，而不是迭代第二个列表：

define col (!pos !charend('/') / !pos !cmdend)
!let !arr2=!2
!do !i !in(!1)
    .....
    by !i [mean f1.2, totals[mean f1.2]].
    .....
!let !sheet=!head(!arr2)
!let !arr2=!tail(!arr2)
    .....
    sheet = !sheet
    .....
!doend
!enddefine.

*and the macro call:
col VARa VARb VARc/"sheet 1" "sheet 2" "sheet 3".

3. 在单对上定义宏，使用多个宏调用这是最简单的方法，如果每个列表中只有几个项目 - 您可以使用单个变量名称和单个工作表名称定义宏，您将能够通过运行获得相同的结果 -

col VARa/ "sheet 1" .
col VARb/ "sheet 2" .

代替col VARa VARb/ "sheet 1" "sheet 2" .正如你之前尝试过的那样。

如果这些列表很长，您可以单独自动运行宏调用（使用write例如命令 - 但这是一个单独的问题）。