SQL Server SMO - 备份 - 如何确定失败/成功？

如果使用 SMO 执行备份，成功完成后，我测试 SqlError 是否为 null，认为备份已完成且没有错误：

但是，正如您所看到的，它实际上返回了 0 类编号 3014 的错误，这意味着成功。

所以问题是：

问：如何确定备份是否成功完成，以及如何干净地处理这些消息和状态？

我担心这里有多个“陷阱”，当这段代码投入生产时，我不想再惹麻烦了:)

我同意存在多个“陷阱”，并且我个人认为 Microsoft SMO 事件实施得很差，因为 ServerMessageEventArgs 包含一个属性错误，它并不总是提供有关错误的信息，而是提供有关成功操作的消息！

举个例子： 代码 4035 的“错误”是一条信息消息。不是错误。 代码 3014 的“错误”是成功完成时出现的信息消息。不是错误

另请注意，发生错误时，信息事件并不总是发生。实际上，每当 SQL Server 发送一条可能是有关已成功完成的操作的信息的消息时，就会发生这种情况

我还担心没有正确处理错误/成功，但是检查 sqlError 为 Null 是一个坏主意因为它永远不会为空，并且它将始终包含一些有关成功操作或错误的消息。和假设发生错误时发生信息事件也是一个坏主意.

我建议通过 SqlError.Number 并根据已触发的 SMO 事件来处理错误。

我编写了以下代码来创建数据库备份。它在 VB.NET 中，但在 C# 中会类似。它接收必要的参数，包括调用事件的委托（在 GUI 上处理）、报告百分比的进度和根据事件触发的错误处理以及如上所述的 SqlError.Number

Public Sub BackupDatabase(databaseName As String, backupFileFullPath As String, optionsBackup As OptionsBackupDatabase, operationProgress As IProgress(Of Integer),
                          operationResult As Action(Of OperationResult)) Implements IDatabaseManager.BackupDatabase
    Dim sqlBackup As New Smo.Backup()
    sqlBackup.Action = Smo.BackupActionType.Database
    sqlBackup.BackupSetName = databaseName & " Backup"
    sqlBackup.BackupSetDescription = "Full Backup of " & databaseName
    sqlBackup.Database = databaseName
    Dim bkDevice As New Smo.BackupDeviceItem(backupFileFullPath, Smo.DeviceType.File)
    sqlBackup.Devices.Add(bkDevice)
    sqlBackup.Initialize = optionsBackup.Overwrite
    sqlBackup.Initialize = True
    sqlBackup.PercentCompleteNotification = 5

    AddHandler sqlBackup.PercentComplete, Sub(sender As Object, e As PercentCompleteEventArgs)
                                              operationProgress.Report(e.Percent)
                                          End Sub
    AddHandler sqlBackup.Complete, Sub(sender As Object, e As ServerMessageEventArgs)
                                       Dim sqlMessage As SqlClient.SqlError = e.Error
                                       Dim opResult As New OperationResult()
                                       Select Case sqlMessage.Number
                                           Case 3014
                                               opResult.operationResultType = OperationResultType.SmoSuccess
                                               opResult.message = "Backup successfully created at " & backupFileFullPath & ". " & sqlMessage.Number & ": " & sqlMessage.Message
                                           Case Else
                                               opResult.operationResultType = OperationResultType.SmoError
                                               opResult.message = "ERROR CODE " & sqlMessage.Number & ": " & sqlMessage.Message
                                       End Select
                                       operationResult.Invoke(opResult)
                                   End Sub

    AddHandler sqlBackup.NextMedia, Sub(sender As Object, e As ServerMessageEventArgs)
                                        Dim sqlMessage As SqlClient.SqlError = e.Error
                                        Dim opResult As New OperationResult()
                                        opResult.operationResultType = OperationResultType.SmoError
                                        opResult.message = "ERROR CODE:  " & sqlMessage.Number & ": " & sqlMessage.Message
                                        operationResult.Invoke(opResult)
                                    End Sub

    AddHandler sqlBackup.Information, Sub(sender As Object, e As ServerMessageEventArgs)
                                          Dim sqlMessage As SqlClient.SqlError = e.Error
                                          Dim opResult As New OperationResult()
                                          Select Case sqlMessage.Number
                                              Case 4035
                                                  opResult.operationResultType = OperationResultType.SmoInformation
                                                  opResult.message = sqlMessage.Number & ": " & sqlMessage.Message
                                              Case Else
                                                  opResult.operationResultType = OperationResultType.SmoError
                                                  opResult.message = "ERROR CODE " & sqlMessage.Number & ": " & sqlMessage.Message
                                          End Select
                                          operationResult.Invoke(opResult)
                                      End Sub
    Try
        sqlBackup.SqlBackupAsync(smoServer)
    Catch ex As Exception
        Throw New BackupManagerException("Error backing up database " & databaseName, ex)
    End Try
End Sub