在 Haskell 中模拟路径依赖类型

这是我想做的事情的一个简化示例。假设你有一个HList对：

let hlist = HCons (1, "1") (HCons ("0", 2) (HCons ("0", 1.5) HNil))

现在我想写一个函数replaceAll它将用相同类型的第一个“值”替换给定类型的所有“键”。例如，与HList上面我想替换所有String键与"1"这是类型的第一个值String发现于HList

 replaceAll @String hlist =
    HCons (1, "1") (HCons ("1", 2) (HCons ("1", 1.5) HNil))

这似乎需要路径相关的类型，以便“提取”第一对的类型，并能够使用它来指导第二步中键的替换，但我不知道如何在 Haskell 中对其进行编码。

这是一个证明搜索问题（“查找String在此列表中”），因此您可以预期解决方案将涉及类型类 Prolog。我将回答您的问题的更简单版本（即“找到first的发生String") 并让您了解如何根据您的具体用例进行调整。

由于我们正在进行证明搜索，因此让我们首先写下我们将要搜索的证明对象。

data Contains a as where
    Here :: Contains a (a ': as)
    There :: Contains a as -> Contains a (b ': as)

类型的值Contains a as是一个你可以找到的建设性证据a在类型级别列表中as。从结构上来说，Contains就像一个自然数（比较There (There Here) with S (S Z)) 识别位置a在列表中as。为了证明这一点a is in as你给出它的索引。

例如，您可以replace中给定位置的元素HList与相同类型的新元素。

replace :: a -> Contains a as -> HList as -> HList as
replace x Here (HCons y ys) = HCons x ys
replace x (There i) (HCons y ys) = HCons y (replace x i ys)

我们想要寻找一个a在给定列表中使用类型类 Prolog。有两种情况 - 要么你找到a在列表的头部，或者在尾部的某个地方。 （如果a不在as, using contains会因“无实例”错误而失败。）理想情况下，我们会编写如下内容：

class CONTAINS a as where
    contains :: Contains a as

instance CONTAINS a (a ': as) where
    contains = Here

instance CONTAINS a as => CONTAINS a (b ': as) where
    contains = There contains  -- recursively call `contains` on the sublist

但这不符合重叠实例规则。在实例搜索期间不会检查实例上下文和类型相等性 - 阐述者不会回溯 - 因此这两个实例都不比另一个实例更具体。

幸运的是有一个众所周知的解决方案 https://wiki.haskell.org/GHC/AdvancedOverlap对于这个问题。它涉及使用封闭类型族来告诉a and b分开。您定义一个辅助类CONTAINS'有一个额外的参数，在本例中是Bool告诉你是否a可以在头部找到as.

class CONTAINS' (eq :: Bool) a (as :: [*]) where
    contains' :: Contains a as

然后，您为以下情况定义实例：eq is True or False。阐述者可以区分这些实例，因为True and False明显不同。请注意，步骤案例递归调用CONTAINS.

instance CONTAINS' True a (a ': as) where
    contains' = Here

instance CONTAINS a as => CONTAINS' False a (b ': as) where
    contains' = There contains

最后你定义你的CONTAINS实例而言CONTAINS'，并使用结果== http://hackage.haskell.org/package/base-4.11.1.0/docs/Data-Type-Equality.html，一个封闭类型族，它测试其参数是否相等，以选择一个实例。

instance CONTAINS' (a == b) a (b ': as) => CONTAINS a (b ': as) where
    contains = contains' @(a == b)

（这是布尔类型族极少数可接受的用途之一。）

现在你可以使用CONTAINS就像任何其他课程一样。当你尝试实例化时a and asGHC 将尝试寻找a inside as，以及contains方法将返回其索引。

example :: Contains Int '[Bool, Int, Char]
example = contains

-- "no instance for CONTAINS"
failingExample :: Contains String '[Bool, Int, Char]
failingExample = contains

这是一个相当简单的例子，代码已经相当混乱了。您绝对可以以相同的方式处理问题中的示例，但总而言之，我不相信静态检查值得在这种情况下如此复杂。您是否考虑过基于Typeable?