在 Prolog 中创建 Niece 规则

使用家庭数据库，我需要在 swi-prolog 中创建一个侄女规则 (niece(X,Y))，其定义为“如果 X 是 Y 的兄弟或姐妹的女儿，则 X 是 Y 的侄女”。这是给定的数据库，其中包含我已经设计的规则：

% family DB

grandfather(don,who).

father(don,ted).
father(don,barb).
father(don,paula).
father(greg,erin).
father(greg,austin).
father(wes,alyssa).
father(ted,jessica).
father(ted,david).
%mother(ted, john).

mother(audrey,ted).
mother(audrey,barb).
mother(audrey,paula).
mother(paula,erin).
mother(paula,austin).
mother(barb,alyssa).

married(don,audrey).
married(wes,barb).
married(greg,paula).

male(don).
male(ted).
male(wes).
male(greg).
male(austin).
male(david).

female(audrey).
female(barb).
female(paula).
female(alyssa).
female(jessica).
female(erin).

parent(X,Y) :-
    father(X,Y)
  ; mother(X,Y).

grandfather(X,Y) :-
   father(X,Z),
   (  father(Z,Y)
   ;  mother(Z,Y)
   ).

samefather(X,Y) :- 
   father(F,X),
   father(F,Y).

samemother(X,Y) :- 
   mother(M,X),
   mother(M,Y).

sameparent(X,Y) :-
   samefather(X,Y).
sameparent(X,Y) :-
   samemother(X,Y),
   not(samefather(X,Y)).

couple(X,Y) :- 
   married(X,Y),
   married(X,Y).

这是我对侄女规则的初步尝试：

niece(X,Y) :-
   parent(F,X),
   sameparent(Y,F).

我的想法是使用 sameparent 规则来检查 Y 和 F 是否是兄弟姐妹，然后检查 F 是否是 X 的父级。此规则目前不起作用。我仍在努力理解组合多个规则的语法。如果有人可以使用相同的逻辑来帮助我，我将不胜感激。

删除不必要的规则：

parent(don,ted).
parent(don,barb).
parent(don,paula).
parent(greg,erin).
parent(greg,austin).
parent(wes,alyssa).
parent(ted,jessica).
parent(ted,david).

parent(audrey,ted).
parent(audrey,barb).
parent(audrey,paula).
parent(paula,erin).
parent(paula,austin).
parent(barb,alyssa).

male(don).
male(ted).
male(wes).
male(greg).
male(austin).
male(david).

female(audrey).
female(barb).
female(paula).
female(alyssa).
female(jessica).
female(erin).

father(X,Y) :-
    male(X),
    parent(X,Y).

mother(X,Y) :-
    female(X),
    parent(X,Y).

sameparent(X,Y) :-
   parent(A,X),
   parent(A,Y).

给你 ：

niece(X,Y) :-
    female(X),
    parent(Z,X),
    sameparent(Z,Y),
    Z \= Y.

逐行含义：

• X 是 Y 的侄女，如果
• X 是女性并且
• X 的一位父母
• 与 Y 有共同父母
• 谁不是他/她自己。

这给你：

| ?- niece(X,Y).

X = alyssa
Y = ted;

X = alyssa
Y = paula;

X = jessica
Y = barb;

X = jessica
Y = paula;

X = erin
Y = ted;

X = erin
Y = barb

Twice因为就您的数据库而言，每个兄弟/姐妹都有相同的两个父母。

例如，如果A是B的女儿，B是C同父异母的兄弟，则A仍然是C的侄女。

如果您希望该规则为假，并且仅当 B 和 C 是兄弟/姐妹（且不仅仅是同父异母）时，A 才成为 C 的侄女，您可以将侄女规则更改为以下内容：

sameFather(X,Y) :-
    father(A,X),
    father(A,Y).

sameMother(X,Y) :-
    mother(A,X),
    mother(A,Y).

niece(X,Y) :-
    female(X),
    parent(Z,X),
    sameFather(Z,Y),
    sameMother(Z,Y),
    Z \= Y.

那么你不会得到重复的结果niece(X,Y).