如果行（特定字段）匹配，则 awk 列的平均部分

这是我的输入文件的示例：

$cat NDVI-bm  
P01 031.RAW 0.516 0 0  
P01 021.RAW 0.449 0 0  
P02 045.RAW 0.418 0 0  
P03 062.RAW 0.570 0 0  
P03 064.RAW 0.469 0 0  
P04 083.RAW 0.636 0 0  
P04 081.RAW 0.592 0 0  
P04 082.RAW 0.605 0 0  
P04 084.RAW 0.648 0 0  
P05 093.RAW 0.748 0 0

如果第一个字段匹配，我需要对第 3 列进行平均。很简单，但我很挣扎，因为我的 awk 知识非常基础……这是我到目前为止所掌握的：

awk '{array[$1]+=$3(need to divide here by number of matches...)} END { for (i in array) {print i"," array[i]}}' NDVI-bm

通过搜索网络，我真的不确定我是否走在正确的道路上...除非有一种简单的方法来计算匹配的数量，但我似乎找不到...有什么想法吗？

谢谢你的帮助 ！

例如，计算以“P01”开头的行的平均值：

/^P01/{
    num+=1
    cnt+=$3
}
END {print "avg = " cnt/num}

Output:

$ awk -f avg.awk input
avg = 0.4825

...或者，作为单行：

$ awk '/^P01/{cnt+=$3; num+=1} END{print "avg="cnt/num}' input

或者同时计算第一列的所有值：

{
    sum[$1]+=$3
    cnt[$1]++
}


END {
    print "Name" "\t" "sum" "\t" "cnt" "\t" "avg"
    for (i in sum)
        print i "\t" sum[i] "\t" cnt[i] "\t" sum[i]/cnt[i]

}

Outputs:

$ awk -f avg.awk input
Name    sum     cnt     avg
P01     0.965   2       0.4825
P02     0.418   1       0.418
P03     1.039   2       0.5195
P04     2.481   4       0.62025
P05     0.748   1       0.748