使用 Delphi 查找特殊驱动器

我正在尝试在 Delphi 2007 中编写一个小程序，以便在便携式 USB 驱动器插入 Windows 7 计算机时访问该驱动器上的文件。但该驱动器并不显示为标准驱动器号。它出现在 Windows 资源管理器中的便携式设备下。我编写了以下代码来枚举“计算机”下的所有项目：

Procedure TfrmMain.ComputerChanged(Var Msg: TMessage);
Var
  Enum: IEnumIDList;
  Fetched: Longword;
  Item: PItemIDList;
  Path: String;
  Computer: IShellFolder;
  StrRet: TSTRRET;
Begin
  Status('Computer changed...  Checking folders.');
  fDesktop.BindToObject(fCompPidl, Nil, IID_IShellFolder, Computer);
  If Assigned(Computer) And
     (Computer.EnumObjects(Self.Handle, SHCONTF_FOLDERS, Enum) = NOERROR) Then
  Begin
    While (Enum.Next(1, Item, Fetched) = NOERROR) Do
    Begin
      FillChar(StrRet, SizeOf(StrRet), #0);
      Computer.GetDisplayNameOf(Item, SHGDN_FORADDRESSBAR or SHGDN_NORMAL, StrRet);
      Path := StrRetToStr(StrRet, Item);
      Status(Path);
    End;
  End;
End;

（注意：Status 过程仅向 TMemo 输出一条消息。）

每当我的应用程序收到 Windows shell 子系统的更改通知时，就会调用此函数。它枚举了所有本地驱动器和网络驱动器，但没有枚举其他驱动器（iCloud 照片驱动器也丢失了）。

有谁知道如何访问这些虚拟驱动器上的文件？

您很可能没有正确初始化 COM。如果您不调用，您的代码将按原样运行协初始化Ex http://msdn.microsoft.com/en-us/library/windows/desktop/ms695279%28v=vs.85%29.aspx或者如果您使用错误的值调用它，但便携式设备驱动程序需要单元线程才能工作。

根据您的代码，这是一个可以正常运行并显示便携式设备的示例应用程序。如果你注释掉CoInitializeEx/CoUninitialize调用或传入COINIT_MULTITHREADED相反，它仍然可以工作，但它只显示驱动器。

program ListMyComputer;

{$APPTYPE CONSOLE}

uses
  ComObj, ShlObj, ShellApi, ShLwApi, ActiveX, Windows, SysUtils;

var
  Enum: IEnumIDList;
  Fetched: Longword;
  CompPidl, Item: PItemIDList;
  Path: PWideChar;
  Desktop, Computer: IShellFolder;
  StrRet: TSTRRET;
begin
  CoInitializeEx(nil, COINIT_APARTMENTTHREADED);
  try
    WriteLn('Computer changed...  Checking folders.');
    SHGetDesktopFolder(Desktop);
    SHGetFolderLocation(0, CSIDL_DRIVES, 0, 0, CompPidl);
    Desktop.BindToObject(CompPidl, Nil, IID_IShellFolder, Computer);
    CoTaskMemFree(CompPidl);
    If Assigned(Computer) And
       (Computer.EnumObjects(0, SHCONTF_FOLDERS, Enum) = NOERROR) Then
    Begin
      While (Enum.Next(1, Item, Fetched) = NOERROR) Do
      Begin
        FillChar(StrRet, SizeOf(StrRet), #0);
        Computer.GetDisplayNameOf(Item, SHGDN_FORADDRESSBAR or SHGDN_NORMAL, StrRet);
        StrRetToStr(@StrRet, Item, Path);
        WriteLn(Path);
        CoTaskMemFree(Path);
      End;
    End;
    WriteLn('Enumeration complete');
    ReadLn;
  finally
    CoUninitialize
  end;
end.