Prolog 中的简化旅行推销员

我浏览过类似的问题，但找不到与我的问题相关的任何内容。我正在努力寻找一种算法或一组“循环”来找到一条路径CityA to CityB，使用数据库

distance(City1,City2,Distance)

事实。到目前为止我所做的事情如下，但它总是回溯到write(X),然后完成最终迭代，这就是我想要它做的事情，但仅限于一定程度。

例如，我不希望它打印出任何死胡同的城市名称，或使用最终迭代。我希望它基本上能够从CityA to CityB，写下它所经过的城市的名称。

我希望有人能帮助我！

all_possible_paths(CityA, CityB) :-
    write(CityA),
    nl,
    loop_process(CityA, CityB).

loop_process(CityA, CityB) :- 
    CityA == CityB.
loop_process(CityA, CityB) :-
    CityA \== CityB,
    distance(CityA, X, _),
    write(X),
    nl,
    loop_process(X, CityB).

我试图向您展示如何实现您正在做的事情，以便您可以更好地理解它是如何工作的。所以既然你的OP不是很完整，我就采取了一些自由行动！以下是我正在研究的事实：

road(birmingham,bristol, 9).
road(london,birmingham, 3).
road(london,bristol, 6).
road(london,plymouth, 5).
road(plymouth,london, 5).
road(portsmouth,london, 4).
road(portsmouth,plymouth, 8).

这是我们将调用来查找路径的谓词，获取道路/4。它基本上称为工作谓词，它有两个累加器（一个用于已访问的点，一个用于我们经过的距离）。

get_road(Start, End, Visited, Result) :-
    get_road(Start, End, [Start], 0, Visited, Result).

这是工作谓词，
获取道路/6: get_road(+Start, +End, +Waypoints, +DistanceAcc, -Visited, -TotalDistance) :
第一个子句告诉我们，如果我们的第一个点和最后一个点之间有一条路，我们就可以在这里结束。

get_road(Start, End, Waypoints, DistanceAcc, Visited, TotalDistance) :-
    road(Start, End, Distance),
    reverse([End|Waypoints], Visited),
    TotalDistance is DistanceAcc + Distance.

第二个子句告诉我们，如果我们的第一个点和中间点之间有一条路，我们可以采用它，然后求解 get_road(intermediate, end)。

get_road(Start, End, Waypoints, DistanceAcc, Visited, TotalDistance) :-
    road(Start, Waypoint, Distance),
    \+ member(Waypoint, Waypoints),
    NewDistanceAcc is DistanceAcc + Distance,
    get_road(Waypoint, End, [Waypoint|Waypoints], NewDistanceAcc, Visited, TotalDistance).

用法如下：

?- get_road(portsmouth, plymouth, Visited, Distance).

并产生：

Visited = [portsmouth, plymouth],
Distance = 8 ;
Visited = [portsmouth, london, plymouth],
Distance = 9 ;
Visited = [portsmouth, plymouth, london, plymouth],
Distance = 18 ;
false.

希望对您有所帮助。