如何堵住此类孔 3

继从我的最后一个问题 https://stackoverflow.com/questions/58035216/how-to-plug-this-type-hole-2，我现在能够得到我想要的结果，但以一种完全邪恶的方式：使用unsafePerformIO。我知道这不是解决这个问题的正确方法（尽管为了我的辩护，我从 hoogle 检查类型中得到了这个想法，然后从 kmett 的存储库中的 ag 搜索中查看他何时使用unsafePerformIO跨越一百个左右的存储库。我阅读了有关黑客攻击的警告，我知道这很糟糕。）。

我现在想要的是一种无需unsafePerformIO.

这是代码：

module Main where

import Control.Monad (liftM)
import Data.List (isSubsequenceOf)
import qualified Data.Text as T
import System.Directory (listDirectory)
import System.FilePath ((</>), takeExtension)
import System.IO.Unsafe (unsafePerformIO)
import Text.PDF.Info

title :: FilePath -> IO String
title path = do
  result <- pdfInfo path
  case result of
    Left someError -> do
      return "no title"
    Right info -> do
      case (pdfInfoTitle info) of
        Nothing -> return "no title"
        Just title -> return (T.unpack title)

titleString :: FilePath -> String
titleString s = unsafePerformIO (title s)
{-# NOINLINE titleString #-}

dir = "/some/path"

main :: IO ()
main = do
  print =<<
    liftM
      (filter
         (\path ->
            (isSubsequenceOf "annotated" (titleString (dir </> path))) &&
            (takeExtension path == ".pdf")))
      (listDirectory dir)

一路上，我尝试使用洞打字和大量的 Hoogle 从工具中获得帮助（授人以渔......）。我需要指导来更好地使用工具和文档进行发现过程。如果你有关于如何处理这些事情的提示，或者至少想象一下，如果你失去了除了洞打字和胡歌之外的所有 Haskell 长期记忆，你会做什么，并让我知道你将如何进行。我计划很快观看 Brian McKenna 的 data61 视频，但在那之前。提前致谢！

首先，让我们拆分一下过滤功能：

isAnnotatedPdf :: FilePath -> Bool
isAnnotatedPdf path = (isSubsequenceOf "annotated" (titleString (dir </> path))) && (takeExtension path == ".pdf")

main :: IO ()
main = do
  print =<<
    liftM
      (filter isAnnotatedPdf)
      (listDirectory dir)

现在，使用一些语法糖来清理main:

main :: IO ()
main = do
  dirList <- listDirectory dir
  let filteredList = filter isAnnotatedPdf dirList
  print filteredList

接下来，改变isAnnotatedPdf返回其结果IO，然后修改main这样就可以这样做：

isAnnotatedPdf :: FilePath -> IO Bool
isAnnotatedPdf path = do
  return $ (isSubsequenceOf "annotated" (titleString (dir </> path))) && (takeExtension path == ".pdf")

main :: IO ()
main = do
  dirList <- listDirectory dir
  filteredList <- filterM isAnnotatedPdf dirList
  print filteredList

提取变量pdfTitle inside isAnnotatedPdf为了让下一步更加清晰：

isAnnotatedPdf :: FilePath -> IO Bool
isAnnotatedPdf path = do
  let pdfTitle = titleString (dir </> path)
  return $ (isSubsequenceOf "annotated" pdfTitle) && (takeExtension path == ".pdf")

最后，改变isAnnotatedPdf使用其新的IO上下文而不是使用你的unsafePerformIO包装：

isAnnotatedPdf :: FilePath -> IO Bool
isAnnotatedPdf path = do
  pdfTitle <- title (dir </> path)
  return $ (isSubsequenceOf "annotated" pdfTitle) && (takeExtension path == ".pdf")

你就完成了！现在你可以摆脱titleString以及你所有的参考文献unsafePerformIO.

作为奖励，您现在可以轻松避免致电pdfInfo对于非 PDF 的内容，通过移动纯takeExtension在单子标题检查之前检查，如下所示：

isAnnotatedPdf :: FilePath -> IO Bool
isAnnotatedPdf path = if takeExtension path == ".pdf"
  then do
    pdfTitle <- title (dir </> path)
    return $ isSubsequenceOf "annotated" pdfTitle
  else return False

或者使用<$>代替do:

isAnnotatedPdf :: FilePath -> IO Bool
isAnnotatedPdf path = if takeExtension path == ".pdf"
  then isSubsequenceOf "annotated" <$> title (dir </> path)
  else return False