ControlSend 使用 SetKeyDelay, 0, 0 时随机发送错误字符（修改和未修改）

我正在自我回答这个问题，因为我在互联网上看到过这个问题，但几乎没有有用的答案，而且在 Stack Overflow 上也绝对找不到我能找到的解决方案。

示例代码

考虑一下这段代码，它只写了几行 shell 命令：

^0::
    SetKeyDelay, 0, 0
    myWindow = ahk_exe Notepad.exe
    ControlSend, , set c=".cshrc-andrew.cheong"`n, %myWindow%
    ControlSend, , set v=".vimrc-andrew.cheong"`n, %myWindow%
    ControlSend, , foreach d ( /userhome/andrew.cheong /home/$USER /data/$USER )`n, %myWindow%
    ControlSend, , if ( -e $d/$c ) source $d/$c`n, %myWindow%
    ControlSend, , if ( -e $d/$v ) alias vim "vim -N -u $d/$v"`n, %myWindow%
    ControlSend, , end`n, %myWindow%
    Return

^{I'm writing the commands to Notepad to show that it is not an issue limited to terminal applications like PuTTy or xterm. It's easy to think so, since these applications sometimes have laggy behavior.}

示例输出

具体使用时SetKeyDelay, 0, 0为了快速“打字”，我会遇到各种奇怪的行为，例如：

• 双引号替换为单引号。括号被 9 和 0 替换。美元符号被 4 取代。

  set c=".cshrc-andrew.cheong'
  set v=".vimrc-andrew.cheong"
  foreach d ( /userhome/andrew.cheong /home/$USER /data/$USER )
  if 9 -e 4d/4c 0 source 4d/4c
  if ( -e $d/$v ) alias vim 'vim -n -u 4d/4v'
  end
  

• 破折号替换为下划线。案例变化。

  set c='.cshrc-andrew.cheong"
  set v='.vimrc-andrew.cheong'
  foreach d ( /userhome/andrew.cheong /home/4user /data/$USER )
  if 9 -e 4d/$C ) source 4d/$c
  if 9 _e $d/$v ) alias vim 'vim -N -u $d/$v"
  end
  

• 句点替换为 > 。更多案例变化。

  set c=".cshrc-andrew.cheong"
  set v=">VIMrc-andrew.cheong"
  foreach d ( /userhome/andrew.cheong /home/$USER /data/$USER )
  if 9 -e $d/$c ) source 4d/$c
  if ( -e $d/$V ) alias vim "vim -N -u $d/$v"
  end
  

It's obvious the issue has something to do with the Shift modifier, as if it's being randomly turned on or off.

为什么会发生这种情况，我们该如何解决？

注意使用时没有问题Send及其变体。这个问题具体出现在ControlSend，需要将输入发送到特定控件或未聚焦的窗口。

Solution

将其复制到您的脚本中（来自 AutoHotkey 论坛上的用户 RHCP）：

pSendChars(string, control := "", WinTitle := "", WinText := "", ExcludeTitle := "", ExcludeText := "")
{
    for k, char in StrSplit(string)
        postmessage, WM_CHAR := 0x102, Asc(char),, %Control%, %WinTitle%, %WinText%, %ExcludeTitle%, %ExcludeText%
    return
}

并像这样使用它：

^0::
    myWindow = ahk_exe Notepad.exe
    line .= "set c="".cshrc-acheong""`n"
    line .= "set v="".vimrc-acheong""`n"
    line .= "foreach d ( /userhome/andrew.cheong /home/cama /home/$USER )`n"
    line .= "    if ( -e $d/$c ) source $d/$c`n"
    line .= "    if ( -e $d/$v ) alias vim ""vim -N -u $d/$v""`n"
    line .= "end`n"
    pSendChars(line, "edit1", myWindow)
    Return

就是这样。

^{Note that edit1 is Notepad's name for its text control. When using this script for PuTTy, I changed it to a blank string. Use AutoHotkey's WindowSpy program to find out the control you wish to write to.}

Why

这个问题之前已经出现过几次了。只是为了添加 Lexikos 的内容 写道，问题是由于 controlSend 使用了 post message 和 sendInput/sendEvent 来发送击键。这是必需的 因为某些程序将无法正确解释击键，除非 发送的修饰键在逻辑上是向下的（通过 sendInput/Event 发送）。

发送修饰键（除非明确说明，例如 {shitft down}） 通过 sendInput，而非修饰符通过 postMessage 发送。钥匙已发送 通过 postmessage 直接发送到窗口，因此延迟较少 比其他键/消息。因此，击键是可能的 消息不同步到达，导致出现意外字符。在 您的情况，大写字母需要通过 Shift 键发送 发送输入/事件。

除了使用keyDelays之外，您还可以尝试controlSetText和posting WM_Char 消息。如果您正在使用文本控件，我会 推荐使用controlSetText。

- RHCP 于 2013 年 9 月 30 日 https://autohotkey.com/boards/viewtopic.php?p=38107#p38107