awk 命令创建单个列的 sha2 并粘贴到新文件中

我有一个包含多行的文件。使用该原始文件，我将创建另外一个文件，但在该新文件中，我只获取原始文件的几列。

我要做的是，我需要创建第一列的 sha2 并将其作为普通值以及 sha2 值粘贴到新文件中，而不是只选择几列并粘贴到新文件中。

希望我说清楚了。

这是我用来执行相同操作的 awk 命令。

 awk -F '|' -v  OFS='|' -v  var="10|" '(NR - 1) != 0  {$2=var$2; print $2,$3,$4,$5} (NR - 1) == 0   {print} ' $line > $subName$i$output

INPUT

2|0001001010000026316|531849|1150|101|01111991|00919323739251      |[email protected] /cdn-cgi/l/email-protection                                   |VIJAY PANDEY                            |PART OF GROUND FLOOR & BASEMENT         |SHOPPER STOP SV ROAD ANDHERI WEST       |LANDMARK-ERSTWHILE CRASSWORD BOOK STORE |MUMBAI                        |400058

预期输出需要第二列的 SHA2 值并附加为同一行的最后一列

10|0001001010000026316|531849|1150|101|2e16abd9f3e3e368210b11faa5bfebdb6e001034b58cc9ad1c689dfd1f7eeacd

尝试这个 ：

awk -F"|" -v var="10" '
    NR==1;
    NR>1{
        "echo "$2"|sha256sum" | getline shaoutput; 
        split(shaoutput, sha, " "); 
        print var, $2, $3, $4, $5, sha[1]
    }' OFS="|" file

Output :

10|0001001010000026316|531849|1150|101|2e16abd9f3e3e368210b11faa5bfebdb6e001034b58cc9ad1c689dfd1f7eeacd

我更喜欢使用NR==1 and NR>1因为它更具可读性。

NR==1;可以，不需要添加{print}

For NR>1, I use sha256sum生成 sha 作为 awk 没有任何函数可以做到这一点（据我所知）。我将输出保存在shaoutput变量，使用清理输出split，然后打印需要的内容。

我不想将输出分隔符存储在var多变的。 在 print 中使用逗号将使 awk 使用OFS变量作为分隔符。

Edited

正如 Ed Morton 所建议的，一个改进的解决方案：

awk -v var="10" '
    BEGIN{
        FS=OFS="|"
    }
    NR==1;
    NR>1{
        shaoutput="";
        cmd="echo \047" $2 "\047 | sha256sum" ;
        if ( (cmd | getline line) > 0 ){
            shaoutput=line
            close(cmd)
        }
        split(shaoutput, sha, " ");
        print var, $2, $3, $4, $5, sha[1];
    }' file