vbscript如何按修改日期对子文件夹中的文件进行排序（并使用文件的绝对路径打印）

我需要创建一个vbs来按包含子文件夹的文件夹中的修改日期对可设置数量的文件（仅文件）进行排序，并使用绝对路径打印文件，如下所示：

The vbs:

Dim MAX
Dim Folder
MAX = 100
Folder = "C:\Test"
vbscript functions to group all files of all subfolders, and sort them by MOD date... ok
vbscript funciont to make a text file output (This i can't do it by myself)
end

文本文件输出（100个最新文件）：

c:\newest 1st file.txt
c:\subfolder1\newest 2nd file.txt
c:\subfolder7\newest 3rd file.txt
c:\subfolder2\newest 4 file.txt
c:\subfolder8\newest 5 file.txt
c:\subfolder4\newest 6 file.txt
c:\subfolder2\newest 7 file.txt
c:\newest 8 file.txt
c:\subfolder3\newest 9 file.txt
etc...

真的不管解决方案是否可以用批处理完成，我同意，但我已经尝试过：

Dir /S /TC /O-D

唯一的问题是没有告诉我绝对路径......

EDIT：哦，当然我已经尝试过：

Dir / B / S / TC / O-D

但是 /B 参数意味着我之前所说的命令有很大的不同......

I mean:

Dir / S / TC / O-D

该命令将所有子目录中的所有文件分组（在一起）并按日期对它们进行排序。 （好的！）

Dir / B / S / TC / O-D

该命令逐个文件夹处理并对每个文件进行排序并显示它。 （坏的！）

因此，如果我需要对最新的 100 个文件进行排序，并且如果我使用带有“/B”参数的 Batch dir 命令，我会得到以下结果：

Output:

(Position 1) c:\subfolder1\Newest 1st file of this folder.txt
(Position 2) c:\subfolder1\Newest 2nd fil eof this folder.txt
(Position 3) c:\subfolder1\Old file of this folder.txt
(Position 3) c:\subfolder1\Older file of this folder.txt
(Position 4) c:\subfolder1\Oldest file of this folder.txt
(Position 5) c:\subfolder2\Newest 1st file of this folder.txt
(Position 6) c:\subfolder2\Newest 2nd file of this folder.txt
(Position 7) c:\subfolder2\Old file.txt
etc ...

所以请不要告诉我有关使用 dir 和 /B 参数的任何信息，我知道它很好:(。

再次感谢

我遵循上面 KH1 的建议：“您需要将所有文件路径和名称以及 DateModified 一起加载到数组中，对数组进行排序，然后迭代数组并输出文件路径和名称”，但是在批处理文件。下面的程序使用文件的 YYYYMMDDHHMM 修改时间戳作为数组的索引。这样，数组就被保留了自动排序通过批量设置命令。参数与上面的 dbenham 程序相同：FileCount 和可选的 RootFolder。

@echo off
setlocal EnableDelayedExpansion

rem Get order of FileTimeStamp elements independent of regional settings
for /F "skip=1 tokens=2-4 delims=(-)" %%a in ('date^<NUL') do (
   set timeStampOrder=%%a %%b %%c ho mi ap
)

rem For each file in the folder given by %2 (default current one)
for /R %2 %%F in (*.*) do (
   rem Extract FileTimeStamp data (yy mm dd ho mi ap)
   for /F "tokens=1-6" %%a in ("%timeStampOrder%") do (
      for /F "tokens=1-6 delims=/-.: " %%i in ("%%~tF") do (
         set %%a=%%i
         set %%b=%%j
         set %%c=%%k
         set %%d=%%l
         set %%e=%%m
         set %%f=%%n
      )
   )
   rem Adjust hour if needed
   if !ap! equ p set /A "ho=10!ho! %% 100 + 12
   rem Create the array element with proper index
   set "file[!yy!!mm!!dd!!ho!!mi!]=%%~fF"
)

rem At this point the array is automatically sorted

rem Show the first %1 array elements
set n=0
for /F "tokens=2 delims==" %%a in ('set file[') do (
   echo %%a
   set /A n+=1
   if !n! equ %1 goto finish
)

:finish