使用 XSLT 可以很容易地实现这一点。首先,您将创建一个模板来匹配以开头的元素UPC
<xsl:template match="product/*[starts-with(local-name(), 'UPC')]">
然后,您将根据元素的位置使用修改后的名称创建一个新元素
<xsl:element name="UPC_{position()}">
请注意此处在创建名称时使用“属性值模板”。大括号表示这是一个要计算的表达式,而不是按字面意思输出。
这是完整的 XSLT
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
<xsl:template match="product/*[starts-with(local-name(), 'UPC')]">
<xsl:element name="UPC_{position()}">
<xsl:apply-templates select="@*|node()"/>
</xsl:element>
</xsl:template>
<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
应用 XML 后,输出如下
<products>
<product>
<UPC_1>123</UPC_1>
<UPC_2>223</UPC_2>
<UPC_3>345</UPC_3>
<other>unchange</other>
</product>
<product>
<UPC_1>1234</UPC_1>
<UPC_2>1235</UPC_2>
<other>unchange</other>
</product>
</products>
话虽如此,只有当您的 UPC 元素始终是第一个元素时,它才有效。如果你有这个作为输入
<product>
<UPC_US>123</UPC_US>
<UPC_UK>223</UPC_UK>
<UPC_JP>345</UPC_JP>
<other>unchange</other>
</product>
输出将是这样的
<products>
<product>
<UPC_1>123</UPC_1>
<UPC_2>223</UPC_2>
<other>unchange</other>
<UPC_4>345</UPC_4>
</product>
</products>
如果这不是您想要的,您可以使用xsl:数字来计算元素的数量。试试这个 XSLT
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
<xsl:template match="product/*[starts-with(local-name(), 'UPC')]">
<xsl:variable name="count">
<xsl:number count="*[starts-with(local-name(), 'UPC')]"/>
</xsl:variable>
<xsl:element name="UPC_{$count}">
<xsl:apply-templates select="@*|node()"/>
</xsl:element>
</xsl:template>
<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
在这种情况下,第二个例子将产生这个
<products>
<product>
<UPC_1>123</UPC_1>
<UPC_2>223</UPC_2>
<other>unchange</other>
<UPC_3>345</UPC_3>
</product>
</products>
在这两种情况下,请记下使用身份转换模板按原样复制所有其他元素。