VBA 中的编辑距离 [关闭]

我有包含数据的 Excel 工作表，我想获取它们之间的 Levenshtein 距离。我已经尝试导出为文本，从脚本（php）读入，运行Levenshtein（计算Levenshtein距离），再次将其保存到Excel。

但我正在寻找一种在 VBA 中以编程方式计算编辑距离的方法。我该怎么做呢？

翻译自维基百科 http://en.wikipedia.org/wiki/Levenshtein_distance :

Option Explicit
Public Function Levenshtein(s1 As String, s2 As String)

Dim i As Integer
Dim j As Integer
Dim l1 As Integer
Dim l2 As Integer
Dim d() As Integer
Dim min1 As Integer
Dim min2 As Integer

l1 = Len(s1)
l2 = Len(s2)
ReDim d(l1, l2)
For i = 0 To l1
    d(i, 0) = i
Next
For j = 0 To l2
    d(0, j) = j
Next
For i = 1 To l1
    For j = 1 To l2
        If Mid(s1, i, 1) = Mid(s2, j, 1) Then
            d(i, j) = d(i - 1, j - 1)
        Else
            min1 = d(i - 1, j) + 1
            min2 = d(i, j - 1) + 1
            If min2 < min1 Then
                min1 = min2
            End If
            min2 = d(i - 1, j - 1) + 1
            If min2 < min1 Then
                min1 = min2
            End If
            d(i, j) = min1
        End If
    Next
Next
Levenshtein = d(l1, l2)
End Function

?Levenshtein("星期六","星期日")

3