什么数据类型适合在 ActiveX 方法中处理二进制数据？

我正在为我的朋友编写一个 ActiveX 控件，它应该封装加密例程。主要从 VB6 开始使用。我应该为加密密钥、初始化向量、输入和输出数据等二进制数据选择什么数据类型，以便我的朋友可以方便地从VB6使用它？

我正在使用 Delphi 7 来编写这个 ActiveX，如果这很重要的话。一种选择是使用十六进制字符串。另一个可能是什么？

VB6 二进制数据存储在字节变量和数组中。

Dim arrData() As Byte

VB6 应用程序应该将该变量传递给您的 Delphi COM，如下所示OleVariant。 Delphi COM可以转换VarArray to TStream反之亦然：

procedure VariantToStream(const v :OleVariant; Stream: TStream);
var
  p : pointer;
  lo, hi, size: Integer;
begin
  lo := VarArrayLowBound(v,  1);
  hi := VarArrayHighBound (v, 1);
  if (lo >= 0) and (hi >= 0) then
  begin
    size := hi - lo + 1;
    p := VarArrayLock (v);
    try
      Stream.WriteBuffer (p^, size);
    finally
      VarArrayUnlock (v);
    end;
  end;
end;

procedure StreamToVariant(Stream: TStream; var v: OleVariant);
var
  p : pointer;
  size: Integer;
begin
  size := Stream.Size - Stream.Position;
  v := VarArrayCreate ([0, size - 1], varByte);
  if size > 0 then
  begin
    p := VarArrayLock (v);
    try
      Stream.ReadBuffer (p^, size);
    finally
      VarArrayUnlock (v);
    end;
  end;
end;

用途在CoClass unit:

// HRESULT _stdcall BinaryTest([in] VARIANT BinIn, [out, retval] VARIANT * BinOut );
function TMyComClass.BinaryTest(BinIn: OleVariant): OleVariant; safecall;
var
  Stream: TMemoryStream;
begin
  Stream := TMemoryStream.Create;
  try
    VariantToStream(BinIn, Stream);
    Stream.Position := 0;

    // do something with Stream ...

    // ... and return some Binary data to caller (* BinOut)
    Stream.Position := 0;
    StreamToVariant(Stream, Result);
  finally
    Stream.Free;
  end;
end;

这是最常用的方法SAFEARRAY通过 COM 自动化处理二进制数据的字节数。
将数据填充到BSTR（十六进制字符串、Base64 编码等..）对我来说听起来有点难看，看起来更像是一个 hack。