在 Delphi 7 中制作 TPageControl 平面

我不知道这个问题是否可以在这里得到解答，但我希望能够。 我在 Delphi 7 中编写了一个简单的文本编辑器，作为我在 Windows 下编写 C 代码的主要 IDE。我在虚拟机中运行 Windows，我需要一些简单的东西。 无论如何，它使用 TpageControl，每当您打开或创建新文件时都会获得一个新选项卡。相当标准。 现在，Delphi下的TPageControl没有flat属性。

不，我的意思不是将选项卡样式设置为 tsButtons 或 tsFlatButtons

边框不能设置为“无”，并且当您将文本编辑器添加到选项卡控件中时，它看起来非常糟糕。

有没有办法让TpageControl变平？

EDIT:

在支持平面的开源 PageControl 上，我发现了以下内容：

procedure TCustomTabExtControl.WndProc(var Message: TMessage);
begin
  if(Message.Msg=TCM_ADJUSTRECT) and (FFlat) then
   begin
    Inherited WndProc(Message);
    Case TAbPosition of
    tpTop : begin
    PRect(Message.LParam)^.Left:=0;
    PRect(Message.LParam)^.Right:=ClientWidth;
    PRect(Message.LParam)^.Top:=PRect(Message.LParam)^.Top-4;
    PRect(Message.LParam)^.Bottom:=ClientHeight;
  end;
    tpLeft : begin
    PRect(Message.LParam)^.Top:=0;
    PRect(Message.LParam)^.Right:=ClientWidth;
    PRect(Message.LParam)^.Left:=PRect(Message.LParam)^.Left-4;
    PRect(Message.LParam)^.Bottom:=ClientHeight;
  end;
    tpBottom : begin
    PRect(Message.LParam)^.Left:=0;
    PRect(Message.LParam)^.Right:=ClientWidth;
    PRect(Message.LParam)^.Bottom:=PRect(Message.LParam)^.Bottom-4;
    PRect(Message.LParam)^.Top:=0;
  end;
    tpRight : begin
    PRect(Message.LParam)^.Top:=0;
    PRect(Message.LParam)^.Left:=0;
    PRect(Message.LParam)^.Right:=PRect(Message.LParam)^.Right-4;
    PRect(Message.LParam)^.Bottom:=ClientHeight;
    end;
  end;
 end else Inherited WndProc(Message);

end;

问题是，当我在主应用程序上尝试类似的操作时，它不起作用。它甚至不会编译。

当选项卡绘制为按钮时，显示区域周围不会绘制边框，因此设置Style财产给tsButtons or tsFlatButtons。 （对于非 VCL 程序员，这相当于包含tcs_Buttons http://msdn.microsoft.com/en-us/library/bb760549.aspx选项卡控件上的窗口样式。）

另一种方法是使用TNotebook。它可以容纳页面，但根本不进行任何绘画。您必须自己提供选项卡，例如将选项卡控件的高度设置为等于选项卡的高度，或者使用TTabSet. (TTabSet在 Delphi 2005 中可用；我不确定 Delphi 7。）

关于您找到的代码，如果您指出为什么它不编译，或者您提供了找到它的位置的链接，那将会很有帮助，因为我认为编译错误是因为它引用了自定义类的字段或属性而不是库存的。您可以尝试将以下内容放入您自己的代码中，而无需编写自定义控件。

在您的文件中做出两个新声明form像这样：

FOldTabProc: TWndMethod;
procedure TabWndProc(var Msg: TMessage);

在表格的OnCreate事件处理程序，将该方法分配给页面控件的WindowProc财产：

FOldTabProc := PageControl1.WindowProc;
PageControl1.WindowProc := TabWndProc;

现在实现该方法并处理tcm_AdjustRect信息：

procedure TForm1.TabWndProc(var Msg: TMessage);
begin
  FOldTabProc(Msg);
  if Msg.Msg = tcm_AdjustRect then begin
    case PageControl1.TabPosition of
      tpTop: begin
        PRect(Msg.LParam)^.Left := 0;
        PRect(Msg.LParam)^.Right := PageControl1.ClientWidth;
        Dec(PRect(Msg.LParam)^.Top, 4);
        PRect(Msg.LParam)^.Bottom := PageControl1.ClientHeight;
      end;
    end;
  end;
end;

如果您需要的话，您可以填写其他三种情况。Tcm_AdjustRect是在中声明的消息标识符CommCtrl单元。如果您在该单元中没有该消息，请自行声明；它的值为 4904。

我怀疑这并不能阻止控件绘制其边界。相反，它会导致所包含的TTabSheet变大一点并掩盖边界。