如何反转 Groovy 集合的排序？

我正在根据多个字段对列表进行排序。

sortedList.sort {[it.getAuthor(), it.getDate()]}

这工作正常，但我想要逆转日期并且reverse()不起作用。

如何按升序对作者排序，但按降序（反向）顺序对日期排序？

我想要的示例：

Author    Date
Adam      12/29/2011
Adam      12/20/2011
Adam      10/10/2011
Ben       11/14/2011
Curt      10/17/2010

我所拥有的示例：

Author    Date
Adam      10/10/2011
Adam      12/20/2011
Adam      12/29/2011
Ben       11/14/2011
Curt      10/17/2010

对于像这样的多属性排序，如果您使用sort()带有闭包或比较器，例如：

sortedList.sort { a, b ->
    if (a.author == b.author) {
        // if the authors are the same, sort by date descending
        return b.date <=> a.date
    }

    // otherwise sort by authors ascending
    return a.author <=> b.author
}

或者更简洁的版本（由特德·纳莱德 https://stackoverflow.com/users/8912/ted-naleid):

sortedList.sort { a, b ->

    // a.author <=> b.author will result in a falsy zero value if equal,
    // causing the date comparison in the else of the elvis expression
    // to be returned

    a.author <=> b.author ?: b.date <=> a.date
}

我在 groovysh 中在以下列表中运行了上面的内容：

[
    [author: 'abc', date: new Date() + 1],
    [author: 'abc', date: new Date()],
    [author: 'bcd', date: new Date()],
    [author: 'abc', date: new Date() - 10]
]

并收到正确排序的：

[
    {author=abc, date=Fri Dec 30 14:38:38 CST 2011},
    {author=abc, date=Thu Dec 29 14:38:38 CST 2011},
    {author=abc, date=Mon Dec 19 14:38:38 CST 2011},
    {author=bcd, date=Thu Dec 29 14:38:38 CST 2011}
]