捕获音频会话事件

我尝试编写一些应用程序来监视音频会话（如 SndVol 所做的那样）。我激活了 IAudioSessionManager2，通过 IAudioSessionEnumerator 获取当前音频会话列表，使用音频会话管理器中的 RegisterSessionNotification 方法注册通知。但是，我的应用程序从未收到 OnSessionCreated() 通知。当然，我在这里读到了类似的主题：通知未发送 https://stackoverflow.com/questions/736084/iaudiosessionmanager2-notifications-not-sent, IAudioSessionNotification 任何人都有工作代码 https://stackoverflow.com/questions/858974/iaudiosessionnotification-anyone-have-working-code

我仔细阅读了所有答案，但我找不到我做错了什么。这是我的代码（德尔福）：

TDNAudioSessionManager = class(TDNUnknownObject, IAudioSessionNotification)
private
  FManager: IAudioSessionManager2;
  FList: TDNAudioSessionList;
  function IsManagerValid: Boolean;
protected
  procedure ActivateSessionManager(out AManager: IAudioSessionManager2);
  procedure GetCurrentSessions;
  // IAudioSessionNotification
  function OnSessionCreated(ANewSession: IAudioSessionControl): HRESULT; stdcall;
public
  constructor Create;
  destructor Destroy; override;
end;

constructor TDNAudioSessionManager.Create;
begin
  inherited Create;
  ActivateSessionManager(FManager);
  if IsManagerValid then
  begin
    FList := TDNAudioSessionList.Create;
    FManager.RegisterSessionNotification(Self);
    GetCurrentSessions;
   end;
 end;

destructor TDNAudioSessionManager.Destroy;
begin
  if IsManagerValid then
  begin
    FManager.UnregisterSessionNotification(Self);
    FManager := nil;
  end;
  FreeAndNil(FList);
  inherited Destroy;
 end;

function TDNAudioSessionManager.IsManagerValid: Boolean;
begin
  Result := Assigned(FManager);
end;

procedure TDNAudioSessionManager.GetCurrentSessions;
var
  AEnumerator: IAudioSessionEnumerator;
  ASession: IAudioSessionControl;
  ACount: Integer;
  I: Integer;
begin
  if IsManagerValid then
    if FManager.GetSessionEnumerator(AEnumerator) = S_OK then
    try
      AEnumerator.GetCount(ACount);
      for I := 0 to ACount - 1 do
      begin
        AEnumerator.GetSession(I, ASession);
        FList.Add(ASession);
      end;
    finally
      AEnumerator := nil;
    end;
end;

function TDNAudioSessionManager.OnSessionCreated(ANewSession: IAudioSessionControl): HRESULT;
begin
  FList.Add(ANewSession);
  Result := S_OK;
end;

procedure TDNAudioSessionManager.ActivateSessionManager(out AManager: IAudioSessionManager2);
var
  AEnumerator: IMMDeviceEnumerator;
  ADefault: IMMDevice;
  ARes: HRESULT;
begin
  AManager := nil;
  ARes := CoCreateInstance(CLSID_MMDeviceEnumerator, nil, CLSCTX_INPROC_SERVER, IID_IMMDeviceEnumerator, AEnumerator);
  if not ARes = S_OK then Exit;
  if AEnumerator.GetDefaultAudioEndpoint(eRender, eConsole,  ADefault) = S_OK then
  try
    ADefault.Activate(IID_IAudioSessionManager2, CLSCTX_INPROC_SERVER, nil, AManager);
  finally
    ADefault := nil;
  end;
end;

initialization
  CoInitializeEx(nil, COINIT_MULTITHREADED);
end.

注意：TDNUnknownObject 是实现 IUnknown 方法的类。

还有一个问题：应用程序关闭时音频会话会发送什么事件？ （在 SndVol 中，它已从列表中删除）。我尝试了 OnSessionDisconnected、OnStateChanged （状态为 AudioSessionExpired），但我的应用程序也从未收到它们。

提前致谢！

TDN 未知对象：

TDNUnknownObject = class(TObject, IUnknown)
protected
  // IUnknown
  function _AddRef: Integer; stdcall;
  function _Release: Integer; stdcall;
  function QueryInterface(const IID: TGUID; out Obj): HRESULT; virtual; stdcall;
end;

function TDNUnknownObject._AddRef: Integer; stdcall;
begin
  Result := -1;
end;

function TDNUnknownObject._Release: Integer; stdcall;
begin
  Result := -1;
end;

function TDNUnknownObject.QueryInterface(const IID: TGUID; out Obj): HRESULT; stdcall;
begin
  if GetInterface(IID, Obj) then
    Result := S_OK
  else
    Result := E_NOINTERFACE;
end;

好吧，我对此感到摸不着头脑。第一个问题出现了：为什么不使用 TInterfacedObject？节省了大量的工作，并且被证明可以正确工作。该对象派生自 IUnknown 并别名为 IInterface，并且完全执行您在此处尝试执行的操作。当然，您可以尝试编写自己的版本，但要注意：Delphi 编译器将更加严格，因此您将很容易遇到双重实现和名称冲突等陷阱。因此，编译器、链接器和调试器的行为可能会很奇怪。

好的，来自 MS 的简短说明： 确保应用程序通过在非 UI 线程中调用 CoInitializeEx(Nil, COINIT_MULTITHREADED) 使用多线程单元 (MTA) 模型初始化 COM。如果 MTA 未初始化，应用程序不会从会话管理器接收会话通知。运行应用程序用户界面的线程应该初始化单元线程模型。

就是这样：您的初始化部分不正确。 它应该是：

initialization
  CoInitializeEx(Nil,
                 COINIT_APARTMENTTHREADED);