SQL Server：返回字符串过程 INITCAP

这就是我所做的。

create proc INITCAP(@string varchar(30))
as
begin
    SET @string = UPPER(LEFT(@string,1)) + LOWER(RIGHT(@string, LEN(@string) -1))
end

declare @lastname varchar
set @lastname = exec INITCAP 'MILLER'

declare @firstname varchar
set @firstname = exec INITCAP 'StEvE'

UPDATE Employee SET firstname = @firstname, lastname = @lastname WHERE empID = 7934

我不断收到错误：

消息 156，级别 15，状态 1，程序 INITCAP，第 97 行
关键字“exec”附近的语法不正确。
消息 156，级别 15，状态 1，程序 INITCAP，第 100 行
关键字“exec”附近的语法不正确。

我该怎么办？我要程序INITCAP像在 Oracle 中一样工作：返回类似以下的名称：“Steve”、“Miller”

解决方案#1（我不会使用这个解决方案）

您可以这样使用 OUTPUT 参数：

create proc INITCAP(@string varchar(30) OUTPUT)
as
begin
    SET @string = UPPER(LEFT(@string,1)) + LOWER(SUBSTRING(@string, 2, 8000))
end
go 

declare @lastname varchar
set @lastname = 'MILLER'
exec INITCAP @lastname OUTPUT

declare @firstname varchar
set @firstname = 'StEvE'
exec INITCAP @firstname OUTPUT

解决方案#2： 反而，我会选创建内联函数：

CREATE FUNCTION dbo.Capitalize1(@string varchar(30))
RETURNS TABLE
AS
RETURN
SELECT UPPER(LEFT(@string,1)) + LOWER(SUBSTRING(@string, 2, 8000)) AS Result;

Usage:

UPDATE e 
SET firstname = cap.Result
FROM Employee e
CROSS APPLY dbo.Capitalize1(e.firstname) cap;

解决方案#3：另一个选择可能是标量函数with schemabinding选项（出于性能原因）：

CREATE FUNCTION dbo.Capitalize2(@string varchar(30))
RETURNS VARCHAR(30)
WITH SCHEMABINDING
AS
BEGIN
    RETURN UPPER(LEFT(@string,1)) + LOWER(SUBSTRING(@string, 2, 8000));
END;

Usage:

UPDATE Employee
SET firstname = dbo.Capitalize2(firstname);