如何在 Julia 中逐行读取文件？

如何打开文本文件并逐行读取它？我对两种不同情况的答案感兴趣：

1. 一次获取数组中的所有行。
2. 一次处理每一行。

对于第二种情况，我不想一次将所有行保留在内存中。

将文件作为行数组一次性读入内存只需调用readlines功能：

julia> words = readlines("/usr/share/dict/words")
235886-element Array{String,1}:
 "A"
 "a"
 "aa"
 ⋮
 "zythum"
 "Zyzomys"
 "Zyzzogeton"

默认情况下，这会丢弃换行符，但如果您想保留它们，可以传递关键字参数keep=true:

julia> words = readlines("/usr/share/dict/words", keep=true)
235886-element Array{String,1}:
 "A\n"
 "a\n"
 "aa\n"
 ⋮
 "zythum\n"
 "Zyzomys\n"
 "Zyzzogeton\n"

如果您有一个已经打开的文件对象，您也可以将其传递给readlines功能：

julia> open("/usr/share/dict/words") do io
           readline(io) # throw out the first line
           readlines(io)
       end
235885-element Array{String,1}:
 "a"
 "aa"
 "aal"
 ⋮
 "zythum"
 "Zyzomys"
 "Zyzzogeton"

这表明readline函数，它从打开的 I/O 对象中读取一行，或者当给定文件名时，打开文件并从中读取第一行：

julia> readline("/usr/share/dict/words")
"A"

如果您不想一次加载所有文件内容（或者如果您正在处理来自网络套接字的流数据），那么您可以使用eachline函数来获取一次生成一行的迭代器：

julia> for word in eachline("/usr/share/dict/words")
           if length(word) >= 24
               println(word)
           end
       end
formaldehydesulphoxylate
pathologicopsychological
scientificophilosophical
tetraiodophenolphthalein
thyroparathyroidectomize

The eachline函数可以，比如readlines，还可以给出一个打开的文件句柄以从中读取行。您还可以通过打开文件并调用来“推出您自己的”迭代器readline反复：

julia> open("/usr/share/dict/words") do io
           while !eof(io)
               word = readline(io)
               if length(word) >= 24
                   println(word)
               end
           end
       end
formaldehydesulphoxylate
pathologicopsychological
scientificophilosophical
tetraiodophenolphthalein
thyroparathyroidectomize

这相当于什么eachline为你做的事情很少需要你自己做，但如果你需要的话，能力就在那里。有关逐个字符读取文件的更多信息，请参阅此问题和解答：我们如何使用 julia 一次读取 .txt 文件的每个字符？ https://stackoverflow.com/questions/52281241/how-do-we-use-julia-to-read-through-each-character-of-a-txt-file-one-at-a-time